From e89fdae2fa1626348d8025824a7469252fa85e42 Mon Sep 17 00:00:00 2001
From: aarne <aarne@chalmers.se>
Date: Mon, 22 Jun 2009 15:39:08 +0000
Subject: next-lib renamed to lib, lib to old-lib

---
 old-lib/resource/english/RelativeEng.gf | 54 +++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 old-lib/resource/english/RelativeEng.gf

(limited to 'old-lib/resource/english/RelativeEng.gf')

diff --git a/old-lib/resource/english/RelativeEng.gf b/old-lib/resource/english/RelativeEng.gf
new file mode 100644
index 000000000..1ec1fc10a
--- /dev/null
+++ b/old-lib/resource/english/RelativeEng.gf
@@ -0,0 +1,54 @@
+concrete RelativeEng of Relative = CatEng ** open ResEng in {
+
+  flags optimize=all_subs ;
+
+  lin
+
+    RelCl cl = {
+      s = \\t,a,p,_ => "such" ++ "that" ++ cl.s ! t ! a ! p ! ODir ; 
+      c = Nom
+      } ;
+
+    RelVP rp vp = {
+      s = \\t,ant,b,ag => 
+        let 
+          agr = case rp.a of {
+            RNoAg => ag ;
+            RAg a => a
+            } ;
+          cl = mkClause (rp.s ! RC (fromAgr agr).g Nom) agr vp
+        in
+        cl.s ! t ! ant ! b ! ODir ;
+      c = Nom
+      } ;
+
+-- Pied piping: "at which we are looking". Stranding and empty
+-- relative are defined in $ExtraEng.gf$ ("that we are looking at", 
+-- "we are looking at").
+
+    RelSlash rp slash = {
+      s = \\t,a,p,agr => 
+          slash.c2 ++ rp.s ! RPrep (fromAgr agr).g ++ slash.s ! t ! a ! p ! ODir ;
+      c = Acc
+      } ;
+
+    FunRP p np rp = {
+      s = \\c => np.s ! Acc ++ p.s ++ rp.s ! RPrep (fromAgr np.a).g ;
+      a = RAg np.a
+      } ;
+
+    IdRP = 
+      let varr : Str -> Str = \x -> variants {x ; "that"} --- for bwc
+      in {
+      s = table {
+        RC _ Gen => "whose" ; 
+        RC Neutr _  => varr "which" ;
+        RC _ Acc    => varr "whom" ;
+        RC _ Nom    => varr "who" ;
+        RPrep Neutr => "which" ;
+        RPrep _     => "whom"
+        } ;
+      a = RNoAg
+      } ;
+
+}
-- 
cgit v1.2.3