Remove contribs and examples

Everything has now been moved to a separate repository at
https://github.com/GrammaticalFramework/gf-contrib
The contents of the examples folder are build during SetupWeb

3 files changed, 0 insertions, 144 deletions

diff --git a/examples/tutorial/foods/Foods.gf b/examples/tutorial/foods/Foods.gf
deleted file mode 100644
index 35779a76d..000000000
--- a/examples/tutorial/foods/Foods.gf
+++ /dev/null
@@ -1,16 +0,0 @@
-abstract Foods = {
-
-  flags startcat=Phrase ;
-
-  cat
-    Phrase ; Item ; Kind ; Quality ;
-
-  fun
-    Is : Item -> Quality -> Phrase ;
-    This, That, These, Those : Kind -> Item ;
-    QKind : Quality -> Kind -> Kind ;
-    Wine, Cheese, Fish, Pizza : Kind ;
-    Very : Quality -> Quality ;
-    Fresh, Warm, Italian, Expensive, Delicious, Boring : Quality ;
-
-}
diff --git a/examples/tutorial/foods/FoodsEng.gf b/examples/tutorial/foods/FoodsEng.gf
deleted file mode 100644
index 69a427006..000000000
--- a/examples/tutorial/foods/FoodsEng.gf
+++ /dev/null
@@ -1,52 +0,0 @@
---# -path=.:prelude
-
-concrete FoodsEng of Foods = open Prelude in {
-
-  lincat
-    Phrase, Quality = SS ; 
-    Kind = {s : Number => Str} ; 
-    Item = {s : Str ; n : Number} ; 
-
-  lin
-    Is item quality = ss (item.s ++ copula ! item.n ++ quality.s) ;
-    This  = det Sg "this" ;
-    That  = det Sg "that" ;
-    These = det Pl "these" ;
-    Those = det Pl "those" ;
-    QKind quality kind = {s = \\n => quality.s ++ kind.s ! n} ;
-    Wine = regNoun "wine" ;
-    Cheese = regNoun "cheese" ;
-    Fish = noun "fish" "fish" ;
-    Pizza = regNoun "pizza" ;
-    Very = prefixSS "very" ;
-    Fresh = ss "fresh" ;
-    Warm = ss "warm" ;
-    Italian = ss "Italian" ;
-    Expensive = ss "expensive" ;
-    Delicious = ss "delicious" ;
-    Boring = ss "boring" ;
-
-  param
-    Number = Sg | Pl ;
-
-  oper
-    det : Number -> Str -> {s : Number => Str} -> {s : Str ; n : Number} = 
-      \n,d,cn -> {
-        s = d ++ cn.s ! n ;
-        n = n
-      } ;
-    noun : Str -> Str -> {s : Number => Str} = 
-      \man,men -> {s = table {
-        Sg => man ;
-        Pl => men 
-        }
-      } ;
-    regNoun : Str -> {s : Number => Str} = 
-      \car -> noun car (car + "s") ;
-    copula : Number => Str = 
-      table {
-        Sg => "is" ;
-        Pl => "are"
-        } ;
-}
-    
diff --git a/examples/tutorial/foods/FoodsIta.gf b/examples/tutorial/foods/FoodsIta.gf
deleted file mode 100644
index 099bbebcf..000000000
--- a/examples/tutorial/foods/FoodsIta.gf
+++ /dev/null
@@ -1,76 +0,0 @@
---# -path=.:prelude
-
-concrete FoodsIta of Foods = open Prelude in {
-
-  lincat
-    Phrase = SS ; 
-    Quality = {s : Gender => Number => Str} ; 
-    Kind = {s : Number => Str ; g : Gender} ; 
-    Item = {s : Str ; g : Gender ; n : Number} ; 
-
-  lin
-    Is item quality = 
-      ss (item.s ++ copula item.n ++ quality.s ! item.g ! item.n) ;
-    This  = det Sg "questo" "questa" ;
-    That  = det Sg "quel"   "quella" ;
-    These = det Pl "questi" "queste" ;
-    Those = det Pl "quei"   "quelle" ;
-    QKind quality kind = {
-      s = \\n => kind.s ! n ++ quality.s ! kind.g ! n ;
-      g = kind.g
-      } ;
-    Wine = noun "vino" "vini" Masc ;
-    Cheese = noun "formaggio" "formaggi" Masc ;
-    Fish = noun "pesce" "pesci" Masc ;
-    Pizza = noun "pizza" "pizze" Fem ;
-    Very qual = {s = \\g,n => "molto" ++ qual.s ! g ! n} ;
-    Fresh = adjective "fresco" "fresca" "freschi" "fresche" ;
-    Warm = regAdj "caldo" ;
-    Italian = regAdj "italiano" ;
-    Expensive = regAdj "caro" ;
-    Delicious = regAdj "delizioso" ;
-    Boring = regAdj "noioso" ;
-
-  param
-    Number = Sg | Pl ;
-    Gender = Masc | Fem ;
-
-  oper
-    det : Number -> Str -> Str -> {s : Number => Str ; g : Gender} -> 
-        {s : Str ; g : Gender ; n : Number} = 
-      \n,m,f,cn -> {
-        s = case cn.g of {Masc => m ; Fem => f} ++ cn.s ! n ;
-        g = cn.g ;
-        n = n
-      } ;
-    noun : Str -> Str -> Gender -> {s : Number => Str ; g : Gender} = 
-      \man,men,g -> {
-        s = table {
-          Sg => man ;
-          Pl => men 
-          } ;
-        g = g
-      } ;
-    adjective : (_,_,_,_ : Str) -> {s : Gender => Number => Str} = 
-      \nero,nera,neri,nere -> {
-        s = table {
-          Masc => table {
-            Sg => nero ;
-            Pl => neri
-            } ; 
-          Fem => table {
-            Sg => nera ;
-            Pl => nere
-            }
-          }
-      } ;
-    regAdj : Str -> {s : Gender => Number => Str} = \nero ->
-      let ner = init nero 
-      in adjective nero (ner + "a") (ner + "i") (ner + "e") ;
-
-    copula : Number -> Str = 
-      \n -> case n of {
-        Sg => "è" ;
-        Pl => "sono"
-        } ;
-}