From c8ceed08efcc0bdc1fcbd89bce643d9f52f0991b Mon Sep 17 00:00:00 2001
From: aarne <aarne@chalmers.se>
Date: Wed, 9 Dec 2009 09:47:16 +0000
Subject: moving a few things to deprecated

---
 .../old-lib/resource/romance/QuestionRomance.gf    | 113 +++++++++++++++++++++
 1 file changed, 113 insertions(+)
 create mode 100644 deprecated/old-lib/resource/romance/QuestionRomance.gf

(limited to 'deprecated/old-lib/resource/romance/QuestionRomance.gf')

diff --git a/deprecated/old-lib/resource/romance/QuestionRomance.gf b/deprecated/old-lib/resource/romance/QuestionRomance.gf
new file mode 100644
index 000000000..6d2fa8669
--- /dev/null
+++ b/deprecated/old-lib/resource/romance/QuestionRomance.gf
@@ -0,0 +1,113 @@
+incomplete concrete QuestionRomance of Question = 
+  CatRomance ** open CommonRomance, ResRomance, Prelude in {
+
+  flags optimize=all_subs ;
+
+  lin
+
+    QuestCl cl = {
+      s = \\t,a,p => 
+            let cls = cl.s ! DDir ! t ! a ! p ---- DInv? 
+            in table {
+              QDir   => cls ! Indic ;
+              QIndir => subjIf ++ cls ! Indic
+              }
+      } ;
+
+    QuestVP qp vp = {
+      s = \\t,a,b,_ => 
+        let
+          cl = mkClause (qp.s ! Nom) False (agrP3 qp.a.g qp.a.n) vp  
+        in
+        cl.s ! DDir ! t ! a ! b ! Indic
+      } ;   
+
+    QuestSlash ip slash = {
+      s = \\t,a,p => 
+            let 
+              cls : Direct -> Str = 
+                    \d -> slash.s ! ip.a ! d ! t ! a ! p ! Indic ;
+              who = slash.c2.s ++ ip.s ! slash.c2.c
+            in table {
+              QDir   => who ++ cls DInv ;
+              QIndir => who ++ cls DDir
+              }
+      } ;
+
+    QuestIAdv iadv cl = {
+      s = \\t,a,p,q => 
+            let 
+              ord = case q of {
+                QDir   => DInv ;
+                QIndir => DDir
+              } ;
+              cls = cl.s ! ord ! t ! a ! p ! Indic ;
+              why = iadv.s
+            in why ++ cls
+      } ;
+
+    QuestIComp icomp np = {
+      s = \\t,a,p,_ => 
+            let 
+              vp  = predV copula ;
+              cls = (mkClause (np.s ! Aton Nom) np.hasClit np.a vp).s ! 
+                       DInv ! t ! a ! p ! Indic ;
+              why = icomp.s ! {g = np.a.g ; n = np.a.n}
+            in why ++ cls
+      } ;
+
+    PrepIP p ip = {
+      s = p.s ++ ip.s ! p.c
+      } ;
+
+    AdvIP ip adv = {
+      s = \\c => ip.s ! c ++ adv.s ;
+      a = ip.a
+      } ;
+
+    IdetCN idet cn = 
+      let 
+        g = cn.g ;
+        n = idet.n ;
+        a = aagr g n
+      in {
+      s = \\c => idet.s ! g ! c ++ cn.s ! n ; 
+      a = a
+      } ;
+
+    IdetIP idet = 
+      let 
+        g = Masc ; ---- Fem in Extra
+        n = idet.n ;
+        a = aagr g n
+      in {
+      s = \\c => idet.s ! g ! c ; 
+      a = a
+      } ;
+
+    IdetQuant idet num = 
+      let 
+        n = num.n ;
+      in {
+      s = \\g,c => idet.s ! n ! g ! c ++ num.s ! g ;
+      n = n
+      } ;
+
+
+    CompIAdv a = {s = \\_  => a.s} ;
+
+    CompIP p = {s = \\_  => p.s ! Nom} ;
+
+}
+
+{- ---b 
+    IDetCN idet num ord cn = 
+      let 
+        g = cn.g ;
+        n = idet.n ;
+        a = aagr g n
+      in {
+      s = \\c => idet.s ! g ! c ++ num.s ! g ++ ord.s ! a ++ cn.s ! n ; 
+      a = a
+      } ;
+-}
-- 
cgit v1.2.3