calculator ex

3 files changed, 96 insertions, 0 deletions

diff --git a/examples/tutorial/calculator/Calculator.gf b/examples/tutorial/calculator/Calculator.gf
new file mode 100644
index 000000000..0d67c1e21
--- /dev/null
+++ b/examples/tutorial/calculator/Calculator.gf
@@ -0,0 +1,25 @@
+abstract Calculator = {
+
+  flags startcat = Prog ;
+
+  cat Prog ; Exp ; Var ;
+
+  fun
+    PEmpty : Prog ;
+    PDecl  : Exp -> (Var -> Prog) -> Prog ;
+    PAss   : Var -> Exp  -> Prog  -> Prog ;
+
+    EPlus, EMinus, ETimes : Exp -> Exp -> Exp ;
+
+    EInt : Int -> Exp ;
+    EVar : Var -> Exp ;
+
+    ex1 : Prog ;
+
+  def
+    ex1 = 
+      PDecl (EPlus (EInt 2) (EInt 3)) (\x -> 
+        PDecl (EPlus (EVar x) (EInt 1)) (\y -> 
+          PAss x (EPlus (EVar x) (ETimes (EInt 9) (EVar y))) PEmpty)) ;
+
+}
diff --git a/examples/tutorial/calculator/CalculatorC.gf b/examples/tutorial/calculator/CalculatorC.gf
new file mode 100644
index 000000000..f78d4f38b
--- /dev/null
+++ b/examples/tutorial/calculator/CalculatorC.gf
@@ -0,0 +1,47 @@
+--# -path=.:prelude
+
+concrete CalculatorC of Calculator = open Prelude in {
+
+  flags lexer=codevars ; unlexer=code ;
+
+  lincat 
+    Prog, Var = SS ; 
+    Exp = TermPrec ;
+
+  lin
+    PEmpty = ss [] ;
+    PDecl exp prog = ss ("int" ++ prog.$0 ++ "=" ++ exp.s ++ ";" ++ prog.s) ;
+    PAss vr exp prog = ss (vr.s ++ "=" ++ exp.s ++ ";" ++ prog.s) ;
+
+    EPlus  = infixl 0 "+" ;
+    EMinus = infixl 0 "-" ;
+    ETimes = infixl 1 "*" ;
+
+    EInt i = constant i.s ;
+    EVar x = constant x.s ;
+
+  oper
+    Prec : PType = Predef.Ints 2 ;
+    TermPrec : Type = {s : Str ; p : Prec} ;
+
+    usePrec : TermPrec -> Prec -> Str = \x,p ->
+      case <<x.p,p> : Prec * Prec> of {
+        <1,1> | <1,0> | <0,0> => x.s ;
+        <1,_> | <0,_>         => "(" ++ x.s ++ ")" ;
+        _ => x.s
+        } ;
+
+    mkPrec : Prec -> Str -> TermPrec = \p,s -> 
+      {s = s ; p = p} ;
+
+    constant : Str -> TermPrec = mkPrec 2 ;
+
+    infixl : Prec -> Str -> (_,_ : TermPrec) -> TermPrec = \p,f,x,y ->
+      mkPrec p (usePrec x p ++ f ++ usePrec y (nextPrec p)) ;
+
+    nextPrec : Prec -> Prec = \p -> case <p : Prec> of {
+      2 => 2 ; 
+      n => Predef.plus n 1
+      } ;
+
+}
diff --git a/examples/tutorial/calculator/CalculatorJ.gf b/examples/tutorial/calculator/CalculatorJ.gf
new file mode 100644
index 000000000..15b2caffd
--- /dev/null
+++ b/examples/tutorial/calculator/CalculatorJ.gf
@@ -0,0 +1,24 @@
+--# -path=.:prelude
+
+concrete CalculatorJ of Calculator = open Prelude in {
+
+  flags lexer=codevars ; unlexer=code ;
+
+  lincat 
+    Prog, Exp, Var = SS ;
+
+  lin
+    PEmpty = ss [] ;
+    PDecl exp prog = ss (exp.s ++ ";" ++ prog.s) ;
+    PAss vr exp prog = ss (exp.s ++ ";" ++ "istore" ++ vr.s ++ ";" ++ prog.s) ;
+
+    EPlus  = postfix "iadd" ;
+    EMinus = postfix "isub" ;
+    ETimes = postfix "imul" ;
+
+    EInt = prefixSS "iconst" ;
+    EVar = prefixSS "iload" ;
+
+  oper
+    postfix : Str -> SS -> SS -> SS = \op,x,y -> ss (x.s ++ ";" ++ y.s ++ ";" ++ op) ;
+}