From 98665df78b8018af30051cb4a9a31f845e0ba19d Mon Sep 17 00:00:00 2001
From: aarne <aarne@cs.chalmers.se>
Date: Mon, 22 Sep 2008 11:49:15 +0000
Subject: moved lib/next-resource to next-lib/src, to enable linking with
 next-lib as value of GF_LIB_PATH

---
 next-lib/src/finnish/RelativeFin.gf | 50 +++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 next-lib/src/finnish/RelativeFin.gf

(limited to 'next-lib/src/finnish/RelativeFin.gf')

diff --git a/next-lib/src/finnish/RelativeFin.gf b/next-lib/src/finnish/RelativeFin.gf
new file mode 100644
index 000000000..9aab4e869
--- /dev/null
+++ b/next-lib/src/finnish/RelativeFin.gf
@@ -0,0 +1,50 @@
+concrete RelativeFin of Relative = CatFin ** open Prelude, ResFin, MorphoFin in {
+
+  flags optimize=all_subs ;
+
+  lin
+
+    RelCl cl = {
+      s = \\t,a,p,_ => "siten" ++ "että" ++ cl.s ! t ! a ! p ! SDecl ;
+      ---- sellainen
+      c = NPCase Nom
+      } ;
+
+    RelVP rp vp = {
+      s = \\t,ant,b,ag => 
+        let 
+          agr = case rp.a of {
+            RNoAg => ag ;
+            RAg a => a
+            } ;
+          cl = mkClause 
+             (subjForm {s = rp.s ! agr.n ; 
+                        a = agr ; isPron = False} vp.sc) agr vp
+        in
+        cl.s ! t ! ant ! b ! SDecl ;
+      c = NPCase Nom
+      } ;
+
+    RelSlash rp slash = {
+      s = \\t,a,p,ag => 
+            let 
+              cls = slash.s ! t ! a ! p ;
+              who = appCompl True p slash.c2 (rp2np ag.n rp)
+            in
+            who ++ cls ;
+      c = slash.c2.c
+      } ;
+
+    FunRP p np rp = {
+      s = \\n,c => appCompl True Pos p (rp2np n rp) ++ np.s ! c ; --- is c OK?
+      a = RAg np.a
+      } ;
+
+    IdRP = {
+      s = \\n,c => relPron ! n ! npform2case n c ;
+      a = RNoAg
+      } ;
+
+
+
+}
-- 
cgit v1.2.3