From 10f621045a53c3a2b75195f355e362537ac6f08b Mon Sep 17 00:00:00 2001
From: aarne <aarne@cs.chalmers.se>
Date: Thu, 6 Sep 2007 11:34:53 +0000
Subject: ExtFoods for book

---
 examples/tutorial/resource-foods/ExtFoodsI.gf | 49 +++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 examples/tutorial/resource-foods/ExtFoodsI.gf

(limited to 'examples/tutorial/resource-foods/ExtFoodsI.gf')

diff --git a/examples/tutorial/resource-foods/ExtFoodsI.gf b/examples/tutorial/resource-foods/ExtFoodsI.gf
new file mode 100644
index 000000000..57b8c1cf1
--- /dev/null
+++ b/examples/tutorial/resource-foods/ExtFoodsI.gf
@@ -0,0 +1,49 @@
+incomplete concrete ExtFoodsI of ExtFoods = FoodsI ** open Syntax, LexFoods in {
+
+  flags lexer=text ; unlexer=text ;
+
+  lincat
+    Move = Text ;
+    Verb = V2 ;
+    Guest = NP ;
+    GuestKind = N ;
+  lin
+    MAssert p = mkText (mkS p) ;
+    MDeny p = mkText (mkS negativePol p) ;
+    MAsk p = mkText (mkQS p) ;
+
+    PVerb = mkCl ;
+    PVerbWant guest verb item = mkCl guest want_VV (mkVP verb item) ;
+
+    WhichVerb kind guest verb = 
+      mkText (mkQS (mkQCl (mkIP whichSg_IDet kind) guest verb)) ;
+    WhichVerbWant kind guest verb = 
+      mkText (mkQS (mkQCl (mkIP whichSg_IDet kind) 
+        (mkSlash guest want_VV verb))) ;
+    WhichIs kind quality = 
+      mkText (mkQS (mkQCl (mkIP whichSg_IDet kind) (mkVP quality))) ;
+
+    Do verb item = 
+      mkText 
+        (mkPhr (mkUtt politeImpForm (mkImp verb item))) exclMarkPunct ;
+    DoPlease verb item = 
+      mkText 
+        (mkPhr (mkUtt politeImpForm (mkImp verb item)) please_Voc) 
+        exclMarkPunct ;
+
+    I = mkNP i_Pron ;
+    You = mkNP youPol_Pron ;
+    We = mkNP we_Pron ;
+
+    GThis = mkNP this_QuantSg ;
+    GThat = mkNP that_QuantSg ;
+    GThese = mkNP these_QuantPl ;
+    GThose = mkNP those_QuantPl ;
+
+    Eat = eat_V2 ;
+    Drink = drink_V2 ;
+    Pay = pay_V2 ;
+    Lady = lady_N ;
+    Gentleman = gentleman_N ;
+
+}
-- 
cgit v1.2.3