From 766852a64c9816f073100ff720cf7bafab39c043 Mon Sep 17 00:00:00 2001
From: aarne <aarne@cs.chalmers.se>
Date: Mon, 22 Sep 2008 12:24:28 +0000
Subject: adapted German to 1.5

---
 next-lib/src/german/RelativeGer.gf | 48 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 next-lib/src/german/RelativeGer.gf

(limited to 'next-lib/src/german/RelativeGer.gf')

diff --git a/next-lib/src/german/RelativeGer.gf b/next-lib/src/german/RelativeGer.gf
new file mode 100644
index 000000000..2605ed3a4
--- /dev/null
+++ b/next-lib/src/german/RelativeGer.gf
@@ -0,0 +1,48 @@
+concrete RelativeGer of Relative = CatGer ** open ResGer in {
+
+  flags optimize=all_subs ;
+
+  lin
+
+    RelCl cl = {
+      s = \\m,t,a,b,_ => "derart" ++ conjThat ++ cl.s ! m ! t ! a ! b ! Sub ;
+      c = Nom
+      } ;
+
+    RelVP rp vp = {
+      s = \\m,t,ant,b,gn => 
+        let 
+          agr = case rp.a of {
+            RNoAg => agrP3 (numGenNum gn) ;
+            RAg a => a ** {g = Neutr}
+            } ;
+          cl = mkClause (rp.s ! gn ! Nom) agr vp
+        in
+        cl.s ! m ! t ! ant ! b ! Sub ;
+      c = Nom
+      } ;
+
+    RelSlash rp slash = {
+      s = \\m,t,a,p,gn => 
+          appPrep slash.c2 (rp.s ! gn) ++ slash.s ! m ! t ! a ! p ! Sub ;
+      c = slash.c2.c
+      } ;
+
+    FunRP p np rp = {
+      s = \\gn,c => np.s ! c ++ appPrep p (rp.s ! gn) ;
+      a = RAg {n = np.a.n ; p = np.a.p}
+      } ;
+
+    IdRP = {s = relPron ; a = RNoAg} ;
+
+  oper
+      relPron :  GenNum => Case => Str = \\gn,c =>
+    case <gn,c> of {
+      <GSg Fem,Gen> => "deren" ;
+      <GSg g,Gen>   => "dessen" ;
+      <GPl,Dat>     => "denen" ;
+      <GPl,Gen>     => "deren" ;
+      _ => artDef ! gn ! c
+      } ;
+
+}
-- 
cgit v1.2.3