From e9e80fc389365e24d4300d7d5390c7d833a96c50 Mon Sep 17 00:00:00 2001
From: aarne <aarne@cs.chalmers.se>
Date: Wed, 25 Jun 2008 16:54:35 +0000
Subject: changed names of resource-1.3; added a note on homepage on release

---
 old-examples/tutorial/foods/FoodsEng.gf | 52 +++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 old-examples/tutorial/foods/FoodsEng.gf

(limited to 'old-examples/tutorial/foods/FoodsEng.gf')

diff --git a/old-examples/tutorial/foods/FoodsEng.gf b/old-examples/tutorial/foods/FoodsEng.gf
new file mode 100644
index 000000000..69a427006
--- /dev/null
+++ b/old-examples/tutorial/foods/FoodsEng.gf
@@ -0,0 +1,52 @@
+--# -path=.:prelude
+
+concrete FoodsEng of Foods = open Prelude in {
+
+  lincat
+    Phrase, Quality = SS ; 
+    Kind = {s : Number => Str} ; 
+    Item = {s : Str ; n : Number} ; 
+
+  lin
+    Is item quality = ss (item.s ++ copula ! item.n ++ quality.s) ;
+    This  = det Sg "this" ;
+    That  = det Sg "that" ;
+    These = det Pl "these" ;
+    Those = det Pl "those" ;
+    QKind quality kind = {s = \\n => quality.s ++ kind.s ! n} ;
+    Wine = regNoun "wine" ;
+    Cheese = regNoun "cheese" ;
+    Fish = noun "fish" "fish" ;
+    Pizza = regNoun "pizza" ;
+    Very = prefixSS "very" ;
+    Fresh = ss "fresh" ;
+    Warm = ss "warm" ;
+    Italian = ss "Italian" ;
+    Expensive = ss "expensive" ;
+    Delicious = ss "delicious" ;
+    Boring = ss "boring" ;
+
+  param
+    Number = Sg | Pl ;
+
+  oper
+    det : Number -> Str -> {s : Number => Str} -> {s : Str ; n : Number} = 
+      \n,d,cn -> {
+        s = d ++ cn.s ! n ;
+        n = n
+      } ;
+    noun : Str -> Str -> {s : Number => Str} = 
+      \man,men -> {s = table {
+        Sg => man ;
+        Pl => men 
+        }
+      } ;
+    regNoun : Str -> {s : Number => Str} = 
+      \car -> noun car (car + "s") ;
+    copula : Number => Str = 
+      table {
+        Sg => "is" ;
+        Pl => "are"
+        } ;
+}
+    
-- 
cgit v1.2.3