moved lib/next-resource to next-lib/src, to enable linking with next-lib as value of GF_LIB_PATH

1 files changed, 24 insertions, 0 deletions

diff --git a/next-lib/src/english/PhraseEng.gf b/next-lib/src/english/PhraseEng.gf
new file mode 100644
index 000000000..c635d4b98
--- /dev/null
+++ b/next-lib/src/english/PhraseEng.gf
@@ -0,0 +1,24 @@
+concrete PhraseEng of Phrase = CatEng ** open Prelude, ResEng in {
+
+  lin
+    PhrUtt pconj utt voc = {s = pconj.s ++ utt.s ++ voc.s} ;
+
+    UttS s = s ;
+    UttQS qs = {s = qs.s ! QDir} ;
+    UttImpSg pol imp = {s = pol.s ++ imp.s ! contrNeg True pol.p ! ImpF Sg False} ;
+    UttImpPl pol imp = {s = pol.s ++ imp.s ! contrNeg True pol.p ! ImpF Pl False} ;
+    UttImpPol pol imp = {s = pol.s ++ imp.s ! contrNeg True pol.p ! ImpF Sg True} ;
+
+    UttIP ip = {s = ip.s ! Nom} ; --- Acc also
+    UttIAdv iadv = iadv ;
+    UttNP np = {s = np.s ! Nom} ;
+    UttVP vp = {s = infVP False vp (agrP3 Sg)} ;
+    UttAdv adv = adv ;
+
+    NoPConj = {s = []} ;
+    PConjConj conj = {s = conj.s2} ; ---
+
+    NoVoc = {s = []} ;
+    VocNP np = {s = "," ++ np.s ! Nom} ;
+
+}