started examples-3.0 with examples that are tested to work

5 files changed, 128 insertions, 0 deletions

diff --git a/examples-3.0/tutorial/calculator/Calculator.gf b/examples-3.0/tutorial/calculator/Calculator.gf
new file mode 100644
index 000000000..65192e226
--- /dev/null
+++ b/examples-3.0/tutorial/calculator/Calculator.gf
@@ -0,0 +1,25 @@
+abstract Calculator = {
+
+  flags startcat = Prog ;
+
+  cat Prog ; Exp ; Var ;
+
+  fun
+    PEmpty : Prog ;
+    PInit  : Exp -> (Var -> Prog) -> Prog ;
+    PAss   : Var -> Exp  -> Prog  -> Prog ;
+
+    EPlus, EMinus, ETimes, EDiv : Exp -> Exp -> Exp ;
+
+    EInt : Int -> Exp ;
+    EVar : Var -> Exp ;
+
+    ex1 : Prog ;
+
+  def
+    ex1 = 
+      PInit (EPlus (EInt 2) (EInt 3)) (\x -> 
+        PInit (EPlus (EVar x) (EInt 1)) (\y -> 
+          PAss x (EPlus (EVar x) (ETimes (EInt 9) (EVar y))) PEmpty)) ;
+
+}
diff --git a/examples-3.0/tutorial/calculator/CalculatorC.gf b/examples-3.0/tutorial/calculator/CalculatorC.gf
new file mode 100644
index 000000000..53eade357
--- /dev/null
+++ b/examples-3.0/tutorial/calculator/CalculatorC.gf
@@ -0,0 +1,24 @@
+--# -path=.:prelude
+
+concrete CalculatorC of Calculator = open Prelude, Formal in {
+
+  flags lexer=codevars ; unlexer=code ;
+
+  lincat 
+    Prog, Var = SS ; 
+    Exp = TermPrec ;
+
+  lin
+    PEmpty = ss [] ;
+    PInit exp prog = ss ("int" ++ prog.$0 ++ "=" ++ top exp ++ ";" ++ prog.s) ;
+    PAss vr exp prog = ss (vr.s ++ "=" ++ top exp ++ ";" ++ prog.s) ;
+
+    EPlus  = infixl 0 "+" ;
+    EMinus = infixl 0 "-" ;
+    ETimes = infixl 1 "*" ;
+    EDiv   = infixl 1 "/" ;
+
+    EInt i = constant i.s ;
+    EVar x = constant x.s ;
+
+}
diff --git a/examples-3.0/tutorial/calculator/CalculatorE.gf b/examples-3.0/tutorial/calculator/CalculatorE.gf
new file mode 100644
index 000000000..f432d371a
--- /dev/null
+++ b/examples-3.0/tutorial/calculator/CalculatorE.gf
@@ -0,0 +1,27 @@
+--# -path=.:prelude
+
+concrete CalculatorE of Calculator = open Prelude in {
+
+  flags lexer=codevar ; unlexer=unwords ;
+
+  lincat 
+    Prog, Exp, Var = SS ;
+
+  lin
+    PEmpty = ss [] ;
+    PInit exp prog = ss ("initialize" ++ prog.$0 ++ "as" ++ exp.s ++ PAUSE ++ prog.s) ;
+    PAss vr exp prog = ss ("redefine" ++ vr.s ++ "as" ++ exp.s ++ PAUSE ++ prog.s) ;
+
+    EPlus  = infix "plus" ;
+    EMinus = infix "minus" ;
+    ETimes = infix "times" ;
+    EDiv   = infix ["divided by"] ;
+
+    EInt i = i ;
+    EVar x = x ;
+
+  oper
+    infix : Str -> SS -> SS -> SS = \op,x,y -> 
+      ss (x.s ++ op ++ y.s ++ PAUSE) ;
+    PAUSE = "PAUSE" ;
+}
diff --git a/examples-3.0/tutorial/calculator/CalculatorJ.gf b/examples-3.0/tutorial/calculator/CalculatorJ.gf
new file mode 100644
index 000000000..68ff5342c
--- /dev/null
+++ b/examples-3.0/tutorial/calculator/CalculatorJ.gf
@@ -0,0 +1,25 @@
+--# -path=.:prelude
+
+concrete CalculatorJ of Calculator = open Prelude in {
+
+  flags lexer=codevars ; unlexer=code ;
+
+  lincat 
+    Prog, Exp, Var = SS ;
+
+  lin
+    PEmpty = ss [] ;
+    PInit exp prog = ss (exp.s ++ ";" ++ "istore" ++ prog.$0 ++ ";" ++ prog.s) ;
+    PAss vr exp prog = ss (exp.s ++ ";" ++ "istore" ++ vr.s ++ ";" ++ prog.s) ;
+
+    EPlus  = postfix "iadd" ;
+    EMinus = postfix "isub" ;
+    ETimes = postfix "imul" ;
+    EDiv   = postfix "idiv" ;
+
+    EInt = prefixSS "iconst" ;
+    EVar = prefixSS "iload" ;
+
+  oper
+    postfix : Str -> SS -> SS -> SS = \op,x,y -> ss (x.s ++ ";" ++ y.s ++ ";" ++ op) ;
+}
diff --git a/examples-3.0/tutorial/calculator/CalculatorP.gf b/examples-3.0/tutorial/calculator/CalculatorP.gf
new file mode 100644
index 000000000..57ac549c1
--- /dev/null
+++ b/examples-3.0/tutorial/calculator/CalculatorP.gf
@@ -0,0 +1,27 @@
+--# -path=.:prelude
+
+concrete CalculatorP of Calculator = open Prelude in {
+
+  flags lexer=codevars ; unlexer=code ;
+
+  lincat 
+    Prog, Var = SS ; 
+    Exp = SS ;
+
+  lin
+    PEmpty = ss [] ;
+    PDecl exp prog = ss ("int" ++ prog.$0 ++ "=" ++ exp.s ++ ";" ++ prog.s) ;
+    PAss vr exp prog = ss (vr.s ++ "=" ++ exp.s ++ ";" ++ prog.s) ;
+
+    EPlus  = infix "+" ;
+    EMinus = infix "-" ;
+    ETimes = infix "*" ;
+    EDiv   = infix "/" ;
+
+    EInt i = i ;
+    EVar x = x ;
+
+  oper
+    infix : Str -> SS -> SS -> SS = \f,x,y -> 
+      ss ("(" ++ x.s ++ f ++ y.s ++ ")") ;
+}