miniresource functor

6 files changed, 86 insertions, 0 deletions

diff --git a/examples/miniresource/MiniresourceFin.gf b/examples/miniresource/MiniresourceFin.gf
new file mode 100644
index 000000000..13544b9a5
--- /dev/null
+++ b/examples/miniresource/MiniresourceFin.gf
@@ -0,0 +1,2 @@
+concrete MiniresourceFin of Miniresource = MiniresourceI with 
+  (Grammar = GrammarFin), (Lexicon = LexiconFin) ;
diff --git a/examples/miniresource/MiniresourceFre.gf b/examples/miniresource/MiniresourceFre.gf
new file mode 100644
index 000000000..b188d91f1
--- /dev/null
+++ b/examples/miniresource/MiniresourceFre.gf
@@ -0,0 +1,2 @@
+concrete MiniresourceFre of Miniresource = MiniresourceI with 
+  (Grammar = GrammarFre), (Lexicon = LexiconFre) ;
diff --git a/examples/miniresource/MiniresourceI.gf b/examples/miniresource/MiniresourceI.gf
new file mode 100644
index 000000000..26b79b044
--- /dev/null
+++ b/examples/miniresource/MiniresourceI.gf
@@ -0,0 +1,76 @@
+incomplete concrete MiniresourceI of Miniresource = open Grammar, Lexicon in {
+
+-- module Grammar in GF book, Chapter 9: syntax and structural words
+
+  lincat
+    S = Grammar.S ; 
+    Cl = Grammar.Cl ; 
+    NP = Grammar.NP ; 
+    VP = Grammar.VP ; 
+    AP = Grammar.AP ; 
+    CN = Grammar.CN ; 
+    Det = Grammar.Det ; 
+    N = Grammar.N ; 
+    A = Grammar.A ; 
+    V = Grammar.V ; 
+    V2 = Grammar.V2 ; 
+    AdA = Grammar.AdA ; 
+    Tense = Grammar.Temp ; 
+    Pol = Grammar.Pol ;
+    Conj = Grammar.Conj ;
+  lin
+    UseCl = Grammar.UseCl ;
+    PredVP = Grammar.PredVP ;
+    ComplV2 v np = Grammar.ComplSlash (Grammar.SlashV2a v) np ;
+    DetCN = Grammar.DetCN ;
+    ModCN = Grammar.AdjCN ;
+
+    CompAP ap = Grammar.UseComp (Grammar.CompAP ap) ;
+    AdAP = Grammar.AdAP ;
+
+    ConjS c x y = Grammar.ConjS c (Grammar.BaseS x y) ;
+    ConjNP c x y = Grammar.ConjNP c (Grammar.BaseNP x y) ;
+
+    UseV = Grammar.UseV ;
+    UseN = Grammar.UseN ;
+    UseA = Grammar.PositA ;
+
+    a_Det = Grammar.DetQuant Grammar.IndefArt Grammar.NumSg ; 
+    the_Det = Grammar.DetQuant Grammar.DefArt Grammar.NumSg ; 
+    every_Det = Grammar.every_Det ;
+    this_Det  = Grammar.DetQuant Grammar.this_Quant Grammar.NumSg ; 
+    these_Det = Grammar.DetQuant Grammar.this_Quant Grammar.NumPl ; 
+    that_Det  = Grammar.DetQuant Grammar.that_Quant Grammar.NumSg ; 
+    those_Det = Grammar.DetQuant Grammar.that_Quant Grammar.NumPl  ; 
+    i_NP = Grammar.UsePron Grammar.i_Pron ;
+    youSg_NP = Grammar.UsePron Grammar.youSg_Pron ;
+    he_NP = Grammar.UsePron Grammar.he_Pron ;
+    she_NP = Grammar.UsePron Grammar.she_Pron ;
+    we_NP = Grammar.UsePron Grammar.we_Pron ;
+    youPl_NP = Grammar.UsePron Grammar.youPl_Pron ;
+    they_NP = Grammar.UsePron Grammar.they_Pron ;
+    very_AdA = Grammar.very_AdA ;
+
+    Pos = Grammar.PPos ;
+    Neg = Grammar.PNeg ;
+    Pres = Grammar.TTAnt Grammar.TPres Grammar.ASimul ;
+    Perf = Grammar.TTAnt Grammar.TPres Grammar.AAnter ;
+
+    and_Conj = Grammar.and_Conj ;
+    or_Conj = Grammar.or_Conj ;
+
+-- module Test: content word lexicon for testing
+
+    man_N = Lexicon.man_N ;
+    woman_N = Lexicon.woman_N ;
+    house_N = Lexicon.house_N ;
+    tree_N = Lexicon.tree_N ;
+    big_A = Lexicon.big_A ;
+    small_A = Lexicon.small_A ;
+    green_A = Lexicon.green_A ;
+    walk_V = Lexicon.walk_V ;
+    arrive_V = Lexicon.come_V ;  -----
+    love_V2 = Lexicon.love_V2 ;
+    please_V2 = Lexicon.hear_V2 ; ----
+
+}
diff --git a/examples/miniresource/MiniresourceIChi.gf b/examples/miniresource/MiniresourceIChi.gf
new file mode 100644
index 000000000..fce80208b
--- /dev/null
+++ b/examples/miniresource/MiniresourceIChi.gf
@@ -0,0 +1,2 @@
+concrete MiniresourceIChi of Miniresource = MiniresourceI with 
+  (Grammar = GrammarChi), (Lexicon = LexiconChi) ;
diff --git a/examples/miniresource/MiniresourceIEng.gf b/examples/miniresource/MiniresourceIEng.gf
new file mode 100644
index 000000000..9711b4295
--- /dev/null
+++ b/examples/miniresource/MiniresourceIEng.gf
@@ -0,0 +1,2 @@
+concrete MiniresourceIEng of Miniresource = MiniresourceI with 
+  (Grammar = GrammarEng), (Lexicon = LexiconEng) ;
diff --git a/examples/miniresource/MiniresourceSwe.gf b/examples/miniresource/MiniresourceSwe.gf
new file mode 100644
index 000000000..d24eef7e2
--- /dev/null
+++ b/examples/miniresource/MiniresourceSwe.gf
@@ -0,0 +1,2 @@
+concrete MiniresourceSwe of Miniresource = MiniresourceI with 
+  (Grammar = GrammarSwe), (Lexicon = LexiconSwe) ;