next-lib renamed to lib, lib to old-lib

27 files changed, 3041 insertions, 0 deletions

diff --git a/old-lib/resource/english/AdjectiveEng.gf b/old-lib/resource/english/AdjectiveEng.gf
new file mode 100644
index 000000000..19dd5dddc
--- /dev/null
+++ b/old-lib/resource/english/AdjectiveEng.gf
@@ -0,0 +1,38 @@
+concrete AdjectiveEng of Adjective = CatEng ** open ResEng, Prelude in {
+
+  lin
+
+    PositA  a = {
+      s = \\_ => a.s ! AAdj Posit ;
+      isPre = True
+      } ;
+    ComparA a np = {
+      s = \\_ => a.s ! AAdj Compar ++ "than" ++ np.s ! Nom ; 
+      isPre = False
+      } ;
+
+-- $SuperlA$ belongs to determiner syntax in $Noun$.
+
+    ComplA2 a np = {
+      s = \\_ => a.s ! AAdj Posit ++ a.c2 ++ np.s ! Acc ; 
+      isPre = False
+      } ;
+
+    ReflA2 a = {
+      s = \\ag => a.s ! AAdj Posit ++ a.c2 ++ reflPron ! ag ; 
+      isPre = False
+      } ;
+
+    SentAP ap sc = {
+      s = \\a => ap.s ! a ++ sc.s ; 
+      isPre = False
+      } ;
+
+    AdAP ada ap = {
+      s = \\a => ada.s ++ ap.s ! a ;
+      isPre = ap.isPre
+      } ;
+
+    UseA2 a = a ;
+
+}
diff --git a/old-lib/resource/english/AdverbEng.gf b/old-lib/resource/english/AdverbEng.gf
new file mode 100644
index 000000000..ec7d46321
--- /dev/null
+++ b/old-lib/resource/english/AdverbEng.gf
@@ -0,0 +1,21 @@
+concrete AdverbEng of Adverb = CatEng ** open ResEng, Prelude in {
+
+  lin
+    PositAdvAdj a = {s = a.s ! AAdv} ;
+    ComparAdvAdj cadv a np = {
+      s = cadv.s ++ a.s ! AAdv ++ "than" ++ np.s ! Nom
+      } ;
+    ComparAdvAdjS cadv a s = {
+      s = cadv.s ++ a.s ! AAdv ++ "than" ++ s.s
+      } ;
+
+    PrepNP prep np = {s = prep.s ++ np.s ! Acc} ;
+
+    AdAdv = cc2 ;
+
+    SubjS = cc2 ;
+---b    AdvSC s = s ; --- this rule give stack overflow in ordinary parsing
+
+    AdnCAdv cadv = {s = cadv.s ++ "than"} ;
+
+}
diff --git a/old-lib/resource/english/AllEng.gf b/old-lib/resource/english/AllEng.gf
new file mode 100644
index 000000000..88b6e21f6
--- /dev/null
+++ b/old-lib/resource/english/AllEng.gf
@@ -0,0 +1,9 @@
+--# -path=.:../abstract:../common:prelude
+
+concrete AllEng of AllEngAbs = 
+  LangEng,
+  IrregEng-[
+    blow_V,burn_V,come_V,dig_V,fall_V,fly_V,freeze_V,go_V,lie_V,run_V,
+    sew_V,sing_V,sit_V,sleep_V,spit_V,stand_V,swell_V,swim_V,think_V],
+  ExtraEng
+  ** {} ;
diff --git a/old-lib/resource/english/AllEngAbs.gf b/old-lib/resource/english/AllEngAbs.gf
new file mode 100644
index 000000000..687d573a5
--- /dev/null
+++ b/old-lib/resource/english/AllEngAbs.gf
@@ -0,0 +1,9 @@
+--# -path=.:../abstract:../common:prelude
+
+abstract AllEngAbs = 
+  Lang,
+  IrregEngAbs-[
+    blow_V,burn_V,come_V,dig_V,fall_V,fly_V,freeze_V,go_V,lie_V,run_V,
+    sew_V,sing_V,sit_V,sleep_V,spit_V,stand_V,swell_V,swim_V,think_V],
+  ExtraEngAbs
+  ** {} ;
diff --git a/old-lib/resource/english/BackwardEng.gf b/old-lib/resource/english/BackwardEng.gf
new file mode 100644
index 000000000..630626f0b
--- /dev/null
+++ b/old-lib/resource/english/BackwardEng.gf
@@ -0,0 +1,76 @@
+concrete BackwardEng of Backward = CatEng ** open ResEng in {
+
+  flags optimize=all_subs ;
+
+  lin
+
+-- A repository of obsolete constructs, needed for backward compatibility.
+-- They create spurious ambiguities if used in combination with Lang.
+
+-- from Verb 19/4/2008
+
+    ComplV2 v np = insertObj (\\_ => v.c2 ++ np.s ! Acc) (predV v) ;
+    ComplV3 v np np2 = 
+      insertObj (\\_ => v.c2 ++ np.s ! Acc ++ v.c3 ++ np2.s ! Acc) (predV v) ;
+    ComplV2V v np vp = 
+      insertObj (\\a => infVP v.isAux vp a)
+        (insertObj (\\_ => v.c2 ++ np.s ! Acc) (predV v)) ;
+    ComplV2S v np s = 
+      insertObj (\\_ => conjThat ++ s.s)
+        (insertObj (\\_ => v.c2 ++ np.s ! Acc) (predV v)) ;
+    ComplV2Q v np q = 
+      insertObj (\\_ => q.s ! QIndir) 
+        (insertObj (\\_ => v.c2 ++ np.s ! Acc) (predV v)) ;
+    ComplV2A v np ap = 
+      insertObj (\\_ => v.c2 ++ np.s ! Acc ++ ap.s ! np.a) (predV v) ;
+
+    ReflV2 v = insertObj (\\a => v.c2 ++ reflPron ! a) (predV v) ;
+
+-- from Sentence 19/4/2008
+
+    SlashV2 np v2 = 
+      mkClause (np.s ! Nom) np.a (predV v2) ** {c2 = v2.c2} ;
+
+    SlashVVV2 np vv v2 = 
+      mkClause (np.s ! Nom) np.a 
+        (insertObj (\\a => infVP vv.isAux (predV v2) a) (predVV vv))  **
+        {c2 = v2.c2} ;
+
+-- from Noun 19/4/2008
+
+    NumInt n = {s = n.s ; n = Pl} ; 
+    OrdInt n = {s = n.s ++ "th"} ; --- DEPRECATED
+
+    DetSg quant ord = {
+      s = quant.s ! Sg ++ ord.s ; 
+      n = Sg
+      } ;
+
+    DetPl quant num ord = {
+      s = quant.s ! num.n ++ num.s ++ ord.s ; 
+      n = num.n
+      } ;
+
+    NoNum = {s = []; n = Pl } ;
+
+    DefArt = {s = \\_ => artDef} ;
+
+    IndefArt = {
+      s = table {
+        Sg => artIndef ; 
+        Pl => []
+        }
+      } ;
+
+    MassDet = {s = \\_ => []} ;
+
+
+
+-- from Structural 19/4/2008
+
+    that_NP = regNP "that" Sg ;
+    these_NP = regNP "these" Pl ;
+    this_NP = regNP "this" Sg ;
+    those_NP = regNP "those" Pl ;
+
+}
diff --git a/old-lib/resource/english/CatEng.gf b/old-lib/resource/english/CatEng.gf
new file mode 100644
index 000000000..bbc367f6c
--- /dev/null
+++ b/old-lib/resource/english/CatEng.gf
@@ -0,0 +1,89 @@
+concrete CatEng of Cat = CommonX ** open ResEng, Prelude in {
+
+  flags optimize=all_subs ;
+
+  lincat
+
+-- Tensed/Untensed
+
+    S  = {s : Str} ;
+    QS = {s : QForm => Str} ;
+    RS = {s : Agr => Str ; c : Case} ; -- c for it clefts
+    SSlash = {s : Str ; c2 : Str} ;
+
+-- Sentence
+
+    Cl = {s : ResEng.Tense => Anteriority => CPolarity => Order => Str} ;
+    ClSlash = {
+      s : ResEng.Tense => Anteriority => CPolarity => Order => Str ;
+      c2 : Str
+      } ;
+    Imp = {s : CPolarity => ImpForm => Str} ;
+
+-- Question
+
+    QCl = {s : ResEng.Tense => Anteriority => CPolarity => QForm => Str} ;
+    IP = {s : Case => Str ; n : Number} ;
+    IComp = {s : Str} ;    
+    IDet = {s : Str ; n : Number} ;
+    IQuant = {s : Number => Str} ;
+
+-- Relative
+
+    RCl = {
+      s : ResEng.Tense => Anteriority => CPolarity => Agr => Str ; 
+      c : Case
+      } ;
+    RP = {s : RCase => Str ; a : RAgr} ;
+
+-- Verb
+
+    VP = ResEng.VP ;
+    VPSlash = ResEng.VP ** {c2 : Str} ;
+    Comp = {s : Agr => Str} ; 
+
+-- Adjective
+
+    AP = {s : Agr => Str ; isPre : Bool} ; 
+
+-- Noun
+
+    CN = {s : Number => Case => Str ; g : Gender} ;
+    NP, Pron = {s : Case => Str ; a : Agr} ;
+    Det = {s : Str ; n : Number} ;
+    Predet, Ord = {s : Str} ;
+    Num  = {s : Str; n : Number ; hasCard : Bool} ;
+    Card = {s : Str; n : Number} ;
+    Quant = {s : Number => Str} ;
+    Art = {s : Bool => Number => Str} ;
+
+-- Numeral
+
+    Numeral = {s : CardOrd => Str ; n : Number} ;
+    Digits  = {s : CardOrd => Str ; n : Number ; tail : DTail} ;
+
+-- Structural
+
+    Conj = {s1,s2 : Str ; n : Number} ;
+---b    Conj = {s : Str ; n : Number} ;
+---b    DConj = {s1,s2 : Str ; n : Number} ;
+    Subj = {s : Str} ;
+    Prep = {s : Str} ;
+
+-- Open lexical classes, e.g. Lexicon
+
+    V, VS, VQ, VA = Verb ; -- = {s : VForm => Str} ;
+    V2, V2A, V2Q, V2S = Verb ** {c2 : Str} ;
+    V3 = Verb ** {c2, c3 : Str} ;
+    VV = {s : VVForm => Str ; isAux : Bool} ;
+    V2V = Verb ** {c2 : Str ; isAux : Bool} ;
+
+    A = {s : AForm => Str} ;
+    A2 = {s : AForm => Str ; c2 : Str} ;
+
+    N = {s : Number => Case => Str ; g : Gender} ;
+    N2 = {s : Number => Case => Str ; g : Gender} ** {c2 : Str} ;
+    N3 = {s : Number => Case => Str ; g : Gender} ** {c2,c3 : Str} ;
+    PN = {s : Case => Str ; g : Gender} ;
+
+}
diff --git a/old-lib/resource/english/CompatibilityEng.gf b/old-lib/resource/english/CompatibilityEng.gf
new file mode 100644
index 000000000..28ede2a17
--- /dev/null
+++ b/old-lib/resource/english/CompatibilityEng.gf
@@ -0,0 +1,11 @@
+--# -path=.:../abstract:../common
+
+concrete CompatibilityEng of Compatibility = CatEng ** open Prelude, ResEng in {
+
+-- from Noun 19/4/2008
+
+lin
+    NumInt n = {s = n.s ; n = Pl ; hasCard = True} ; 
+    OrdInt n = {s = n.s ++ "th"} ;
+
+}
diff --git a/old-lib/resource/english/ConjunctionEng.gf b/old-lib/resource/english/ConjunctionEng.gf
new file mode 100644
index 000000000..269ae5f80
--- /dev/null
+++ b/old-lib/resource/english/ConjunctionEng.gf
@@ -0,0 +1,60 @@
+concrete ConjunctionEng of Conjunction = 
+  CatEng ** open ResEng, Coordination, Prelude in {
+
+  flags optimize=all_subs ;
+
+  lin
+
+    ConjS = conjunctDistrSS ;
+
+    ConjAdv = conjunctDistrSS ;
+
+    ConjNP conj ss = conjunctDistrTable Case conj ss ** {
+      a = conjAgr (agrP3 conj.n) ss.a
+      } ;
+
+    ConjAP conj ss = conjunctDistrTable Agr conj ss ** {
+      isPre = ss.isPre
+      } ;
+
+{---b
+
+    ConjS = conjunctSS ;
+    DConjS = conjunctDistrSS ;
+
+    ConjAdv = conjunctSS ;
+    DConjAdv = conjunctDistrSS ;
+
+    ConjNP conj ss = conjunctTable Case conj ss ** {
+      a = conjAgr (agrP3 conj.n) ss.a 
+      } ;
+    DConjNP conj ss = conjunctDistrTable Case conj ss ** {
+      a = conjAgr (agrP3 conj.n) ss.a
+      } ;
+
+    ConjAP conj ss = conjunctTable Agr conj ss ** {
+      isPre = ss.isPre
+      } ;
+    DConjAP conj ss = conjunctDistrTable Agr conj ss ** {
+      isPre = ss.isPre
+      } ;
+-}
+
+-- These fun's are generated from the list cat's.
+
+    BaseS = twoSS ;
+    ConsS = consrSS comma ;
+    BaseAdv = twoSS ;
+    ConsAdv = consrSS comma ;
+    BaseNP x y = twoTable Case x y ** {a = conjAgr x.a y.a} ;
+    ConsNP xs x = consrTable Case comma xs x ** {a = conjAgr xs.a x.a} ;
+    BaseAP x y = twoTable Agr x y ** {isPre = andB x.isPre y.isPre} ;
+    ConsAP xs x = consrTable Agr comma xs x ** {isPre = andB xs.isPre x.isPre} ;
+
+  lincat
+    [S] = {s1,s2 : Str} ;
+    [Adv] = {s1,s2 : Str} ;
+    [NP] = {s1,s2 : Case => Str ; a : Agr} ;
+    [AP] = {s1,s2 : Agr => Str ; isPre : Bool} ;
+
+}
diff --git a/old-lib/resource/english/ExtraEng.gf b/old-lib/resource/english/ExtraEng.gf
new file mode 100644
index 000000000..7f6b3fde3
--- /dev/null
+++ b/old-lib/resource/english/ExtraEng.gf
@@ -0,0 +1,53 @@
+concrete ExtraEng of ExtraEngAbs = CatEng ** 
+  open ResEng, Coordination, Prelude in {
+
+  lin
+    GenNP np = {s = \\_ => np.s ! Gen} ;
+    ComplBareVS v s  = insertObj (\\_ => s.s) (predV v) ;
+
+    StrandRelSlash rp slash = {
+      s = \\t,a,p,ag => 
+        rp.s ! RC (fromAgr ag).g Acc ++ slash.s ! t ! a ! p ! ODir ++ slash.c2 ;
+      c = Acc
+      } ;
+    EmptyRelSlash rp slash = {
+      s = \\t,a,p,_ => slash.s ! t ! a ! p ! ODir ++ slash.c2 ;
+      c = Acc
+      } ;
+
+    StrandQuestSlash ip slash = 
+      {s = \\t,a,b,q => 
+         (mkQuestion (ss (ip.s ! Acc)) slash).s ! t ! a ! b ! q ++ slash.c2
+      };
+
+  lincat
+    VPI   = {s : VPIForm => Agr => Str} ;
+    [VPI] = {s1,s2 : VPIForm => Agr => Str} ;
+
+  lin
+    BaseVPI = twoTable2 VPIForm Agr ;
+    ConsVPI = consrTable2 VPIForm Agr comma ;
+
+    MkVPI vp = {
+      s = \\v,a => vp.ad ++ vp.inf ++ vp.s2 ! a
+      } ;
+    ConjVPI = conjunctDistrTable2 VPIForm Agr ;
+    ComplVPIVV vv vpi = 
+      insertObj (\\a => (if_then_Str vv.isAux [] "to") ++ vpi.s ! VPIInf ! a) (predVV vv) ;
+
+    UncNegCl  t a cl = {s = t.s ++ a.s ++ cl.s ! t.t ! a.a ! neg ! ODir} ;
+    UncNegQCl t a cl = {s = \\q => t.s ++ a.s ++ cl.s ! t.t ! a.a ! neg !q} ;
+    UncNegRCl t a cl = {
+      s = \\r => t.s ++ a.s ++ cl.s ! t.t ! a.a ! neg ! r ;
+      c = cl.c
+      } ;
+    UncNegImpSg imp = {s = imp.s ! neg ! ImpF Sg False} ;
+    UncNegImpPl imp = {s = imp.s ! neg ! ImpF Pl False} ;
+
+    CompoundCN a b = {s = \\n,c => a.s ! Sg ! Nom ++ b.s ! n ! c ; g = b.g} ;
+
+
+  oper
+    neg = CNeg False ; 
+
+} 
diff --git a/old-lib/resource/english/ExtraEngAbs.gf b/old-lib/resource/english/ExtraEngAbs.gf
new file mode 100644
index 000000000..9ee849627
--- /dev/null
+++ b/old-lib/resource/english/ExtraEngAbs.gf
@@ -0,0 +1,16 @@
+abstract ExtraEngAbs = Extra ** {
+
+-- uncontracted negations; contracted are the default
+  fun
+    UncNegCl  : Tense -> Ant -> Cl  -> S ;
+    UncNegQCl : Tense -> Ant -> QCl -> QS ;
+    UncNegRCl : Tense -> Ant -> RCl -> RS ;
+
+    UncNegImpSg : Imp -> Utt;           -- do not help yourself
+    UncNegImpPl : Imp -> Utt;           -- do not help yourselves
+
+-- freely compounded nouns
+
+    CompoundCN : CN -> CN -> CN ;       -- rock album
+
+}
diff --git a/old-lib/resource/english/GrammarEng.gf b/old-lib/resource/english/GrammarEng.gf
new file mode 100644
index 000000000..932dd9821
--- /dev/null
+++ b/old-lib/resource/english/GrammarEng.gf
@@ -0,0 +1,21 @@
+--# -path=.:../abstract:../common:prelude
+
+concrete GrammarEng of Grammar = 
+  NounEng, 
+  VerbEng, 
+  AdjectiveEng,
+  AdverbEng,
+  NumeralEng,
+  SentenceEng,
+  QuestionEng,
+  RelativeEng,
+  ConjunctionEng,
+  PhraseEng,
+  TextX,
+  StructuralEng,
+  IdiomEng
+  ** {
+
+flags startcat = Phr ; unlexer = text ; lexer = text ;
+
+} ;
diff --git a/old-lib/resource/english/IdiomEng.gf b/old-lib/resource/english/IdiomEng.gf
new file mode 100644
index 000000000..87fb03136
--- /dev/null
+++ b/old-lib/resource/english/IdiomEng.gf
@@ -0,0 +1,30 @@
+concrete IdiomEng of Idiom = CatEng ** open Prelude, ResEng in {
+
+  flags optimize=all_subs ;
+
+  lin
+    ImpersCl vp = mkClause "it" (agrP3 Sg) vp ;
+    GenericCl vp = mkClause "one" (agrP3 Sg) vp ;
+
+    CleftNP np rs = mkClause "it" (agrP3 Sg) 
+      (insertObj (\\_ => rs.s ! np.a)
+        (insertObj (\\_ => np.s ! rs.c) (predAux auxBe))) ;
+
+    CleftAdv ad s = mkClause "it" (agrP3 Sg) 
+      (insertObj (\\_ => conjThat ++ s.s)
+        (insertObj (\\_ => ad.s) (predAux auxBe))) ;
+
+    ExistNP np = 
+      mkClause "there" (agrP3 (fromAgr np.a).n) 
+        (insertObj (\\_ => np.s ! Acc) (predAux auxBe)) ;
+
+    ExistIP ip = 
+      mkQuestion (ss (ip.s ! Nom)) 
+        (mkClause "there" (agrP3 ip.n) (predAux auxBe)) ;
+
+    ProgrVP vp = insertObj (\\a => vp.ad ++ vp.prp ++ vp.s2 ! a) (predAux auxBe) ;
+
+    ImpPl1 vp = {s = "let's" ++ infVP True vp (AgP1 Pl)} ;
+
+}
+
diff --git a/old-lib/resource/english/IrregEng.gf b/old-lib/resource/english/IrregEng.gf
new file mode 100644
index 000000000..2b90da1c4
--- /dev/null
+++ b/old-lib/resource/english/IrregEng.gf
@@ -0,0 +1,181 @@
+--# -path=.:prelude:../abstract:../common
+
+concrete IrregEng of IrregEngAbs = CatEng ** open ParadigmsEng in {
+
+flags optimize=values ;
+
+  lin
+  awake_V = irregV "awake" "awoke" "awoken" ;
+  bear_V = irregV "bear" "bore" "born" ;
+  beat_V = irregV "beat" "beat" "beat" ;
+  become_V = irregV "become" "became" "become" ;
+  begin_V = irregV "begin" "began" "begun" ;
+  bend_V = irregV "bend" "bent" "bent" ;
+  beset_V = irregV "beset" "beset" "beset" ;
+  bet_V = irregDuplV "bet" "bet" "bet" ;
+  bid_V = irregDuplV "bid" (variants {"bid" ; "bade"}) (variants {"bid" ; "bidden"}) ;
+  bind_V = irregV "bind" "bound" "bound" ;
+  bite_V = irregV "bite" "bit" "bitten" ;
+  bleed_V = irregV "bleed" "bled" "bled" ;
+  blow_V = irregV "blow" "blew" "blown" ;
+  break_V = irregV "break" "broke" "broken" ;
+  breed_V = irregV "breed" "bred" "bred" ;
+  bring_V = irregV "bring" "brought" "brought" ;
+  broadcast_V = irregV "broadcast" "broadcast" "broadcast" ;
+  build_V = irregV "build" "built" "built" ;
+  burn_V = irregV "burn" (variants {"burned" ; "burnt"}) (variants {"burned" ; "burnt"}) ;
+  burst_V = irregV "burst" "burst" "burst" ;
+  buy_V = irregV "buy" "bought" "bought" ;
+  cast_V = irregV "cast" "cast" "cast" ;
+  catch_V = irregV "catch" "caught" "caught" ;
+  choose_V = irregV "choose" "chose" "chosen" ;
+  cling_V = irregV "cling" "clung" "clung" ;
+  come_V = irregV "come" "came" "come" ;
+  cost_V = irregV "cost" "cost" "cost" ;
+  creep_V = irregV "creep" "crept" "crept" ;
+  cut_V = irregDuplV "cut" "cut" "cut" ;
+  deal_V = irregV "deal" "dealt" "dealt" ;
+  dig_V = irregDuplV "dig" "dug" "dug" ;
+  dive_V = irregV "dive" (variants {"dived" ; "dove"}) "dived" ;
+  do_V = mk5V "do" "does" "did" "done" "doing" ;
+  draw_V = irregV "draw" "drew" "drawn" ;
+  dream_V = irregV "dream" (variants {"dreamed" ; "dreamt"}) (variants {"dreamed" ; "dreamt"}) ;
+  drive_V = irregV "drive" "drove" "driven" ;
+  drink_V = irregV "drink" "drank" "drunk" ;
+  eat_V = irregV "eat" "ate" "eaten" ;
+  fall_V = irregV "fall" "fell" "fallen" ;
+  feed_V = irregV "feed" "fed" "fed" ;
+  feel_V = irregV "feel" "felt" "felt" ;
+  fight_V = irregV "fight" "fought" "fought" ;
+  find_V = irregV "find" "found" "found" ;
+  fit_V = irregDuplV "fit" "fit" "fit" ;
+  flee_V = irregV "flee" "fled" "fled" ;
+  fling_V = irregV "fling" "flung" "flung" ;
+  fly_V = irregV "fly" "flew" "flown" ;
+  forbid_V = irregDuplV "forbid" "forbade" "forbidden" ;
+  forget_V = irregDuplV "forget" "forgot" "forgotten" ;
+  forgive_V = irregV "forgive" "forgave" "forgiven" ;
+  forsake_V = irregV "forsake" "forsook" "forsaken" ;
+  freeze_V = irregV "freeze" "froze" "frozen" ;
+  get_V = irregDuplV "get" "got" "gotten" ;
+  give_V = irregV "give" "gave" "given" ;
+  go_V = mk5V "go" "goes" "went" "gone" "going" ;
+  grind_V = irregV "grind" "ground" "ground" ;
+  grow_V = irregV "grow" "grew" "grown" ;
+  hang_V = irregV "hang" "hung" "hung" ;
+  have_V = mk5V "have" "has" "had" "had" "having" ;
+  hear_V = irregV "hear" "heard" "heard" ;
+  hide_V = irregV "hide" "hid" "hidden" ;
+  hit_V = irregDuplV "hit" "hit" "hit" ;
+  hold_V = irregV "hold" "held" "held" ;
+  hurt_V = irregV "hurt" "hurt" "hurt" ;
+  keep_V = irregV "keep" "kept" "kept" ;
+  kneel_V = irregV "kneel" "knelt" "knelt" ;
+  knit_V = irregDuplV "knit" "knit" "knit" ;
+  know_V = irregV "know" "knew" "know" ;
+  lay_V = irregV "lay" "laid" "laid" ;
+  lead_V = irregV "lead" "led" "led" ;
+  leap_V = irregV "leap" (variants {"leaped" ; "lept"}) (variants {"leaped" ; "lept"}) ;
+  learn_V = irregV "learn" (variants {"learned" ; "learnt"}) (variants {"learned" ; "learnt"}) ;
+  leave_V = irregV "leave" "left" "left" ;
+  lend_V = irregV "lend" "lent" "lent" ;
+  let_V = irregDuplV "let" "let" "let" ;
+  lie_V = irregV "lie" "lay" "lain" ;
+  light_V = irregV "light" (variants {"lighted" ; "lit"}) "lighted" ;
+  lose_V = irregV "lose" "lost" "lost" ;
+  make_V = irregV "make" "made" "made" ;
+  mean_V = irregV "mean" "meant" "meant" ;
+  meet_V = irregV "meet" "met" "met" ;
+  misspell_V = irregV "misspell" (variants {"misspelled" ; "misspelt"}) (variants {"misspelled" ; "misspelt"}) ;
+  mistake_V = irregV "mistake" "mistook" "mistaken" ;
+  mow_V = irregV "mow" "mowed" (variants {"mowed" ; "mown"}) ;
+  overcome_V = irregV "overcome" "overcame" "overcome" ;
+  overdo_V = mk5V "overdo" "overdoes" "overdid" "overdone" "overdoing" ;
+  overtake_V = irregV "overtake" "overtook" "overtaken" ;
+  overthrow_V = irregV "overthrow" "overthrew" "overthrown" ;
+  pay_V = irregV "pay" "paid" "paid" ;
+  plead_V = irregV "plead" "pled" "pled" ;
+  prove_V = irregV "prove" "proved" (variants {"proved" ; "proven"}) ;
+  put_V = irregDuplV "put" "put" "put" ;
+  quit_V = irregDuplV "quit" "quit" "quit" ;
+  read_V = irregV "read" "read" "read" ;
+  rid_V = irregDuplV "rid" "rid" "rid" ;
+  ride_V = irregV "ride" "rode" "ridden" ;
+  ring_V = irregV "ring" "rang" "rung" ;
+  rise_V = irregV "rise" "rose" "risen" ;
+  run_V = irregDuplV "run" "ran" "run" ;
+  saw_V = irregV "saw" "sawed" (variants {"sawed" ; "sawn"}) ;
+  say_V = irregV "say" "said" "said" ;
+  see_V = irregV "see" "saw" "seen" ;
+  seek_V = irregV "seek" "sought" "sought" ;
+  sell_V = irregV "sell" "sold" "sold" ;
+  send_V = irregV "send" "sent" "sent" ;
+  set_V = irregDuplV "set" "set" "set" ;
+  sew_V = irregV "sew" "sewed" (variants {"sewed" ; "sewn"}) ;
+  shake_V = irregV "shake" "shook" "shaken" ;
+  shave_V = irregV "shave" "shaved" (variants {"shaved" ; "shaven"}) ;
+  shear_V = irregV "shear" "shore" "shorn" ;
+  shed_V = irregDuplV "shed" "shed" "shed" ;
+  shine_V = irregV "shine" "shone" "shone" ;
+  shoe_V = irregV "shoe" "shoed" (variants {"shoed" ; "shod"}) ;
+  shoot_V = irregV "shoot" "shot" "shot" ;
+  show_V = irregV "show" "showed" (variants {"showed" ; "shown"}) ;
+  shrink_V = irregV "shrink" "shrank" "shrunk" ;
+  shut_V = irregDuplV "shut" "shut" "shut" ;
+  sing_V = irregV "sing" "sang" "sung" ;
+  sink_V = irregV "sink" "sank" "sunk" ;
+  sit_V = irregDuplV "sit" "sat" "sat" ;
+  sleep_V = irregV "sleep" "slept" "slept" ;
+  slay_V = irregV "slay" "slew" "slain" ;
+  slide_V = irregV "slide" "slid" "slid" ;
+  sling_V = irregV "sling" "slung" "slung" ;
+  slit_V = irregDuplV "slit" "slit" "slit" ;
+  smite_V = irregV "smite" "smote" "smitten" ;
+  sow_V = irregV "sow" "sowed" (variants {"sowed" ; "sown"}) ;
+  speak_V = irregV "speak" "spoke" "spoken" ;
+  speed_V = irregV "speed" "sped" "sped" ;
+  spend_V = irregV "spend" "spent" "spent" ;
+  spill_V = irregV "spill" (variants {"spilled" ; "spilt"}) (variants {"spilled" ; "spilt"}) ;
+  spin_V = irregDuplV "spin" "spun" "spun" ;
+  spit_V = irregDuplV "spit" (variants {"spit" ; "spat"}) "spit" ;
+  split_V = irregDuplV "split" "split" "split" ;
+  spread_V = irregV "spread" "spread" "spread" ;
+  spring_V = irregV "spring" (variants {"sprang" ; "sprung"}) "sprung" ;
+  stand_V = irregV "stand" "stood" "stood" ;
+  steal_V = irregV "steal" "stole" "stolen" ;
+  stick_V = irregV "stick" "stuck" "stuck" ;
+  sting_V = irregV "sting" "stung" "stung" ;
+  stink_V = irregV "stink" "stank" "stunk" ;
+  stride_V = irregV "stride" "strod" "stridden" ;
+  strike_V = irregV "strike" "struck" "struck" ;
+  string_V = irregV "string" "strung" "strung" ;
+  strive_V = irregV "strive" "strove" "striven" ;
+  swear_V = irregV "swear" "swore" "sworn" ;
+  sweep_V = irregV "sweep" "swept" "swept" ;
+  swell_V = irregV "swell" "swelled" (variants {"swelled" ; "swollen"}) ;
+  swim_V = irregDuplV "swim" "swam" "swum" ;
+  swing_V = irregV "swing" "swung" "swung" ;
+  take_V = irregV "take" "took" "taken" ;
+  teach_V = irregV "teach" "taught" "taught" ;
+  tear_V = irregV "tear" "tore" "torn" ;
+  tell_V = irregV "tell" "told" "told" ;
+  think_V = irregV "think" "thought" "thought" ;
+  thrive_V = irregV "thrive" (variants {"thrived" ; "throve"}) "thrived" ;
+  throw_V = irregV "throw" "threw" "thrown" ;
+  thrust_V = irregV "thrust" "thrust" "thrust" ;
+  tread_V = irregV "tread" "trod" "trodden" ;
+  understand_V = irregV "understand" "understood" "understood" ;
+  uphold_V = irregV "uphold" "upheld" "upheld" ;
+  upset_V = irregDuplV "upset" "upset" "upset" ;
+  wake_V = irregV "wake" "woke" "woken" ;
+  wear_V = irregV "wear" "wore" "worn" ;
+  weave_V = irregV "weave" (variants {"weaved" ; "wove"}) (variants {"weaved" ; "woven"}) ;
+  wed_V = irregDuplV "wed" "wed" "wed" ;
+  weep_V = irregV "weep" "wept" "wept" ;
+  wind_V = irregV "wind" "wound" "wound" ;
+  win_V = irregDuplV "win" "won" "won" ;
+  withhold_V = irregV "withhold" "withheld" "withheld" ;
+  withstand_V = irregV "withstand" "withstood" "withstood" ;
+  wring_V = irregV "wring" "wrung" "wrung" ;
+  write_V = irregV "write" "wrote" "written" ;
+}
diff --git a/old-lib/resource/english/IrregEngAbs.gf b/old-lib/resource/english/IrregEngAbs.gf
new file mode 100644
index 000000000..103fe3278
--- /dev/null
+++ b/old-lib/resource/english/IrregEngAbs.gf
@@ -0,0 +1,176 @@
+abstract IrregEngAbs = Cat ** {
+fun
+  awake_V : V ;
+  bear_V : V ;
+  beat_V : V ;
+  become_V : V ;
+  begin_V : V ;
+  bend_V : V ;
+  beset_V : V ;
+  bet_V : V ;
+  bid_V : V ;
+  bind_V : V ;
+  bite_V : V ;
+  bleed_V : V ;
+  blow_V : V ;
+  break_V : V ;
+  breed_V : V ;
+  bring_V : V ;
+  broadcast_V : V ;
+  build_V : V ;
+  burn_V : V ;
+  burst_V : V ;
+  buy_V : V ;
+  cast_V : V ;
+  catch_V : V ;
+  choose_V : V ;
+  cling_V : V ;
+  come_V : V ;
+  cost_V : V ;
+  creep_V : V ;
+  cut_V : V ;
+  deal_V : V ;
+  dig_V : V ;
+  dive_V : V ;
+  do_V : V ;
+  draw_V : V ;
+  dream_V : V ;
+  drive_V : V ;
+  drink_V : V ;
+  eat_V : V ;
+  fall_V : V ;
+  feed_V : V ;
+  feel_V : V ;
+  fight_V : V ;
+  find_V : V ;
+  fit_V : V ;
+  flee_V : V ;
+  fling_V : V ;
+  fly_V : V ;
+  forbid_V : V ;
+  forget_V : V ;
+  forgive_V : V ;
+  forsake_V : V ;
+  freeze_V : V ;
+  get_V : V ;
+  give_V : V ;
+  go_V : V ;
+  grind_V : V ;
+  grow_V : V ;
+  hang_V : V ;
+  have_V : V ;
+  hear_V : V ;
+  hide_V : V ;
+  hit_V : V ;
+  hold_V : V ;
+  hurt_V : V ;
+  keep_V : V ;
+  kneel_V : V ;
+  knit_V : V ;
+  know_V : V ;
+  lay_V : V ;
+  lead_V : V ;
+  leap_V : V ;
+  learn_V : V ;
+  leave_V : V ;
+  lend_V : V ;
+  let_V : V ;
+  lie_V : V ;
+  light_V : V ;
+  lose_V : V ;
+  make_V : V ;
+  mean_V : V ;
+  meet_V : V ;
+  misspell_V : V ;
+  mistake_V : V ;
+  mow_V : V ;
+  overcome_V : V ;
+  overdo_V : V ;
+  overtake_V : V ;
+  overthrow_V : V ;
+  pay_V : V ;
+  plead_V : V ;
+  prove_V : V ;
+  put_V : V ;
+  quit_V : V ;
+  read_V : V ;
+  rid_V : V ;
+  ride_V : V ;
+  ring_V : V ;
+  rise_V : V ;
+  run_V : V ;
+  saw_V : V ;
+  say_V : V ;
+  see_V : V ;
+  seek_V : V ;
+  sell_V : V ;
+  send_V : V ;
+  set_V : V ;
+  sew_V : V ;
+  shake_V : V ;
+  shave_V : V ;
+  shear_V : V ;
+  shed_V : V ;
+  shine_V : V ;
+  shoe_V : V ;
+  shoot_V : V ;
+  show_V : V ;
+  shrink_V : V ;
+  shut_V : V ;
+  sing_V : V ;
+  sink_V : V ;
+  sit_V : V ;
+  sleep_V : V ;
+  slay_V : V ;
+  slide_V : V ;
+  sling_V : V ;
+  slit_V : V ;
+  smite_V : V ;
+  sow_V : V ;
+  speak_V : V ;
+  speed_V : V ;
+  spend_V : V ;
+  spill_V : V ;
+  spin_V : V ;
+  spit_V : V ;
+  split_V : V ;
+  spread_V : V ;
+  spring_V : V ;
+  stand_V : V ;
+  steal_V : V ;
+  stick_V : V ;
+  sting_V : V ;
+  stink_V : V ;
+  stride_V : V ;
+  strike_V : V ;
+  string_V : V ;
+  strive_V : V ;
+  swear_V : V ;
+  sweep_V : V ;
+  swell_V : V ;
+  swim_V : V ;
+  swing_V : V ;
+  take_V : V ;
+  teach_V : V ;
+  tear_V : V ;
+  tell_V : V ;
+  think_V : V ;
+  thrive_V : V ;
+  throw_V : V ;
+  thrust_V : V ;
+  tread_V : V ;
+  understand_V : V ;
+  uphold_V : V ;
+  upset_V : V ;
+  wake_V : V ;
+  wear_V : V ;
+  weave_V : V ;
+  wed_V : V ;
+  weep_V : V ;
+  wind_V : V ;
+  win_V : V ;
+  withhold_V : V ;
+  withstand_V : V ;
+  wring_V : V ;
+  write_V : V ;
+}
diff --git a/old-lib/resource/english/LangEng.gf b/old-lib/resource/english/LangEng.gf
new file mode 100644
index 000000000..966308a2b
--- /dev/null
+++ b/old-lib/resource/english/LangEng.gf
@@ -0,0 +1,10 @@
+--# -path=.:../abstract:../common:prelude
+
+concrete LangEng of Lang = 
+  GrammarEng,
+  LexiconEng
+  ** {
+
+flags startcat = Phr ; unlexer = text ; lexer = text ;
+
+} ;
diff --git a/old-lib/resource/english/LexiconEng.gf b/old-lib/resource/english/LexiconEng.gf
new file mode 100644
index 000000000..a92058c90
--- /dev/null
+++ b/old-lib/resource/english/LexiconEng.gf
@@ -0,0 +1,375 @@
+--# -path=.:prelude
+
+concrete LexiconEng of Lexicon = CatEng ** 
+  open ParadigmsEng, IrregEng, Prelude in {
+
+flags 
+  optimize=values ;
+
+lin
+  airplane_N = regN "airplane" ;
+  answer_V2S = mkV2S (regV "answer") toP ;
+  apartment_N = regN "apartment" ;
+  apple_N = regN "apple" ;
+  art_N = regN "art" ;
+  ask_V2Q = mkV2Q (regV "ask") noPrep ;
+  baby_N = regN "baby" ;
+  bad_A = mkADeg "bad" "worse" "worst" "badly" ;
+  bank_N = regN "bank" ;
+  beautiful_A = compoundADeg (regA "beautiful") ;
+  become_VA = mkVA (irregV "become" "became" "become") ;
+  beer_N = regN "beer" ;
+  beg_V2V = mkV2V (regDuplV "beg") noPrep toP ;
+  big_A = duplADeg "big" ;
+  bike_N = regN "bike" ;
+  bird_N = regN "bird" ;
+  black_A = regADeg "black" ;
+  blue_A = regADeg "blue" ;
+  boat_N = regN "boat" ;
+  book_N = regN "book" ;
+  boot_N = regN "boot" ;
+  boss_N = mkN human (regN "boss") ;
+  boy_N = mkN masculine (regN "boy") ;
+  bread_N = regN "bread" ;
+  break_V2 = dirV2 (irregV "break" "broke" "broken") ;
+  broad_A = regADeg "broad" ;
+  brother_N2 = mkN2 (mkN masculine (mkN "brother")) (mkPrep "of") ;
+  brown_A = regADeg "brown" ;
+  butter_N = regN "butter" ;
+  buy_V2 = dirV2 (irregV "buy" "bought" "bought") ;
+  camera_N = regN "camera" ;
+  cap_N = regN "cap" ;
+  car_N = regN "car" ;
+  carpet_N = regN "carpet" ;
+  cat_N = regN "cat" ;
+  ceiling_N = regN "ceiling" ;
+  chair_N = regN "chair" ;
+  cheese_N = regN "cheese" ;
+  child_N = mk2N "child" "children" ;
+  church_N = regN "church" ;
+  city_N = regN "city" ;
+  clean_A = regADeg "clean" ;
+  clever_A = regADeg "clever" ;
+  close_V2 = dirV2 (regV "close") ;
+  coat_N = regN "coat" ;
+  cold_A = regADeg "cold" ;
+  come_V = (irregV "come" "came" "come") ;
+  computer_N = regN "computer" ;
+  country_N = regN "country" ;
+  cousin_N = mkN human (regN "cousin") ;
+  cow_N = regN "cow" ;
+  die_V = (regV "die") ;
+  dirty_A = regADeg "dirty" ;
+  distance_N3 = mkN3 (regN "distance") fromP toP ;
+  doctor_N = mkN human (regN "doctor") ;
+  dog_N = regN "dog" ;
+  door_N = regN "door" ;
+  drink_V2 = dirV2 (irregV "drink" "drank" "drunk") ;
+  easy_A2V = mkA2V (regA "easy") forP ;
+  eat_V2 = dirV2 (irregV "eat" "ate" "eaten") ;
+  empty_A = regADeg "empty" ;
+  enemy_N = regN "enemy" ;
+  factory_N = regN "factory" ;
+  father_N2 = mkN2 (mkN masculine (mkN "father")) (mkPrep "of") ;
+  fear_VS = mkVS (regV "fear") ;
+  find_V2 = dirV2 (irregV "find" "found" "found") ;
+  fish_N = mk2N "fish" "fish" ;
+  floor_N = regN "floor" ;
+  forget_V2 = dirV2 (irregDuplV "forget" "forgot" "forgotten") ;
+  fridge_N = regN "fridge" ;
+  friend_N = mkN human (regN "friend") ;
+  fruit_N = regN "fruit" ;
+  fun_AV = mkAV (regA "fun") ;
+  garden_N = regN "garden" ;
+  girl_N = mkN feminine (regN "girl") ;
+  glove_N = regN "glove" ;
+  gold_N = regN "gold" ;
+  good_A = mkADeg "good" "better" "best" "well" ;
+  go_V = mk5V "go" "goes" "went" "gone" "going" ;
+  green_A = regADeg "green" ;
+  harbour_N = regN "harbour" ;
+  hate_V2 = dirV2 (regV "hate") ;
+  hat_N = regN "hat" ;
+  have_V2 = dirV2 (mk5V "have" "has" "had" "had" "having") ;
+  hear_V2 = dirV2 (irregV "hear" "heard" "heard") ;
+  hill_N = regN "hill" ;
+  hope_VS = mkVS (regV "hope") ;
+  horse_N = regN "horse" ;
+  hot_A = duplADeg "hot" ;
+  house_N = regN "house" ;
+  important_A = compoundADeg (regA "important") ;
+  industry_N = regN "industry" ;
+  iron_N = regN "iron" ;
+  king_N = mkN masculine (regN "king") ;
+  know_V2 = dirV2 (irregV "know" "knew" "known") ;
+  lake_N = regN "lake" ;
+  lamp_N = regN "lamp" ;
+  learn_V2 = dirV2 (regV "learn") ;
+  leather_N = regN "leather" ;
+  leave_V2 = dirV2 (irregV "leave" "left" "left") ;
+  like_V2 = dirV2 (regV "like") ;
+  listen_V2 = prepV2 (regV "listen") toP ;
+  live_V = (regV "live") ;
+  long_A = regADeg "long" ;
+  lose_V2 = dirV2 (irregV "lose" "lost" "lost") ;
+  love_N = regN "love" ;
+  love_V2 = dirV2 (regV "love") ;
+  man_N = mkN masculine (mk2N "man" "men") ;
+  married_A2 = mkA2 (regA "married") toP ;
+  meat_N = regN "meat" ;
+  milk_N = regN "milk" ;
+  moon_N = regN "moon" ;
+  mother_N2 = mkN2 (mkN feminine (mkN "mother")) (mkPrep "of") ;
+  mountain_N = regN "mountain" ;
+  music_N = regN "music" ;
+  narrow_A = regADeg "narrow" ;
+  new_A = regADeg "new" ;
+  newspaper_N = regN "newspaper" ;
+  oil_N = regN "oil" ;
+  old_A = regADeg "old" ;
+  open_V2 = dirV2 (regV "open") ;
+  paint_V2A = mkV2A (regV "paint") noPrep ;
+  paper_N = regN "paper" ;
+  paris_PN = mkPN (mkN nonhuman (mkN "Paris")) ;
+  peace_N = regN "peace" ;
+  pen_N = regN "pen" ;
+  planet_N = regN "planet" ;
+  plastic_N = regN "plastic" ;
+  play_V2 = dirV2 (regV "play") ;
+  policeman_N = mkN masculine (mkN "policeman" "policemen") ;
+  priest_N = mkN human (regN "priest") ;
+  probable_AS = mkAS (regA "probable") ;
+  queen_N = mkN feminine (regN "queen") ;
+  radio_N = regN "radio" ;
+  rain_V0 = mkV0 (regV "rain") ;
+  read_V2 = dirV2 (irregV "read" "read" "read") ;
+  red_A = duplADeg "red" ;
+  religion_N = regN "religion" ;
+  restaurant_N = regN "restaurant" ;
+  river_N = regN "river" ;
+  rock_N = regN "rock" ;
+  roof_N = regN "roof" ;
+  rubber_N = regN "rubber" ;
+  run_V = (irregDuplV "run" "ran" "run") ;
+  say_VS = mkVS (irregV "say" "said" "said") ;
+  school_N = regN "school" ;
+  science_N = regN "science" ;
+  sea_N = regN "sea" ;
+  seek_V2 = dirV2 (irregV "seek" "sought" "sought") ;
+  see_V2 = dirV2 (irregV "see" "saw" "seen") ;
+  sell_V3 = dirV3 (irregV "sell" "sold" "sold") toP ;
+  send_V3 = dirV3 (irregV "send" "sent" "sent") toP ;
+  sheep_N = mk2N "sheep" "sheep" ;
+  ship_N = regN "ship" ;
+  shirt_N = regN "shirt" ;
+  shoe_N = regN "shoe" ;
+  shop_N = regN "shop" ;
+  short_A = regADeg "short" ;
+  silver_N = regN "silver" ;
+  sister_N = mkN2 (mkN feminine (mkN "sister")) (mkPrep "of") ;
+  sleep_V = (irregV "sleep" "slept" "slept") ;
+  small_A = regADeg "small" ;
+  snake_N = regN "snake" ;
+  sock_N = regN "sock" ;
+  speak_V2 = dirV2 (irregV "speak" "spoke" "spoken") ;
+  star_N = regN "star" ;
+  steel_N = regN "steel" ;
+  stone_N = regN "stone" ;
+  stove_N = regN "stove" ;
+  student_N = mkN human (regN "student") ;
+  stupid_A = regADeg "stupid" ;
+  sun_N = regN "sun" ;
+  switch8off_V2 = dirV2 (partV (regV "switch") "off") ;
+  switch8on_V2 = dirV2 (partV (regV "switch") "on") ;
+  table_N = regN "table" ;
+  talk_V3 = mkV3 (regV "talk") toP aboutP ;
+  teacher_N = mkN human (regN "teacher") ;
+  teach_V2 = dirV2 (irregV "teach" "taught" "taught") ;
+  television_N = regN "television" ;
+  thick_A = regADeg "thick" ;
+  thin_A = duplADeg "thin" ;
+  train_N = regN "train" ;
+  travel_V = (regDuplV "travel") ;
+  tree_N = regN "tree" ;
+ ---- trousers_N = regN "trousers" ;
+  ugly_A = regADeg "ugly" ;
+  understand_V2 = dirV2 (irregV "understand" "understood" "understood") ;
+  university_N = regN "university" ;
+  village_N = regN "village" ;
+  wait_V2 = prepV2 (regV "wait") forP ;
+  walk_V = (regV "walk") ;
+  warm_A = regADeg "warm" ;
+  war_N = regN "war" ;
+  watch_V2 = dirV2 (regV "watch") ;
+  water_N = regN "water" ;
+  white_A = regADeg "white" ;
+  window_N = regN "window" ;
+  wine_N = regN "wine" ;
+  win_V2 = dirV2 (irregDuplV "win" "won" "won") ;
+  woman_N = mkN feminine (mk2N "woman" "women") ;
+  wonder_VQ = mkVQ (regV "wonder") ;
+  wood_N = regN "wood" ;
+  write_V2 = dirV2 (irregV "write" "wrote" "written") ;
+  yellow_A = regADeg "yellow" ;
+  young_A = regADeg "young" ;
+
+  do_V2 = dirV2 (mk5V "do" "does" "did" "done" "doing") ;
+  now_Adv = mkAdv "now" ;
+  already_Adv = mkAdv "already" ;
+  song_N = regN "song" ;
+  add_V3 = dirV3 (regV "add") toP ;
+  number_N = regN "number" ;
+  put_V2 = prepV2 (irregDuplV "put" "put" "put") noPrep ;
+  stop_V = regDuplV "stop" ;
+  jump_V = regV "jump" ;
+
+  left_Ord = ss "left" ;
+  right_Ord = ss "right" ;
+  far_Adv = mkAdv "far" ;
+  correct_A = (regA "correct") ;
+  dry_A = regA "dry" ;
+  dull_A = regA "dull" ;
+  full_A = regA "full" ;
+  heavy_A = regA "heavy" ;
+  near_A = regA "near" ;
+  rotten_A = (regA "rotten") ;
+  round_A = regA "round" ;
+  sharp_A = regA "sharp" ;
+  smooth_A = regA "smooth" ;
+  straight_A = regA "straight" ;
+  wet_A = regA "wet" ; ----
+  wide_A = regA "wide" ;
+  animal_N = regN "animal" ;
+  ashes_N = regN "ash" ; -- FIXME: plural only?
+  back_N = regN "back" ;
+  bark_N = regN "bark" ;
+  belly_N = regN "belly" ;
+  blood_N = regN "blood" ;
+  bone_N = regN "bone" ;
+  breast_N = regN "breast" ;
+  cloud_N = regN "cloud" ;
+  day_N = regN "day" ;
+  dust_N = regN "dust" ;
+  ear_N = regN "ear" ;
+  earth_N = regN "earth" ;
+  egg_N = regN "egg" ;
+  eye_N = regN "eye" ;
+  fat_N = regN "fat" ;
+  feather_N = regN "feather" ;
+  fingernail_N = regN "fingernail" ;
+  fire_N = regN "fire" ;
+  flower_N = regN "flower" ;
+  fog_N = regN "fog" ;
+  foot_N = mk2N "foot" "feet" ;
+  forest_N = regN "forest" ;
+  grass_N = regN "grass" ;
+  guts_N = regN "gut" ; -- FIXME: no singular
+  hair_N = regN "hair" ;
+  hand_N = regN "hand" ;
+  head_N = regN "head" ;
+  heart_N = regN "heart" ;
+  horn_N = regN "horn" ;
+  husband_N = mkN masculine (regN "husband") ;
+  ice_N = regN "ice" ;
+  knee_N = regN "knee" ;
+  leaf_N = mk2N "leaf" "leaves" ;
+  leg_N = regN "leg" ;
+  liver_N = regN "liver" ;
+  louse_N = mk2N "louse" "lice" ;
+  mouth_N = regN "mouth" ;
+  name_N = regN "name" ;
+  neck_N = regN "neck" ;
+  night_N = regN "night" ;
+  nose_N = regN "nose" ;
+  person_N = mkN human (regN "person") ;
+  rain_N = regN "rain" ;
+  road_N = regN "road" ;
+  root_N = regN "root" ;
+  rope_N = regN "rope" ;
+  salt_N = regN "salt" ;
+  sand_N = regN "sand" ;
+  seed_N = regN "seed" ;
+  skin_N = regN "skin" ;
+  sky_N = regN "sky" ;
+  smoke_N = regN "smoke" ;
+  snow_N = regN "snow" ;
+  stick_N = regN "stick" ;
+  tail_N = regN "tail" ;
+  tongue_N = regN "tongue" ;
+  tooth_N = mk2N "tooth" "teeth" ;
+  wife_N = mkN feminine (mk2N "wife" "wives") ;
+  wind_N = regN "wind" ;
+  wing_N = regN "wing" ;
+  worm_N = regN "worm" ;
+  year_N = regN "year" ;
+  blow_V = IrregEng.blow_V ;
+  breathe_V = dirV2 (regV "breathe") ;
+  burn_V = IrregEng.burn_V ;
+  dig_V = IrregEng.dig_V ;
+  fall_V = IrregEng.fall_V ;
+  float_V = regV "float" ;
+  flow_V = regV "flow" ;
+  fly_V = IrregEng.fly_V ;
+  freeze_V = IrregEng.freeze_V ;
+  give_V3 = dirV3 give_V toP ;
+  laugh_V = regV "laugh" ;
+  lie_V = IrregEng.lie_V ;
+  play_V = regV "play" ;
+  sew_V = IrregEng.sew_V ;
+  sing_V = IrregEng.sing_V ;
+  sit_V = IrregEng.sit_V ;
+  smell_V = regV "smell" ;
+  spit_V = IrregEng.spit_V ;
+  stand_V = IrregEng.stand_V ;
+  swell_V = IrregEng.swell_V ;
+  swim_V = IrregEng.swim_V ;
+  think_V = IrregEng.think_V ;
+  turn_V = regV "turn" ;
+  vomit_V = regV "vomit" ;
+
+  bite_V2 = dirV2 IrregEng.bite_V ;
+  count_V2 = dirV2 (regV "count") ;
+  cut_V2 = dirV2 IrregEng.cut_V ;
+  fear_V2 = dirV2 (regV "fear") ;
+  fight_V2 = dirV2 fight_V ;
+  hit_V2 = dirV2 hit_V ;
+  hold_V2 = dirV2 hold_V ;
+  hunt_V2 = dirV2 (regV "hunt") ;
+  kill_V2 = dirV2 (regV "kill") ;
+  pull_V2 = dirV2 (regV "pull") ;
+  push_V2 = dirV2 (regV "push") ;
+  rub_V2 = dirV2 (regDuplV "rub") ;
+  scratch_V2 = dirV2 (regV "scratch") ;
+  split_V2 = dirV2 split_V ;
+  squeeze_V2 = dirV2 (regV "squeeze") ;
+  stab_V2 = dirV2 (regDuplV "stab") ;
+  suck_V2 = dirV2 (regV "suck") ;
+  throw_V2 = dirV2 throw_V ;
+  tie_V2 = dirV2 (regV "tie") ;
+  wash_V2 = dirV2 (regV "wash") ;
+  wipe_V2 = dirV2 (regV "wipe") ;
+
+--  other_A = regA "other" ;
+
+  grammar_N = regN "grammar" ;
+  language_N = regN "language" ;
+  rule_N = regN "rule" ;
+
+-- added 4/6/2007
+    john_PN = mkPN (mkN masculine (mkN "John")) ;
+    question_N = regN "question" ;
+    ready_A = regA "ready" ;
+    reason_N = regN "reason" ;
+    today_Adv = mkAdv "today" ;
+    uncertain_A = regA "uncertain" ;
+
+oper
+  aboutP = mkPrep "about" ;
+  atP = mkPrep "at" ;
+  forP = mkPrep "for" ;
+  fromP = mkPrep "from" ;
+  inP = mkPrep "in" ;
+  onP = mkPrep "on" ;
+  toP = mkPrep "to" ;
+
+} ;
diff --git a/old-lib/resource/english/MorphoEng.gf b/old-lib/resource/english/MorphoEng.gf
new file mode 100644
index 000000000..ec8dc58df
--- /dev/null
+++ b/old-lib/resource/english/MorphoEng.gf
@@ -0,0 +1,197 @@
+--# -path=.:../../prelude
+
+--1 A Simple English Resource Morphology
+--
+-- Aarne Ranta 2002 -- 2005
+--
+-- This resource morphology contains definitions needed in the resource
+-- syntax. To build a lexicon, it is better to use $ParadigmsEng$, which
+-- gives a higher-level access to this module.
+
+resource MorphoEng = ResEng ** open Prelude, (Predef=Predef) in {
+
+  flags optimize=all ;
+
+--2 Phonology
+--
+-- To regulate the use of endings for both nouns, adjectives, and verbs:
+
+oper
+  y2ie : Str -> Str -> Str = \fly,s -> 
+    let y = last (init fly) in
+    case y of {
+      "a" => fly + s ;
+      "e" => fly + s ;
+      "o" => fly + s ;
+      "u" => fly + s ;
+    _   => init fly + "ie" + s
+    } ;
+
+
+--2 Nouns
+--
+-- For conciseness and abstraction, we define a worst-case macro for
+-- noun inflection. It is used for defining special case that
+-- only need one string as argument.
+
+oper
+  CommonNoun : Type = {s : Number => Case => Str} ;
+
+  nounGen : Str -> CommonNoun = \dog -> case last dog of {
+    "y" => nounY "dog" ;
+    "s" => nounS (init "dog") ;
+    _   => nounReg "dog"
+    } ;
+
+-- These are auxiliaries to $nounGen$.
+
+  nounReg : Str -> CommonNoun = \dog -> 
+    mkNoun dog (dog + "s") (dog + "'s") (dog + "s'");
+  nounS   : Str -> CommonNoun = \kiss -> 
+    mkNoun kiss (kiss + "es") (kiss + "'s") (kiss + "es'") ;
+  nounY   : Str -> CommonNoun = \fl -> 
+    mkNoun (fl + "y") (fl + "ies") (fl + "y's") (fl + "ies'") ;
+
+
+--3 Proper names
+--
+-- Regular proper names are inflected with "'s" in the genitive.
+
+  nameReg : Str -> Gender -> {s : Case => Str} = \john,g -> 
+    {s = table {Gen => john + "'s" ; _ => john} ; g = g} ;
+
+--2 Determiners
+
+  mkDeterminer : Number -> Str -> {s : Str ; n : Number} = \n,s ->
+    {s = s ; n = n} ;
+
+--2 Pronouns
+--
+-- Here we define personal pronouns. 
+--
+-- We record the form "mine" and the gender for later use.
+
+  Pronoun : Type = 
+    {s : Case => Str ; a : Agr} ;
+
+  mkPronoun : (_,_,_,_ : Str) -> Number -> Person -> Gender -> Pronoun = 
+   \I,me,my,mine,n,p,g -> 
+    {s = table {Nom => I ; Acc => me ; Gen => my} ; 
+     a = toAgr n p g
+    } ;
+
+  human : Gender = Masc ; --- doesn't matter
+
+  pronI = mkPronoun "I" "me" "my" "mine" Sg P1 human ;
+  pronYouSg = mkPronoun "you" "you" "your" "yours" Sg P2 human ; -- verb agr OK
+  pronHe = mkPronoun "he" "him" "his" "his" Sg P3 Masc ;
+  pronShe = mkPronoun "she" "her" "her" "hers" Sg P3 Fem ;
+  pronIt = mkPronoun "it" "it" "its" "it" Sg P3 Neutr ;
+
+  pronWe = mkPronoun "we" "us" "our" "ours" Pl P1 human ;
+  pronYouPl = mkPronoun "you" "you" "your" "yours" Pl P2 human ;
+  pronThey = mkPronoun "they" "them" "their" "theirs" Pl P3 human ; ---
+
+
+--2 Adjectives
+--
+-- To form the adjectival and the adverbial forms, two strings are needed
+-- in the worst case. (First without degrees.)
+
+  Adjective = {s : AForm => Str} ;
+
+-- However, most adjectives can be inflected using the final character.
+-- N.B. this is not correct for "shy", but $mkAdjective$ has to be used.
+
+  regAdjective : Str -> Adjective = \free -> 
+    let 
+      e   = last free ;
+      fre = init free ;
+      freely = case e of {
+        "y" => fre + "ily" ;
+        _   => free + "ly"
+        } ;
+      fre = case e of {
+        "e" => fre ;
+        "y" => fre + "i" ;
+        _   => free
+        }
+    in 
+    mkAdjective free (fre + "er") (fre + "est") freely ; 
+
+-- Many adjectives are 'inflected' by adding a comparison word.
+
+  adjDegrLong : Str -> Adjective = \ridiculous ->
+    mkAdjective 
+      ridiculous 
+      ("more" ++ ridiculous) 
+      ("most" ++ ridiculous) 
+      ((regAdjective ridiculous).s ! AAdv) ;
+
+
+--3 Verbs
+--
+-- The worst case needs five forms. (The verb "be" is treated separately.)
+
+  mkVerb4 : (_,_,_,_: Str) -> Verb = \go,goes,went,gone -> 
+    let going = case last go of {
+      "e" => init go + "ing" ;
+      _ => go + "ing"
+      }
+    in
+    mkVerb go goes went gone going ;
+
+-- This is what we use to derive the irregular forms in almost all cases
+
+  mkVerbIrreg : (_,_,_ : Str) -> Verb = \bite,bit,bitten -> 
+    let bites = case last bite of {
+      "y" => y2ie bite "s" ;
+      "s" => init bite + "es" ;
+      _   => bite + "s"
+      } 
+    in mkVerb4 bite bites bit bitten ;
+
+-- This is used to derive regular forms.
+
+  mkVerbReg : Str -> Verb = \soak -> 
+    let 
+      soaks = case last soak of {
+        "y" => y2ie soak "s" ;
+        "s" => init soak + "es" ;
+        _   => soak + "s"
+        } ;
+      soaked = case last soak of {
+        "e" => init soak + "s" ;
+        _   => soak + "ed"
+        }
+    in 
+    mkVerb4 soak soaks soaked soaked ;
+
+  verbGen : Str -> Verb = \kill -> case last kill of {
+    "y" => verbP3y (init kill) ;
+    "e" => verbP3e (init kill) ;
+    "s" => verbP3s (init kill) ;
+    _   => regVerbP3 kill
+    } ;
+
+-- These are just auxiliary to $verbGen$.
+
+  regVerbP3 : Str -> Verb = \walk -> 
+    mkVerbIrreg walk (walk + "ed") (walk + "ed") ;
+  verbP3s   : Str -> Verb = \kiss -> 
+    mkVerb4 kiss (kiss + "es") (kiss + "ed") (kiss + "ed") ;
+  verbP3e   : Str -> Verb = \love -> 
+    mkVerb4 love (love + "s") (love + "d") (love + "d") ;
+  verbP3y   : Str -> Verb = \cr -> 
+    mkVerb4 (cr + "y") (cr + "ies") (cr + "ied") (cr + "ied") ;
+
+--- The particle always appears right after the verb.
+
+  verbPart : Verb -> Str -> Verb = \v,p ->
+    {s = \\f => v.s ! f ++ p ; isRefl = v.isRefl} ;
+
+  verbNoPart : Verb -> Verb = \v -> verbPart v [] ;
+
+
+} ;
+
diff --git a/old-lib/resource/english/NounEng.gf b/old-lib/resource/english/NounEng.gf
new file mode 100644
index 000000000..cc7427930
--- /dev/null
+++ b/old-lib/resource/english/NounEng.gf
@@ -0,0 +1,137 @@
+concrete NounEng of Noun = CatEng ** open ResEng, Prelude in {
+
+  flags optimize=all_subs ;
+
+  lin
+    DetCN det cn = {
+      s = \\c => det.s ++ cn.s ! det.n ! c ; 
+      a = agrgP3 det.n cn.g
+      } ;
+
+    UsePN pn = pn ** {a = agrgP3 Sg pn.g} ;
+    UsePron p = p ;
+
+    PredetNP pred np = {
+      s = \\c => pred.s ++ np.s ! c ;
+      a = np.a
+      } ;
+
+    PPartNP np v2 = {
+      s = \\c => np.s ! c ++ v2.s ! VPPart ;
+      a = np.a
+      } ;
+
+    RelNP np rs = {
+      s = \\c => np.s ! c ++ "," ++ rs.s ! np.a ;
+      a = np.a
+      } ;
+
+    AdvNP np adv = {
+      s = \\c => np.s ! c ++ adv.s ;
+      a = np.a
+      } ;
+
+    DetQuantOrd quant num ord = {
+      s = quant.s ! num.n ++ num.s ++ ord.s ; 
+      n = num.n
+      } ;
+
+    DetQuant quant num = {
+      s = quant.s ! num.n ++ num.s ; 
+      n = num.n
+      } ;
+
+    DetNP det = {
+      s = \\c => det.s ; ---- case
+      a = agrP3 det.n
+      } ;
+
+    PossPron p = {s = \\_ => p.s ! Gen} ;
+
+    NumSg = {s = []; n = Sg ; hasCard = False} ;
+    NumPl = {s = []; n = Pl ; hasCard = False} ;
+---b    NoOrd = {s = []} ;
+
+    NumCard n = n ** {hasCard = True} ;
+
+    NumDigits n = {s = n.s ! NCard ; n = n.n} ;
+    OrdDigits n = {s = n.s ! NOrd} ;
+
+    NumNumeral numeral = {s = numeral.s ! NCard; n = numeral.n} ;
+    OrdNumeral numeral = {s = numeral.s ! NOrd} ;
+
+    AdNum adn num = {s = adn.s ++ num.s ; n = num.n} ;
+
+    OrdSuperl a = {s = a.s ! AAdj Superl} ;
+
+    DetArtOrd art num ord = {
+      s = art.s ! num.hasCard ! num.n ++ num.s ++ ord.s ;
+      n = num.n
+      } ;
+
+    DetArtCard art card = {
+      s = art.s ! True ! card.n ++ card.s ;
+      n = card.n
+      } ;
+
+    DetArtSg art cn = {
+      s = \\c => art.s ! False ! Sg ++ cn.s ! Sg ! c ;
+      a = agrgP3 Sg cn.g
+      } ;
+
+    DetArtPl art cn = {
+      s = \\c => art.s ! False ! Pl ++ cn.s ! Pl ! c ;
+      a = agrgP3 Pl cn.g
+      } ;
+
+    DefArt = {s = \\c,n => artDef} ;
+
+    IndefArt = {s = \\c,n => case <n,c> of {
+        <Sg,False> => artIndef ;
+        _ => []
+        }
+      } ;
+
+    MassNP cn = {
+      s = cn.s ! Sg ;
+      a = agrP3 Sg
+      } ;
+
+    UseN n = n ;
+    UseN2 n = n ;
+---b    UseN3 n = n ;
+
+    Use2N3 f = {
+      s = \\n,c => f.s ! n ! Nom ;
+      g = f.g ;
+      c2 = f.c2
+      } ;
+
+    Use3N3 f = {
+      s = \\n,c => f.s ! n ! Nom ;
+      g = f.g ;
+      c2 = f.c3
+      } ;
+
+    ComplN2 f x = {s = \\n,c => f.s ! n ! Nom ++ f.c2 ++ x.s ! c ; g = f.g} ;
+    ComplN3 f x = {
+      s = \\n,c => f.s ! n ! Nom ++ f.c2 ++ x.s ! c ;
+      g = f.g ;
+      c2 = f.c3
+      } ;
+
+    AdjCN ap cn = {
+      s = \\n,c => preOrPost ap.isPre (ap.s ! agrgP3 n cn.g) (cn.s ! n ! c) ;
+      g = cn.g
+      } ;
+    RelCN cn rs = {
+      s = \\n,c => cn.s ! n ! c ++ rs.s ! agrgP3 n cn.g ;
+      g = cn.g
+      } ;
+    AdvCN cn ad = {s = \\n,c => cn.s ! n ! c ++ ad.s ; g = cn.g} ;
+
+    SentCN cn sc = {s = \\n,c => cn.s ! n ! c ++ sc.s ; g = cn.g} ;
+
+    ApposCN cn np = {s = \\n,c => cn.s ! n ! Nom ++ np.s ! c ; g = cn.g} ;
+
+}
diff --git a/old-lib/resource/english/NumeralEng.gf b/old-lib/resource/english/NumeralEng.gf
new file mode 100644
index 000000000..2f7c8e553
--- /dev/null
+++ b/old-lib/resource/english/NumeralEng.gf
@@ -0,0 +1,95 @@
+concrete NumeralEng of Numeral = CatEng ** open ResEng in {
+
+lincat 
+  Digit = {s : DForm => CardOrd => Str} ;
+  Sub10 = {s : DForm => CardOrd => Str ; n : Number} ;
+  Sub100     = {s : CardOrd => Str ; n : Number} ;
+  Sub1000    = {s : CardOrd => Str ; n : Number} ;
+  Sub1000000 = {s : CardOrd => Str ; n : Number} ;
+
+lin num x = x ;
+lin n2 = let two = mkNum "two"   "twelve"   "twenty" "second" in
+         {s = \\f,c => case <f,c> of {
+             <teen,NOrd> => "twelfth" ;
+             _ => two.s ! f ! c
+             }
+         } ;
+
+lin n3 = mkNum "three" "thirteen" "thirty" "third" ;
+lin n4 = mkNum "four"  "fourteen" "forty" "fourth" ;
+lin n5 = mkNum "five"  "fifteen"  "fifty" "fifth" ;
+lin n6 = regNum "six" ;
+lin n7 = regNum "seven" ;
+lin n8 = mkNum "eight" "eighteen" "eighty" "eighth" ;
+lin n9 = mkNum "nine" "nineteen" "ninety" "ninth" ;
+
+lin pot01 = mkNum "one" "eleven" "ten" "first" ** {n = Sg} ;
+lin pot0 d = d ** {n = Pl} ;
+lin pot110 = regCardOrd "ten" ** {n = Pl} ;
+lin pot111 = regCardOrd "eleven" ** {n = Pl} ;
+lin pot1to19 d = {s = d.s ! teen} ** {n = Pl} ;
+lin pot0as1 n = {s = n.s ! unit}  ** {n = n.n} ;
+lin pot1 d = {s = d.s ! ten} ** {n = Pl} ;
+lin pot1plus d e = {
+   s = \\c => d.s ! ten ! NCard ++ "-" ++ e.s ! unit ! c ; n = Pl} ;
+lin pot1as2 n = n ;
+lin pot2 d = {s = \\c => d.s ! unit ! NCard ++ mkCard c "hundred"}  ** {n = Pl} ;
+lin pot2plus d e = {
+  s = \\c => d.s ! unit ! NCard ++ "hundred" ++ "and" ++ e.s ! c ; n = Pl} ;
+lin pot2as3 n = n ;
+lin pot3 n = {
+  s = \\c => n.s ! NCard ++ mkCard c "thousand" ; n = Pl} ;
+lin pot3plus n m = {
+  s = \\c => n.s ! NCard ++ "thousand" ++ m.s ! c ; n = Pl} ;
+
+-- numerals as sequences of digits
+
+  lincat 
+    Dig = TDigit ;
+
+  lin
+    IDig d = d ** {tail = T1} ;
+
+    IIDig d i = {
+      s = \\o => d.s ! NCard ++ commaIf i.tail ++ i.s ! o ;
+      n = Pl ;
+      tail = inc i.tail
+    } ;
+
+    D_0 = mkDig "0" ;
+    D_1 = mk3Dig "1" "1st" Sg ;
+    D_2 = mk2Dig "2" "2nd" ;
+    D_3 = mk2Dig "3" "3rd" ;
+    D_4 = mkDig "4" ;
+    D_5 = mkDig "5" ;
+    D_6 = mkDig "6" ;
+    D_7 = mkDig "7" ;
+    D_8 = mkDig "8" ;
+    D_9 = mkDig "9" ;
+
+  oper
+    commaIf : DTail -> Str = \t -> case t of {
+      T3 => "," ;
+      _ => []
+      } ;
+
+    inc : DTail -> DTail = \t -> case t of {
+      T1 => T2 ;
+      T2 => T3 ;
+      T3 => T1
+      } ;
+
+    mk2Dig : Str -> Str -> TDigit = \c,o -> mk3Dig c o Pl ;
+    mkDig : Str -> TDigit = \c -> mk2Dig c (c + "th") ;
+
+    mk3Dig : Str -> Str -> Number -> TDigit = \c,o,n -> {
+      s = table {NCard => c ; NOrd => o} ;
+      n = n
+      } ;
+
+    TDigit = {
+      n : Number ;
+      s : CardOrd => Str
+    } ;
+
+}
diff --git a/old-lib/resource/english/ParadigmsEng.gf b/old-lib/resource/english/ParadigmsEng.gf
new file mode 100644
index 000000000..9ce081457
--- /dev/null
+++ b/old-lib/resource/english/ParadigmsEng.gf
@@ -0,0 +1,577 @@
+--# -path=.:../abstract:../../prelude:../common
+
+--1 English Lexical Paradigms
+--
+-- Aarne Ranta 2003--2005
+--
+-- This is an API for the user of the resource grammar 
+-- for adding lexical items. It gives functions for forming
+-- expressions of open categories: nouns, adjectives, verbs.
+-- 
+-- Closed categories (determiners, pronouns, conjunctions) are
+-- accessed through the resource syntax API, $Structural.gf$. 
+--
+-- The main difference with $MorphoEng.gf$ is that the types
+-- referred to are compiled resource grammar types. We have moreover
+-- had the design principle of always having existing forms, rather
+-- than stems, as string arguments of the paradigms.
+--
+-- The structure of functions for each word class $C$ is the following:
+-- first we give a handful of patterns that aim to cover all
+-- regular cases. Then we give a worst-case function $mkC$, which serves as an
+-- escape to construct the most irregular words of type $C$.
+-- However, this function should only seldom be needed: we have a
+-- separate module [``IrregEng`` ../../english/IrregEng.gf], 
+-- which covers irregular verbss.
+
+resource ParadigmsEng = open 
+  (Predef=Predef), 
+  Prelude, 
+  MorphoEng,
+  CatEng
+  in {
+--2 Parameters 
+--
+-- To abstract over gender names, we define the following identifiers.
+
+oper
+  Gender : Type ; 
+
+  human     : Gender ;
+  nonhuman  : Gender ;
+  masculine : Gender ;
+  feminine : Gender ;
+
+-- To abstract over number names, we define the following.
+
+  Number : Type ; 
+
+  singular : Number ;
+  plural   : Number ;
+
+-- To abstract over case names, we define the following.
+
+  Case : Type ;
+
+  nominative : Case ;
+  genitive   : Case ;
+
+-- Prepositions are used in many-argument functions for rection.
+-- The resource category $Prep$ is used.
+
+
+
+--2 Nouns
+
+-- Nouns are constructed by the function $mkN$, which takes a varying
+-- number of arguments.
+
+  mkN : overload {
+
+-- The regular function captures the variants for nouns ending with
+-- "s","sh","x","z" or "y": "kiss - kisses", "flash - flashes"; 
+-- "fly - flies" (but "toy - toys"),
+
+    mkN : (flash : Str) -> N ;
+
+-- In practice the worst case is to give singular and plural nominative.
+
+    mkN : (man,men : Str) -> N ;
+
+-- The theoretical worst case: give all four forms.
+
+    mkN : (man,men,man's,men's : Str) -> N ;
+
+-- Change gender from the default $nonhuman$.
+
+    mkN : Gender -> N -> N ;
+
+--3 Compound nouns 
+--
+-- A compound noun is an uninflected string attached to an inflected noun,
+-- such as "baby boom", "chief executive officer".
+
+    mkN : Str -> N -> N
+  } ;
+
+
+--3 Relational nouns 
+-- 
+-- Relational nouns ("daughter of x") need a preposition. 
+
+  mkN2 : N -> Prep -> N2 ;
+
+-- The most common preposition is "of", and the following is a
+-- shortcut for regular relational nouns with "of".
+
+  regN2 : Str -> N2 ;
+
+-- Use the function $mkPrep$ or see the section on prepositions below to  
+-- form other prepositions.
+--
+-- Three-place relational nouns ("the connection from x to y") need two prepositions.
+
+  mkN3 : N -> Prep -> Prep -> N3 ;
+
+
+
+--3 Proper names and noun phrases
+--
+-- Proper names, with a regular genitive, are formed from strings.
+
+  mkPN : overload {
+
+    mkPN : Str -> PN ;
+
+-- Sometimes a common noun can be reused as a proper name, e.g. "Bank"
+
+    mkPN : N -> PN
+  } ;
+
+
+--2 Adjectives
+
+  mkA : overload {
+
+-- For regular adjectives, the adverbial and comparison forms are derived. This holds
+-- even for cases with the variations "happy - happily - happier - happiest",
+-- "free - freely - freer - freest", and "rude - rudest".
+
+    mkA : (happy : Str) -> A ;
+
+-- However, the duplication of the final consonant cannot be predicted,
+-- but a separate case is used to give the comparative
+
+    mkA : (fat,fatter : Str) -> A ;
+
+-- As many as four forms may be needed.
+
+    mkA : (good,better,best,well : Str) -> A 
+    } ;
+
+-- To force comparison to be formed by "more - most", 
+-- the following function is used:
+
+    compoundA : A -> A ; -- -/more/most ridiculous
+
+
+
+--3 Two-place adjectives
+--
+-- Two-place adjectives need a preposition for their second argument.
+
+  mkA2 : A -> Prep -> A2 ;
+
+
+
+--2 Adverbs
+
+-- Adverbs are not inflected. Most lexical ones have position
+-- after the verb. Some can be preverbal (e.g. "always").
+
+  mkAdv : Str -> Adv ;
+  mkAdV : Str -> AdV ;
+
+-- Adverbs modifying adjectives and sentences can also be formed.
+
+  mkAdA : Str -> AdA ;
+
+--2 Prepositions
+--
+-- A preposition as used for rection in the lexicon, as well as to
+-- build $PP$s in the resource API, just requires a string.
+
+  mkPrep : Str -> Prep ;
+  noPrep : Prep ;
+
+-- (These two functions are synonyms.)
+
+--2 Verbs
+--
+
+-- Verbs are constructed by the function $mkV$, which takes a varying
+-- number of arguments.
+
+  mkV : overload {
+
+-- The regular verb function recognizes the special cases where the last
+-- character is "y" ("cry-cries" but "buy-buys") or a sibilant
+-- ("kiss-"kisses", "jazz-jazzes", "rush-rushes", "munch - munches", 
+-- "fix - fixes").
+
+    mkV : (cry : Str) -> V ;
+
+-- Give the present and past forms for regular verbs where
+-- the last letter is duplicated in some forms,
+-- e.g. "rip - ripped - ripping".
+
+    mkV : (stop, stopped : Str) -> V ;
+
+-- There is an extensive list of irregular verbs in the module $IrregularEng$.
+-- In practice, it is enough to give three forms, 
+-- e.g. "drink - drank - drunk".
+
+    mkV : (drink, drank, drunk  : Str) -> V ;
+
+-- Irregular verbs with duplicated consonant in the present participle.
+ 
+    mkV : (run, ran, run, running  : Str) -> V ;
+
+-- Except for "be", the worst case needs five forms: the infinitive and
+-- the third person singular present, the past indicative, and the
+-- past and present participles.
+
+    mkV : (go, goes, went, gone, going : Str) -> V
+  };
+
+-- Verbs with a particle.
+-- The particle, such as in "switch on", is given as a string.
+
+  partV  : V -> Str -> V ;
+
+-- Reflexive verbs.
+-- By default, verbs are not reflexive; this function makes them that.
+
+  reflV  : V -> V ;
+
+--3 Two-place verbs
+--
+-- Two-place verbs need a preposition, except the special case with direct object.
+-- (transitive verbs). Notice that a particle comes from the $V$.
+
+  mkV2 : overload {
+    mkV2  : V -> Prep -> V2 ; -- believe in
+    mkV2  : V -> V2           -- kill
+  };
+
+--3 Three-place verbs
+--
+-- Three-place (ditransitive) verbs need two prepositions, of which
+-- the first one or both can be absent.
+
+  mkV3     : V -> Prep -> Prep -> V3 ;   -- speak, with, about
+  dirV3    : V -> Prep -> V3 ;           -- give,_,to
+  dirdirV3 : V -> V3 ;                   -- give,_,_
+
+--3 Other complement patterns
+--
+-- Verbs and adjectives can take complements such as sentences,
+-- questions, verb phrases, and adjectives.
+
+  mkV0  : V -> V0 ;
+  mkVS  : V -> VS ;
+  mkV2S : V -> Prep -> V2S ;
+  mkVV  : V -> VV ;
+  mkV2V : V -> Prep -> Prep -> V2V ;
+  mkVA  : V -> VA ;
+  mkV2A : V -> Prep -> V2A ;
+  mkVQ  : V -> VQ ;
+  mkV2Q : V -> Prep -> V2Q ;
+
+  mkAS  : A -> AS ;
+  mkA2S : A -> Prep -> A2S ;
+  mkAV  : A -> AV ;
+  mkA2V : A -> Prep -> A2V ;
+
+-- Notice: Categories $V0, AS, A2S, AV, A2V$ are just $A$.
+-- $V0$ is just $V$; the second argument is treated as adverb.
+
+  V0 : Type ;
+  AS, A2S, AV, A2V : Type ;
+
+--.
+--2 Definitions of paradigms
+--
+-- The definitions should not bother the user of the API. So they are
+-- hidden from the document.
+
+  Gender = MorphoEng.Gender ; 
+  Number = MorphoEng.Number ;
+  Case = MorphoEng.Case ;
+  human = Masc ; 
+  nonhuman = Neutr ;
+  masculine = Masc ;
+  feminine = Fem ;
+  singular = Sg ;
+  plural = Pl ;
+  nominative = Nom ;
+  genitive = Gen ;
+
+  Preposition : Type = Str ; -- obsolete
+
+  regN = \ray -> 
+    let rays = add_s ray
+     in
+       mk2N ray rays ;
+
+
+  add_s : Str -> Str = \w -> case w of {
+    _ + ("io" | "oo")                         => w + "s" ;   -- radio, bamboo
+    _ + ("s" | "z" | "x" | "sh" | "ch" | "o") => w + "es" ;  -- bus, hero
+    _ + ("a" | "o" | "u" | "e") + "y"  => w + "s" ;   -- boy
+    x + "y"                            => x + "ies" ; -- fly
+    _                                  => w + "s"     -- car
+    } ;
+
+  mk2N = \man,men -> 
+    let mens = case last men of {
+      "s" => men + "'" ;
+      _   => men + "'s"
+      }
+    in
+    mk4N man men (man + "'s") mens ;
+
+  mk4N = \man,men,man's,men's -> 
+    mkNoun man man's men men's ** {g = Neutr ; lock_N = <>} ;
+
+  genderN g man = {s = man.s ; g = g ; lock_N = <>} ;
+
+  compoundN s n = {s = \\x,y => s ++ n.s ! x ! y ; g=n.g ; lock_N = <>} ;
+
+  mkPN = overload {
+    mkPN : Str -> PN = regPN ;
+    mkPN : N -> PN = nounPN
+  } ;
+
+
+  mkN2 = \n,p -> n ** {lock_N2 = <> ; c2 = p.s} ;
+  regN2 n = mkN2 (regN n) (mkPrep "of") ;
+  mkN3 = \n,p,q -> n ** {lock_N3 = <> ; c2 = p.s ; c3 = q.s} ;
+
+--3 Relational common noun phrases
+--
+-- In some cases, you may want to make a complex $CN$ into a
+-- relational noun (e.g. "the old town hall of").
+
+  cnN2 : CN -> Prep -> N2 ;
+  cnN3 : CN -> Prep -> Prep -> N3 ;
+
+-- This is obsolete.
+  cnN2 = \n,p -> n ** {lock_N2 = <> ; c2 = p.s} ;
+  cnN3 = \n,p,q -> n ** {lock_N3 = <> ; c2 = p.s ; c3 = q.s} ;
+
+  regPN n = regGenPN n human ;
+  regGenPN n g = nameReg n g ** {g = g ; lock_PN = <>} ;
+  nounPN n = {s = n.s ! singular ; g = n.g ; lock_PN = <>} ;
+
+  mk2A a b = mkAdjective a a a b ** {lock_A = <>} ;
+  regA a = regADeg a ** {lock_A = <>} ;
+
+  mkA2 a p = a ** {c2 = p.s ; lock_A2 = <>} ;
+
+  ADeg = A ; ----
+
+  mkADeg a b c d = mkAdjective a b c d ** {lock_A = <>} ;
+
+  regADeg happy = 
+    let
+      happ = init happy ;
+      y    = last happy ;
+      happie = case y of {
+        "y" => happ + "ie" ;
+        "e" => happy ;
+        _   => happy + "e"
+        } ;
+      happily : Str = case happy of {
+        _ + "y" => happ + "ily" ;
+        _ + "ll" => happy + "y" ;
+        _   => happy + "ly"
+        } ;
+    in mkADeg happy (happie + "r") (happie + "st") happily ;
+
+  duplADeg fat = 
+    mkADeg fat 
+    (fat + last fat + "er") (fat + last fat + "est") (fat + "ly") ;
+
+  compoundADeg a =
+    let ad = (a.s ! AAdj Posit) 
+    in mkADeg ad ("more" ++ ad) ("most" ++ ad) (a.s ! AAdv) ;
+
+  adegA a = a ;
+
+  mkAdv x = ss x ** {lock_Adv = <>} ;
+  mkAdV x = ss x ** {lock_AdV = <>} ;
+  mkAdA x = ss x ** {lock_AdA = <>} ;
+
+  mkPrep p = ss p ** {lock_Prep = <>} ;
+  noPrep = mkPrep [] ;
+
+  mk5V a b c d e = mkVerb a b c d e ** {s1 = [] ; lock_V = <>} ;
+
+  regV cry = 
+    let
+      cr = init cry ;
+      y  = last cry ;
+      cries = (regN cry).s ! Pl ! Nom ; -- !
+      crie  = init cries ;
+      cried = case last crie of {
+        "e" => crie + "d" ;
+        _   => crie + "ed"
+        } ;
+      crying = case y of {
+        "e" => case last cr of {
+           "e" => cry + "ing" ; 
+           _ => cr + "ing" 
+           } ;
+        _   => cry + "ing"
+        }
+    in mk5V cry cries cried cried crying ;
+
+  reg2V fit fitted =
+   let fitt = Predef.tk 2 fitted ;
+   in mk5V fit (fit + "s") (fitt + "ed") (fitt + "ed") (fitt + "ing") ;
+
+  regDuplV fit = 
+    case last fit of {
+      ("a" | "e" | "i" | "o" | "u" | "y") => 
+        Predef.error (["final duplication makes no sense for"] ++ fit) ;
+      t =>
+       let fitt = fit + t in
+       mk5V fit (fit + "s") (fitt + "ed") (fitt + "ed") (fitt + "ing")
+      } ;
+
+  irregV x y z = let reg = (regV x).s in
+    mk5V x (reg ! VPres) y z (reg ! VPresPart) ** {s1 = [] ; lock_V = <>} ;
+
+  irreg4V x y z w = let reg = (regV x).s in
+    mk5V x (reg ! VPres) y z w ** {s1 = [] ; lock_V = <>} ;
+
+  irregDuplV fit y z = 
+    let 
+      fitting = (regDuplV fit).s ! VPresPart
+    in
+    mk5V fit (fit + "s") y z fitting ;
+
+  partV v p = verbPart v p ** {lock_V = <>} ;
+  reflV v = {s = v.s ; part = v.part ; lock_V = v.lock_V ; isRefl = True} ;
+
+  prepV2 v p = v ** {s = v.s ; s1 = v.s1 ; c2 = p.s ; lock_V2 = <>} ;
+  dirV2 v = prepV2 v noPrep ;
+
+  mkV3 v p q = v ** {s = v.s ; s1 = v.s1 ; c2 = p.s ; c3 = q.s ; lock_V3 = <>} ;
+  dirV3 v p = mkV3 v noPrep p ;
+  dirdirV3 v = dirV3 v noPrep ;
+
+  mkVS  v = v ** {lock_VS = <>} ;
+  mkVV  v = {
+    s = table {VVF vf => v.s ! vf ; _ => variants {}} ; 
+    isAux = False ; lock_VV = <>
+    } ;
+  mkVQ  v = v ** {lock_VQ = <>} ;
+
+  V0 : Type = V ;
+--  V2S, V2V, V2Q : Type = V2 ;
+  AS, A2S, AV : Type = A ;
+  A2V : Type = A2 ;
+
+  mkV0  v = v ** {lock_V = <>} ;
+  mkV2S v p = prepV2 v p ** {lock_V2S = <>} ;
+  mkV2V v p t = prepV2 v p ** {isAux = False ; lock_V2V = <>} ;
+  mkVA  v = v ** {lock_VA = <>} ;
+  mkV2A v p = prepV2 v p ** {lock_V2A = <>} ;
+  mkV2Q v p = prepV2 v p ** {lock_V2Q = <>} ;
+
+  mkAS  v = v ** {lock_A = <>} ;
+  mkA2S v p = mkA2 v p ** {lock_A = <>} ;
+  mkAV  v = v ** {lock_A = <>} ;
+  mkA2V v p = mkA2 v p ** {lock_A2 = <>} ;
+
+
+-- pre-overload API and overload definitions
+
+  mk4N : (man,men,man's,men's : Str) -> N ;
+  regN : Str -> N ;
+  mk2N : (man,men : Str) -> N ;
+  genderN : Gender -> N -> N ;
+  compoundN : Str -> N -> N ;
+
+  mkN = overload {
+    mkN : (man,men,man's,men's : Str) -> N = mk4N ;
+    mkN : Str -> N = regN ;
+    mkN : (man,men : Str) -> N = mk2N ;
+    mkN : Gender -> N -> N = genderN ;
+    mkN : Str -> N -> N = compoundN
+    } ;
+
+
+  mk2A : (free,freely : Str) -> A ;
+  regA : Str -> A ;
+
+  mkA = overload {
+    mkA : Str -> A = regA ;
+    mkA : (fat,fatter : Str) -> A = \fat,fatter -> 
+      mkAdjective fat fatter (init fatter + "st") (fat + "ly") ** {lock_A = <>} ;
+    mkA : (good,better,best,well : Str) -> A = \a,b,c,d ->
+      mkAdjective a b c d  ** {lock_A = <>}
+    } ;
+
+  compoundA = compoundADeg ;
+
+
+  mk5V : (go, goes, went, gone, going : Str) -> V ;
+  regV : (cry : Str) -> V ;
+  reg2V : (stop, stopped : Str) -> V;
+  irregV : (drink, drank, drunk  : Str) -> V ;
+  irreg4V : (run, ran, run, running  : Str) -> V ;
+
+  -- Use reg2V instead
+  regDuplV : Str -> V ;
+  -- Use irreg4V instead
+  irregDuplV : (get,   got,   gotten : Str) -> V ;
+
+  mkV = overload {
+    mkV : (cry : Str) -> V = regV ;
+    mkV : (stop, stopped : Str) -> V = reg2V ;
+    mkV : (drink, drank, drunk  : Str) -> V = irregV ;
+    mkV : (run, ran, run, running  : Str) -> V = irreg4V ;
+    mkV : (go, goes, went, gone, going : Str) -> V = mk5V
+  };
+
+  prepV2 : V -> Prep -> V2 ;
+  dirV2 : V -> V2 ;
+
+  mkV2 = overload {
+    mkV2  : V -> Prep -> V2 = prepV2;
+    mkV2  : V -> V2 = dirV2
+  }; 
+
+
+---- obsolete
+
+-- Comparison adjectives may two more forms. 
+
+  ADeg : Type ;
+
+  mkADeg : (good,better,best,well : Str) -> ADeg ;
+
+-- The regular pattern recognizes two common variations: 
+-- "-e" ("rude" - "ruder" - "rudest") and
+-- "-y" ("happy - happier - happiest - happily")
+
+  regADeg : Str -> ADeg ;      -- long, longer, longest
+
+-- However, the duplication of the final consonant is nor predicted,
+-- but a separate pattern is used:
+
+  duplADeg : Str -> ADeg ;      -- fat, fatter, fattest
+
+-- If comparison is formed by "more", "most", as in general for
+-- long adjective, the following pattern is used:
+
+  compoundADeg : A -> ADeg ; -- -/more/most ridiculous
+
+-- From a given $ADeg$, it is possible to get back to $A$.
+
+  adegA : ADeg -> A ;
+
+
+  regPN    : Str -> PN ;          
+  regGenPN : Str -> Gender -> PN ;     -- John, John's
+
+-- Sometimes you can reuse a common noun as a proper name, e.g. "Bank".
+
+  nounPN : N -> PN ;
+
+
+
+} ;
diff --git a/old-lib/resource/english/PhraseEng.gf b/old-lib/resource/english/PhraseEng.gf
new file mode 100644
index 000000000..c635d4b98
--- /dev/null
+++ b/old-lib/resource/english/PhraseEng.gf
@@ -0,0 +1,24 @@
+concrete PhraseEng of Phrase = CatEng ** open Prelude, ResEng in {
+
+  lin
+    PhrUtt pconj utt voc = {s = pconj.s ++ utt.s ++ voc.s} ;
+
+    UttS s = s ;
+    UttQS qs = {s = qs.s ! QDir} ;
+    UttImpSg pol imp = {s = pol.s ++ imp.s ! contrNeg True pol.p ! ImpF Sg False} ;
+    UttImpPl pol imp = {s = pol.s ++ imp.s ! contrNeg True pol.p ! ImpF Pl False} ;
+    UttImpPol pol imp = {s = pol.s ++ imp.s ! contrNeg True pol.p ! ImpF Sg True} ;
+
+    UttIP ip = {s = ip.s ! Nom} ; --- Acc also
+    UttIAdv iadv = iadv ;
+    UttNP np = {s = np.s ! Nom} ;
+    UttVP vp = {s = infVP False vp (agrP3 Sg)} ;
+    UttAdv adv = adv ;
+
+    NoPConj = {s = []} ;
+    PConjConj conj = {s = conj.s2} ; ---
+
+    NoVoc = {s = []} ;
+    VocNP np = {s = "," ++ np.s ! Nom} ;
+
+}
diff --git a/old-lib/resource/english/QuestionEng.gf b/old-lib/resource/english/QuestionEng.gf
new file mode 100644
index 000000000..2fc894932
--- /dev/null
+++ b/old-lib/resource/english/QuestionEng.gf
@@ -0,0 +1,55 @@
+concrete QuestionEng of Question = CatEng ** open ResEng, Prelude in {
+
+  flags optimize=all_subs ;
+
+  lin
+
+    QuestCl cl = {
+      s = \\t,a,p => 
+            let cls = cl.s ! t ! a ! p 
+            in table {
+              QDir   => cls ! OQuest ;
+              QIndir => "if" ++ cls ! ODir
+              } ---- "whether" in ExtEng
+      } ;
+
+    QuestVP qp vp = 
+      let cl = mkClause (qp.s ! Nom) (agrP3 qp.n) vp
+      in {s = \\t,a,b,_ => cl.s ! t ! a ! b ! ODir} ;
+
+    QuestSlash ip slash = 
+      mkQuestion (ss (slash.c2 ++ ip.s ! Acc)) slash ;
+      --- stranding in ExratEng 
+
+    QuestIAdv iadv cl = mkQuestion iadv cl ;
+
+    QuestIComp icomp np = 
+      mkQuestion icomp (mkClause (np.s ! Nom) np.a (predAux auxBe)) ;
+
+
+    PrepIP p ip = {s = p.s ++ ip.s ! Acc} ;
+
+    AdvIP ip adv = {
+      s = \\c => ip.s ! c ++ adv.s ;
+      n = ip.n
+      } ;
+ 
+    IdetCN idet cn = {
+      s = \\c => idet.s ++ cn.s ! idet.n ! c ; 
+      n = idet.n
+      } ;
+
+    IdetIP idet = {
+      s = \\c => idet.s ; 
+      n = idet.n
+      } ;
+
+    IdetQuant idet num = {
+      s = idet.s ! num.n ++ num.s ; 
+      n = num.n
+      } ;
+
+    CompIAdv a = a ;
+    CompIP p = ss (p.s ! Nom) ;
+
+}
diff --git a/old-lib/resource/english/RelativeEng.gf b/old-lib/resource/english/RelativeEng.gf
new file mode 100644
index 000000000..1ec1fc10a
--- /dev/null
+++ b/old-lib/resource/english/RelativeEng.gf
@@ -0,0 +1,54 @@
+concrete RelativeEng of Relative = CatEng ** open ResEng in {
+
+  flags optimize=all_subs ;
+
+  lin
+
+    RelCl cl = {
+      s = \\t,a,p,_ => "such" ++ "that" ++ cl.s ! t ! a ! p ! ODir ; 
+      c = Nom
+      } ;
+
+    RelVP rp vp = {
+      s = \\t,ant,b,ag => 
+        let 
+          agr = case rp.a of {
+            RNoAg => ag ;
+            RAg a => a
+            } ;
+          cl = mkClause (rp.s ! RC (fromAgr agr).g Nom) agr vp
+        in
+        cl.s ! t ! ant ! b ! ODir ;
+      c = Nom
+      } ;
+
+-- Pied piping: "at which we are looking". Stranding and empty
+-- relative are defined in $ExtraEng.gf$ ("that we are looking at", 
+-- "we are looking at").
+
+    RelSlash rp slash = {
+      s = \\t,a,p,agr => 
+          slash.c2 ++ rp.s ! RPrep (fromAgr agr).g ++ slash.s ! t ! a ! p ! ODir ;
+      c = Acc
+      } ;
+
+    FunRP p np rp = {
+      s = \\c => np.s ! Acc ++ p.s ++ rp.s ! RPrep (fromAgr np.a).g ;
+      a = RAg np.a
+      } ;
+
+    IdRP = 
+      let varr : Str -> Str = \x -> variants {x ; "that"} --- for bwc
+      in {
+      s = table {
+        RC _ Gen => "whose" ; 
+        RC Neutr _  => varr "which" ;
+        RC _ Acc    => varr "whom" ;
+        RC _ Nom    => varr "who" ;
+        RPrep Neutr => "which" ;
+        RPrep _     => "whom"
+        } ;
+      a = RNoAg
+      } ;
+
+}
diff --git a/old-lib/resource/english/ResEng.gf b/old-lib/resource/english/ResEng.gf
new file mode 100644
index 000000000..866ac2154
--- /dev/null
+++ b/old-lib/resource/english/ResEng.gf
@@ -0,0 +1,479 @@
+--# -path=.:../abstract:../common:../../prelude
+
+--1 English auxiliary operations.
+
+-- This module contains operations that are needed to make the
+-- resource syntax work. To define everything that is needed to
+-- implement $Test$, it moreover contains regular lexical
+-- patterns needed for $Lex$.
+
+resource ResEng = ParamX ** open Prelude in {
+
+  flags optimize=all ;
+
+
+-- Some parameters, such as $Number$, are inherited from $ParamX$.
+
+--2 For $Noun$
+
+-- This is the worst-case $Case$ needed for pronouns.
+
+  param
+    Case = Nom | Acc | Gen ;
+
+-- Agreement of $NP$ has 8 values. $Gender$ is needed for "who"/"which" and
+-- for "himself"/"herself"/"itself".
+
+  param
+    Agr = AgP1 Number | AgP2 Number | AgP3Sg Gender | AgP3Pl ;
+
+  param 
+    Gender = Neutr | Masc | Fem ;
+
+--2 For $Verb$
+
+-- Only these five forms are needed for open-lexicon verbs.
+
+  param
+    VForm = 
+       VInf
+     | VPres
+     | VPPart
+     | VPresPart
+     | VPast      --# notpresent
+     ;
+
+-- Auxiliary verbs have special negative forms.
+
+    VVForm = 
+       VVF VForm
+     | VVPresNeg
+     | VVPastNeg  --# notpresent
+     ;
+
+-- The order of sentence is needed already in $VP$.
+
+    Order = ODir | OQuest ;
+
+
+--2 For $Adjective$
+
+    AForm = AAdj Degree | AAdv ;
+
+--2 For $Relative$
+ 
+    RAgr = RNoAg | RAg Agr ;
+    RCase = RPrep Gender | RC Gender Case ;
+
+--2 For $Numeral$
+
+    CardOrd = NCard | NOrd ;
+    DForm = unit | teen | ten  ;
+
+--2 Transformations between parameter types
+
+  oper
+    toAgr : Number -> Person -> Gender -> Agr = \n,p,g -> 
+      case p of {
+        P1 => AgP1 n ;
+        P2 => AgP2 n ;
+        P3 => case n of {
+          Sg => AgP3Sg g ;
+          Pl => AgP3Pl
+          }
+        } ;
+
+    fromAgr : Agr -> {n : Number ; p : Person ; g : Gender} = \a -> case a of {
+      AgP1 n => {n = n ; p = P1 ; g = Masc} ;
+      AgP2 n => {n = n ; p = P2 ; g = Masc} ;
+      AgP3Pl => {n = Pl ; p = P3 ; g = Masc} ;
+      AgP3Sg g => {n = Sg ; p = P3 ; g = g}
+      } ;
+
+    agrP3 : Number -> Agr = \n -> agrgP3 n Neutr ;
+
+    agrgP3 : Number -> Gender -> Agr = \n,g -> toAgr n P3 g ;
+
+    conjAgr : Agr -> Agr -> Agr = \a0,b0 -> 
+      let a = fromAgr a0 ; b = fromAgr b0 
+      in
+      toAgr
+        (conjNumber a.n b.n)
+        (conjPerson a.p b.p) a.g ;
+
+-- For $Lex$.
+
+-- For each lexical category, here are the worst-case constructors.
+
+    mkNoun : (_,_,_,_ : Str) -> {s : Number => Case => Str} = 
+      \man,mans,men,mens -> {
+      s = table {
+        Sg => table {
+          Gen => mans ;
+          _ => man
+          } ;
+        Pl => table {
+          Gen => mens ;
+          _ => men
+          }
+        }
+      } ;
+
+    mkAdjective : (_,_,_,_ : Str) -> {s : AForm => Str} = 
+      \good,better,best,well -> {
+      s = table {
+        AAdj Posit  => good ;
+        AAdj Compar => better ;
+        AAdj Superl => best ;
+        AAdv        => well
+        }
+      } ;
+
+    mkVerb : (_,_,_,_,_ : Str) -> Verb = 
+      \go,goes,went,gone,going -> {
+      s = table {
+        VInf   => go ;
+        VPres  => goes ;
+        VPast  => went ; --# notpresent
+        VPPart => gone ;
+        VPresPart => going
+        } ;
+      isRefl = False
+      } ;
+
+    mkIP : (i,me,my : Str) -> Number -> {s : Case => Str ; n : Number} =
+     \i,me,my,n -> let who = mkNP i me my n P3 Neutr in {
+        s = who.s ; 
+        n = n
+        } ;
+
+    mkNP : (i,me,my : Str) -> Number -> Person -> Gender -> 
+     {s : Case => Str ; a : Agr} =
+     \i,me,my,n,p,g -> {
+     s = table {
+       Nom => i ;
+       Acc => me ;
+       Gen => my
+       } ;
+     a = toAgr n p g ;
+     } ;
+
+-- These functions cover many cases; full coverage inflectional patterns are
+-- in $MorphoEng$.
+
+    regN : Str -> {s : Number => Case => Str} = \car ->
+      mkNoun car (car + "'s") (car + "s") (car + "s'") ;
+
+    regA : Str -> {s : AForm => Str} = \warm ->
+      mkAdjective warm (warm + "er") (warm + "est") (warm + "ly") ;
+
+    regV : Str -> Verb = \walk ->
+      mkVerb walk (walk + "s") (walk + "ed") (walk + "ed") (walk + "ing") ;
+
+    regNP : Str -> Number -> {s : Case => Str ; a : Agr} = \that,n ->
+      mkNP that that (that + "'s") n P3 Neutr ;
+
+-- We have just a heuristic definition of the indefinite article.
+-- There are lots of exceptions: consonantic "e" ("euphemism"), consonantic
+-- "o" ("one-sided"), vocalic "u" ("umbrella").
+
+    artIndef = pre {
+      "a" ; 
+      "an" / strs {"a" ; "e" ; "i" ; "o" ; "A" ; "E" ; "I" ; "O" }
+      } ;
+
+    artDef = "the" ;
+
+-- For $Verb$.
+
+  Verb : Type = {
+    s : VForm => Str ;
+    isRefl : Bool
+    } ;
+
+  param
+  CPolarity = 
+     CPos
+   | CNeg Bool ;  -- contracted or not
+
+  oper
+  contrNeg : Bool -> Polarity -> CPolarity = \b,p -> case p of {
+    Pos => CPos ;
+    Neg => CNeg b
+    } ;
+
+  VerbForms : Type =
+    Tense => Anteriority => CPolarity => Order => Agr => 
+      {aux, adv, fin, inf : Str} ; -- would, not, sleeps, slept
+
+  VP : Type = {
+    s   : VerbForms ;
+    prp : Str ;   -- present participle 
+    inf : Str ;   -- the infinitive form ; VerbForms would be the logical place
+    ad  : Str ;   -- sentence adverb
+    s2  : Agr => Str -- complement
+    } ;
+
+
+  SlashVP = VP ** {c2 : Str} ;
+
+  predVc : (Verb ** {c2 : Str}) -> SlashVP = \verb -> 
+    predV verb ** {c2 = verb.c2} ;
+
+  predV : Verb -> VP = \verb -> {
+    s = \\t,ant,b,ord,agr => 
+      let
+        inf  = verb.s ! VInf ;
+        fin  = presVerb verb agr ;
+        part = verb.s ! VPPart ;
+      in
+      case <t,ant,b,ord> of {
+        <Pres,Simul,CPos,ODir>   => vff            fin [] ;
+        <Pres,Simul,CPos,OQuest> => vf (does agr)   inf ;
+        <Pres,Anter,CPos,_>      => vf (have agr)   part ; --# notpresent
+        <Pres,Anter,CNeg c,_>    => vfn c (have agr) (havent agr) part ; --# notpresent
+        <Past,Simul,CPos,ODir>   => vff (verb.s ! VPast) [] ; --# notpresent
+        <Past,Simul,CPos,OQuest> => vf "did"        inf ; --# notpresent
+        <Past,Simul,CNeg c,_>    => vfn c "did" "didn't"     inf ; --# notpresent
+        <Past,Anter,CPos,_>      => vf "had"        part ; --# notpresent
+        <Past,Anter,CNeg c,_>    => vfn c "had" "hadn't"     part ; --# notpresent
+        <Fut, Simul,CPos,_>      => vf "will"       inf ; --# notpresent
+        <Fut, Simul,CNeg c,_>    => vfn c "will" "won't"      inf ; --# notpresent
+        <Fut, Anter,CPos,_>      => vf "will"       ("have" ++ part) ; --# notpresent
+        <Fut, Anter,CNeg c,_>    => vfn c "will" "won't"("have" ++ part) ; --# notpresent
+        <Cond,Simul,CPos,_>      => vf "would"      inf ; --# notpresent
+        <Cond,Simul,CNeg c,_>    => vfn c "would" "wouldn't"   inf ; --# notpresent
+        <Cond,Anter,CPos,_>      => vf "would"      ("have" ++ part) ; --# notpresent
+        <Cond,Anter,CNeg c,_> => vfn c "would" "wouldn't" ("have" ++ part) ; --# notpresent
+        <Pres,Simul,CNeg c,_>    => vfn c (does agr) (doesnt agr) inf
+        } ;
+    prp  = verb.s ! VPresPart ;
+    inf  = verb.s ! VInf ;
+    ad   = [] ;
+    s2 = \\a => if_then_Str verb.isRefl (reflPron ! a) []
+    } ;
+
+  predAux : Aux -> VP = \verb -> {
+    s = \\t,ant,cb,ord,agr => 
+      let 
+        b = case cb of {
+          CPos => Pos ;
+          _ => Neg
+          } ;
+        inf  = verb.inf ;
+        fin  = verb.pres ! b ! agr ;
+        finp = verb.pres ! Pos ! agr ;
+        part = verb.ppart ;
+      in
+      case <t,ant,cb,ord> of {
+        <Pres,Anter,CPos,_>      => vf (have agr)   part ;  --# notpresent
+        <Pres,Anter,CNeg c,_>    => vfn c (have agr) (havent agr) part ; --# notpresent
+        <Past,Simul,CPos,  _>    => vf (verb.past ! b ! agr) [] ; --# notpresent
+        <Past,Simul,CNeg c,  _> => vfn c (verb.past!Pos!agr)(verb.past!Neg!agr) [] ; --# notpresent
+        <Past,Anter,CPos,_>      => vf "had"        part ; --# notpresent
+        <Past,Anter,CNeg c,_>    => vfn c "had" "hadn't"     part ; --# notpresent
+        <Fut, Simul,CPos,_>      => vf "will"       inf ; --# notpresent
+        <Fut, Simul,CNeg c,_>    => vfn c "will" "won't"      inf ; --# notpresent
+        <Fut, Anter,CPos,_>      => vf "will"       ("have" ++ part) ; --# notpresent
+        <Fut, Anter,CNeg c,_>    => vfn c "will" "won't"("have" ++ part) ; --# notpresent
+        <Cond,Simul,CPos,_>      => vf "would"      inf ; --# notpresent
+        <Cond,Simul,CNeg c,_>    => vfn c "would" "wouldn't"   inf ; --# notpresent
+        <Cond,Anter,CPos,_>      => vf "would"      ("have" ++ part) ; --# notpresent
+        <Cond,Anter,CNeg c,_> => vfn c "would" "wouldn't" ("have" ++ part) ; --# notpresent
+        <Pres,Simul,CPos,  _>    => vf fin          [] ;
+        <Pres,Simul,CNeg c,  _>  => vfn c finp fin          [] 
+        } ;
+    prp = verb.prpart ;
+    inf = verb.inf ;
+    ad = [] ;
+    s2 = \\_ => []
+    } ;
+        
+  vff : Str -> Str -> {aux, adv, fin, inf : Str} = \x,y -> 
+    {aux = [] ; adv = [] ; fin = x ; inf = y} ;
+
+  vf : Str -> Str -> {aux, adv, fin, inf : Str} = \x,y -> vfn True x x y ;
+
+  vfn : Bool -> Str -> Str -> Str -> {aux, fin, adv, inf : Str} = 
+    \contr,x,y,z -> 
+    case contr of {
+      True  => {aux = y ; adv = [] ; fin = [] ; inf = z} ;
+      False => {aux = x ; adv = "not" ; fin = [] ; inf = z}
+      } ;
+
+  insertObj : (Agr => Str) -> VP -> VP = \obj,vp -> {
+    s = vp.s ;
+    prp = vp.prp ;
+    inf = vp.inf ;
+    ad = vp.ad ;
+    s2 = \\a => vp.s2 ! a ++ obj ! a
+    } ;
+
+  insertObjPre : (Agr => Str) -> VP -> VP = \obj,vp -> {
+    s = vp.s ;
+    prp = vp.prp ;
+    inf = vp.inf ;
+    ad = vp.ad ;
+    s2 = \\a => obj ! a ++ vp.s2 ! a 
+    } ;
+
+  insertObjc : (Agr => Str) -> SlashVP -> SlashVP = \obj,vp -> 
+    insertObj obj vp ** {c2 = vp.c2} ;
+
+--- The adverb should be before the finite verb.
+
+  insertAdV : Str -> VP -> VP = \ad,vp -> {
+    s = vp.s ;
+    prp = vp.prp ;
+    inf = vp.inf ;
+    ad  = vp.ad ++ ad ;
+    s2 = \\a => vp.s2 ! a
+    } ;
+
+-- 
+
+  predVV : {s : VVForm => Str ; isAux : Bool} -> VP = \verb ->
+    let verbs = verb.s
+    in
+    case verb.isAux of {
+      True => predAux {
+        pres = table {
+          Pos => \\_ => verbs ! VVF VPres ;
+          Neg => \\_ => verbs ! VVPresNeg
+          } ;
+        past = table {                       --# notpresent
+          Pos => \\_ => verbs ! VVF VPast ;  --# notpresent
+          Neg => \\_ => verbs ! VVPastNeg    --# notpresent
+          } ;    --# notpresent
+        inf = verbs ! VVF VInf ;
+        ppart = verbs ! VVF VPPart ;
+        prpart = verbs ! VVF VPresPart ;
+        } ;
+      _    => predV {s = \\vf => verbs ! VVF vf ; isRefl = False}
+      } ;
+
+  presVerb : {s : VForm => Str} -> Agr -> Str = \verb -> 
+    agrVerb (verb.s ! VPres) (verb.s ! VInf) ;
+
+  infVP : Bool -> VP -> Agr -> Str = \isAux,vp,a ->
+    vp.ad ++ 
+    case isAux of {True => [] ; False => "to"} ++ 
+    vp.inf ++ vp.s2 ! a ;
+
+  agrVerb : Str -> Str -> Agr -> Str = \has,have,agr -> 
+    case agr of {
+      AgP3Sg _ => has ;
+      _        => have
+      } ;
+
+  have   = agrVerb "has"     "have" ;
+  havent = agrVerb "hasn't"  "haven't" ;
+  does   = agrVerb "does"    "do" ;
+  doesnt = agrVerb "doesn't" "don't" ;
+
+  Aux = {
+    pres : Polarity => Agr => Str ; 
+    past : Polarity => Agr => Str ;  --# notpresent
+    inf,ppart,prpart : Str
+    } ;
+
+  auxBe : Aux = {
+    pres = \\b,a => case <b,a> of {
+      <Pos,AgP1 Sg> => "am" ; 
+      <Neg,AgP1 Sg> => ["am not"] ; --- am not I
+      _ => agrVerb (posneg b "is")  (posneg b "are") a
+      } ;
+    past = \\b,a => case a of {          --# notpresent
+      AgP1 Sg | AgP3Sg _ => posneg b "was" ; --# notpresent
+      _                  => (posneg b "were")  --# notpresent
+      } ; --# notpresent
+    inf  = "be" ;
+    ppart = "been" ;
+    prpart = "being"
+    } ;
+
+  posneg : Polarity -> Str -> Str = \p,s -> case p of {
+    Pos => s ;
+    Neg => s + "n't"
+    } ;
+
+  conjThat : Str = "that" ;
+
+  reflPron : Agr => Str = table {
+    AgP1 Sg      => "myself" ;
+    AgP2 Sg      => "yourself" ;
+    AgP3Sg Masc  => "himself" ;
+    AgP3Sg Fem   => "herself" ;
+    AgP3Sg Neutr => "itself" ;
+    AgP1 Pl      => "ourselves" ;
+    AgP2 Pl      => "yourselves" ;
+    AgP3Pl       => "themselves"
+    } ;
+
+-- For $Sentence$.
+
+  Clause : Type = {
+    s : Tense => Anteriority => CPolarity => Order => Str
+    } ;
+
+  mkClause : Str -> Agr -> VP -> Clause =
+    \subj,agr,vp -> {
+      s = \\t,a,b,o => 
+        let 
+          verb  = vp.s ! t ! a ! b ! o ! agr ;
+          compl = vp.s2 ! agr
+        in
+        case o of {
+          ODir => subj ++ verb.aux ++ verb.adv ++ vp.ad ++ verb.fin ++ verb.inf ++ compl ;
+          OQuest => verb.aux ++ subj ++ verb.adv ++ vp.ad ++ verb.fin ++ verb.inf ++ compl
+          }
+    } ;
+
+
+-- For $Numeral$.
+
+  mkNum : Str -> Str -> Str -> Str -> {s : DForm => CardOrd => Str} = 
+    \two, twelve, twenty, second ->
+    {s = table {
+       unit => table {NCard => two ; NOrd => second} ; 
+       teen => \\c => mkCard c twelve ; 
+       ten  => \\c => mkCard c twenty
+       }
+    } ;
+
+  regNum : Str -> {s : DForm => CardOrd => Str} = 
+    \six -> mkNum six (six + "teen") (six + "ty") (regOrd six) ;
+
+  regCardOrd : Str -> {s : CardOrd => Str} = \ten ->
+    {s = table {NCard => ten ; NOrd => regOrd ten}} ;
+
+  mkCard : CardOrd -> Str -> Str = \c,ten -> 
+    (regCardOrd ten).s ! c ; 
+
+  regOrd : Str -> Str = \ten -> 
+    case last ten of {
+      "y" => init ten + "ieth" ;
+      _   => ten + "th"
+      } ;
+
+  mkQuestion : 
+      {s : Str} -> Clause -> 
+      {s : Tense => Anteriority => CPolarity => QForm => Str} = \wh,cl ->
+      {
+      s = \\t,a,p => 
+            let 
+              cls = cl.s ! t ! a ! p ;
+              why = wh.s
+            in table {
+              QDir   => why ++ cls ! OQuest ;
+              QIndir => why ++ cls ! ODir
+              }
+      } ;
+
+-- for VP conjunction
+
+  param
+    VPIForm = VPIInf | VPIPPart ;
+
+
+}
diff --git a/old-lib/resource/english/SentenceEng.gf b/old-lib/resource/english/SentenceEng.gf
new file mode 100644
index 000000000..f643300ea
--- /dev/null
+++ b/old-lib/resource/english/SentenceEng.gf
@@ -0,0 +1,67 @@
+concrete SentenceEng of Sentence = CatEng ** open Prelude, ResEng in {
+
+  flags optimize=all_subs ;
+
+  lin
+
+    PredVP np vp = mkClause (np.s ! Nom) np.a vp ;
+
+    PredSCVP sc vp = mkClause sc.s (agrP3 Sg) vp ;
+
+    ImpVP vp = {
+      s = \\pol,n => 
+        let 
+          agr   = AgP2 (numImp n) ;
+          verb  = infVP True vp agr ;
+          dont  = case pol of {
+            CNeg True => "don't" ;
+            CNeg False => "do" ++ "not" ;
+            _ => []
+            }
+        in
+        dont ++ verb
+    } ;
+
+    SlashVP np vp = 
+      mkClause (np.s ! Nom) np.a vp ** {c2 = vp.c2} ;
+
+    AdvSlash slash adv = {
+      s  = \\t,a,b,o => slash.s ! t ! a ! b ! o ++ adv.s ;
+      c2 = slash.c2
+    } ;
+
+    SlashPrep cl prep = cl ** {c2 = prep.s} ;
+
+    SlashVS np vs slash = 
+      mkClause (np.s ! Nom) np.a 
+        (insertObj (\\_ => conjThat ++ slash.s) (predV vs))  **
+        {c2 = slash.c2} ;
+
+    EmbedS  s  = {s = conjThat ++ s.s} ;
+    EmbedQS qs = {s = qs.s ! QIndir} ;
+    EmbedVP vp = {s = infVP False vp (agrP3 Sg)} ; --- agr
+
+    UseCl  t a p cl = {
+      s = t.s ++ a.s ++ p.s ++ cl.s ! t.t ! a.a ! ctr p.p ! ODir
+    } ;
+    UseQCl t a p cl = {
+      s = \\q => t.s ++ a.s ++ p.s ++ cl.s ! t.t ! a.a ! ctr p.p ! q
+    } ;
+    UseRCl t a p cl = {
+      s = \\r => t.s ++ a.s ++ p.s ++ cl.s ! t.t ! a.a ! ctr p.p ! r ;
+      c = cl.c
+    } ;
+    UseSlash t a p cl = {
+      s = t.s ++ a.s ++ p.s ++ cl.s ! t.t ! a.a ! ctr p.p  ! ODir ;
+      c2 = cl.c2
+    } ;
+
+    AdvS a s = {s = a.s ++ "," ++ s.s} ;
+
+    RelS s r = {s = s.s ++ "," ++ r.s ! agrP3 Sg} ;
+
+  oper
+    ctr = contrNeg True ;  -- contracted negations
+
+}
+
diff --git a/old-lib/resource/english/StructuralEng.gf b/old-lib/resource/english/StructuralEng.gf
new file mode 100644
index 000000000..d132e1ebb
--- /dev/null
+++ b/old-lib/resource/english/StructuralEng.gf
@@ -0,0 +1,131 @@
+concrete StructuralEng of Structural = CatEng ** 
+  open MorphoEng, (P = ParadigmsEng), Prelude in {
+
+  flags optimize=all ;
+
+  lin
+  above_Prep = ss "above" ;
+  after_Prep = ss "after" ;
+  all_Predet = ss "all" ;
+  almost_AdA, almost_AdN = ss "almost" ;
+  although_Subj = ss "although" ;
+  always_AdV = ss "always" ;
+  and_Conj = sd2 [] "and" ** {n = Pl} ;
+---b  and_Conj = ss "and" ** {n = Pl} ;
+  because_Subj = ss "because" ;
+  before_Prep = ss "before" ;
+  behind_Prep = ss "behind" ;
+  between_Prep = ss "between" ;
+  both7and_DConj = sd2 "both" "and" ** {n = Pl} ;
+  but_PConj = ss "but" ;
+  by8agent_Prep = ss "by" ;
+  by8means_Prep = ss "by" ;
+  can8know_VV, can_VV = {
+    s = table { 
+      VVF VInf => ["be able to"] ;
+      VVF VPres => "can" ;
+      VVF VPPart => ["been able to"] ;
+      VVF VPresPart => ["being able to"] ;
+      VVF VPast => "could" ;      --# notpresent
+      VVPastNeg => "couldn't" ;   --# notpresent
+      VVPresNeg => "can't"
+      } ;
+    isAux = True
+    } ;
+  during_Prep = ss "during" ;
+  either7or_DConj = sd2 "either" "or" ** {n = Sg} ;
+  everybody_NP = regNP "everybody" Sg ;
+  every_Det = mkDeterminer Sg "every" ;
+  everything_NP = regNP "everything" Sg ;
+  everywhere_Adv = ss "everywhere" ;
+  few_Det = mkDeterminer Pl "few" ;
+---  first_Ord = ss "first" ; DEPRECATED
+  for_Prep = ss "for" ;
+  from_Prep = ss "from" ;
+  he_Pron = mkNP "he" "him" "his" Sg P3 Masc ;
+  here_Adv = ss "here" ;
+  here7to_Adv = ss ["to here"] ;
+  here7from_Adv = ss ["from here"] ;
+  how_IAdv = ss "how" ;
+  how8many_IDet = mkDeterminer Pl ["how many"] ;
+  if_Subj = ss "if" ;
+  in8front_Prep = ss ["in front of"] ;
+  i_Pron  = mkNP "I" "me" "my"  Sg P1 Masc ;
+  in_Prep = ss "in" ;
+  it_Pron  = mkNP "it" "it" "its" Sg P3 Neutr ;
+  less_CAdv = ss "less" ;
+  many_Det = mkDeterminer Pl "many" ;
+  more_CAdv = ss "more" ;
+  most_Predet = ss "most" ;
+  much_Det = mkDeterminer Sg "much" ;
+  must_VV = {
+    s = table {
+      VVF VInf => ["have to"] ;
+      VVF VPres => "must" ;
+      VVF VPPart => ["had to"] ;
+      VVF VPresPart => ["having to"] ;
+      VVF VPast => ["had to"] ;      --# notpresent
+      VVPastNeg => ["hadn't to"] ;      --# notpresent
+      VVPresNeg => "mustn't"
+      } ;
+    isAux = True
+    } ;
+---b  no_Phr = ss "no" ;
+  no_Utt = ss "no" ;
+  on_Prep = ss "on" ;
+----  one_Quant = mkDeterminer Sg "one" ; -- DEPRECATED
+  only_Predet = ss "only" ;
+  or_Conj = sd2 [] "or" ** {n = Sg} ;
+  otherwise_PConj = ss "otherwise" ;
+  part_Prep = ss "of" ;
+  please_Voc = ss "please" ;
+  possess_Prep = ss "of" ;
+  quite_Adv = ss "quite" ;
+  she_Pron = mkNP "she" "her" "her" Sg P3 Fem ;
+  so_AdA = ss "so" ;
+  somebody_NP = regNP "somebody" Sg ;
+  someSg_Det = mkDeterminer Sg "some" ;
+  somePl_Det = mkDeterminer Pl "some" ;
+  something_NP = regNP "something" Sg ;
+  somewhere_Adv = ss "somewhere" ;
+  that_Quant = mkQuant "that" "those" ;
+  there_Adv = ss "there" ;
+  there7to_Adv = ss "there" ;
+  there7from_Adv = ss ["from there"] ;
+  therefore_PConj = ss "therefore" ;
+  they_Pron = mkNP "they" "them" "their" Pl P3 Masc ; ---- 
+  this_Quant = mkQuant "this" "these" ;
+  through_Prep = ss "through" ;
+  too_AdA = ss "too" ;
+  to_Prep = ss "to" ;
+  under_Prep = ss "under" ;
+  very_AdA = ss "very" ;
+  want_VV = P.mkVV (P.regV "want") ;
+  we_Pron = mkNP "we" "us" "our" Pl P1 Masc ;
+  whatPl_IP = mkIP "what" "what" "what's" Pl ;
+  whatSg_IP = mkIP "what" "what" "what's" Sg ;
+  when_IAdv = ss "when" ;
+  when_Subj = ss "when" ;
+  where_IAdv = ss "where" ;
+  which_IQuant = {s = \\_ => "which"} ;
+---b  whichPl_IDet = mkDeterminer Pl ["which"] ;
+---b  whichSg_IDet = mkDeterminer Sg ["which"] ;
+  whoPl_IP = mkIP "who" "whom" "whose" Pl ;
+  whoSg_IP = mkIP "who" "whom" "whose" Sg ;
+  why_IAdv = ss "why" ;
+  without_Prep = ss "without" ;
+  with_Prep = ss "with" ;
+---b  yes_Phr = ss "yes" ;
+  yes_Utt = ss "yes" ;
+  youSg_Pron = mkNP "you" "you" "your" Sg P2 Masc ;
+  youPl_Pron = mkNP "you" "you" "your" Pl P2 Masc ;
+  youPol_Pron = mkNP "you" "you" "your" Sg P2 Masc ;
+
+
+oper
+  mkQuant : Str -> Str -> {s : Number => Str} = \x,y -> {
+    s = table Number [x ; y]
+    } ;
+
+}
+
diff --git a/old-lib/resource/english/VerbEng.gf b/old-lib/resource/english/VerbEng.gf
new file mode 100644
index 000000000..b78f6e258
--- /dev/null
+++ b/old-lib/resource/english/VerbEng.gf
@@ -0,0 +1,50 @@
+concrete VerbEng of Verb = CatEng ** open ResEng in {
+
+  flags optimize=all_subs ;
+
+  lin
+    UseV = predV ;
+
+    SlashV2a v = predVc v ;
+    Slash2V3 v np = 
+      insertObjc (\\_ => v.c2 ++ np.s ! Acc) (predV v ** {c2 = v.c3}) ;
+    Slash3V3 v np = 
+      insertObjc (\\_ => v.c3 ++ np.s ! Acc) (predVc v) ; ----
+
+    ComplVV v vp = insertObj (\\a => infVP v.isAux vp a) (predVV v) ;
+    ComplVS v s  = insertObj (\\_ => conjThat ++ s.s) (predV v) ;
+    ComplVQ v q  = insertObj (\\_ => q.s ! QIndir) (predV v) ;
+    ComplVA v ap = insertObj (ap.s) (predV v) ;
+
+    SlashV2V v vp = insertObjc (\\a => infVP v.isAux vp a) (predVc v) ;
+    SlashV2S v s  = insertObjc (\\_ => conjThat ++ s.s) (predVc v) ;
+    SlashV2Q v q  = insertObjc (\\_ => q.s ! QIndir) (predVc v) ;
+    SlashV2A v ap = insertObjc (\\a => ap.s ! a) (predVc v) ; ----
+
+    ComplSlash vp np = insertObjPre (\\_ => vp.c2 ++ np.s ! Acc) vp ;
+
+    SlashVV vv vp = 
+      insertObj (\\a => infVP vv.isAux vp a) (predVV vv) **
+        {c2 = vp.c2} ;
+    SlashV2VNP vv np vp = 
+      insertObjPre (\\_ => vv.c2 ++ np.s ! Acc)
+        (insertObjc (\\a => infVP vv.isAux vp a) (predVc vv)) **
+          {c2 = vp.c2} ;
+
+    UseComp comp = insertObj comp.s (predAux auxBe) ;
+
+    AdvVP vp adv = insertObj (\\_ => adv.s) vp ;
+
+    AdVVP adv vp = insertAdV adv.s vp ;
+
+    ReflVP v = insertObjPre (\\a => v.c2 ++ reflPron ! a) v ;
+
+    PassV2 v = insertObj (\\_ => v.s ! VPPart) (predAux auxBe) ;
+
+---b    UseVS, UseVQ = \vv -> {s = vv.s ; c2 = [] ; isRefl = vv.isRefl} ; -- no "to"
+
+    CompAP ap = ap ;
+    CompNP np = {s = \\_ => np.s ! Acc} ;
+    CompAdv a = {s = \\_ => a.s} ;
+
+}