From d09777a9aaeb580d8e793ad5e572296eb4c351d9 Mon Sep 17 00:00:00 2001
From: aarne <unknown>
Date: Thu, 29 Jan 2004 12:57:32 +0000
Subject: New order among numerals.

---
 examples/numerals/danish.gf | 44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 examples/numerals/danish.gf

(limited to 'examples/numerals/danish.gf')

diff --git a/examples/numerals/danish.gf b/examples/numerals/danish.gf
new file mode 100644
index 000000000..d1f97525f
--- /dev/null
+++ b/examples/numerals/danish.gf
@@ -0,0 +1,44 @@
+include numerals.Abs.gf ;
+
+-- AR 12/10/2002 following www.geocities.com/tsca.geo/dansk/dknummer.html
+
+param DForm = ental  | ton  | tiotal  ;
+
+lincat Numeral = {s : Str} ;
+lincat Digit = {s : DForm => Str} ;
+lincat Sub10 = {s : DForm => Str} ;
+lincat Sub100 = {s : Str} ;
+lincat Sub1000 = {s : Str} ;
+lincat Sub1000000 = {s : Str} ;
+
+oper mkTal : Str -> Str -> Str -> Lin Digit = 
+  \to, tolv, tyve -> 
+  {s = table {ental => to ; ton => tolv ; tiotal => tyve}} ;
+oper regTal : Str -> Lin Digit = \fem -> mkTal fem (fem + "ton") (fem + "tio") ;
+oper ss : Str -> {s : Str} = \s -> {s = s} ;
+
+lin num x = x ;
+
+lin n2 = mkTal "to"   "tolv"    "tyve" ;
+lin n3 = mkTal "tre"  "tretten" "tredive" ;
+lin n4 = mkTal "fire" "fjorten" "fyrre" ;
+lin n5 = mkTal "fem"  "femten"  "halvtreds" ;
+lin n6 = mkTal "seks" "seksten" "tres" ;
+lin n7 = mkTal "syv"  "sytten"  "halvfjerds" ;
+lin n8 = mkTal "otte" "atten"   "firs" ;
+lin n9 = mkTal "ni"   "nitten"  "halvfems" ;
+
+lin pot01 = {s = table {f => "en"}} ; ---
+lin pot0 d = {s = table {f => d.s ! f}} ;
+lin pot110 = ss "ti" ;
+lin pot111 = ss "elleve" ;
+lin pot1to19 d = ss (d.s ! ton) ;
+lin pot0as1 n = ss (n.s ! ental) ;
+lin pot1 d = ss (d.s ! tiotal) ;
+lin pot1plus d e = ss (e.s ! ental ++ "og" ++ d.s ! tiotal) ;
+lin pot1as2 n = n ;
+lin pot2 d = ss (d.s ! ental ++ "hundrede") ;
+lin pot2plus d e = ss (d.s ! ental ++ "hundrede" ++ "og" ++ e.s) ;
+lin pot2as3 n = n ;
+lin pot3 n = ss (n.s ++ "tusind") ;
+lin pot3plus n m = ss (n.s ++ "tusind" ++ "og" ++ m.s) ; ---
-- 
cgit v1.2.3