1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
|
resource ResEng = open Prelude in {
-- parameters
param
Number = Sg | Pl ;
Case = Nom | Acc ;
Agr = Ag Number Person ;
TTense = TPres | TPerf | TPast | TFut ;
Person = Per1 | Per2 | Per3 ;
VForm = VInf | VPres | VPast | VPart ;
ClForm = ClDir | ClInv ;
QForm = QDir | QIndir ;
-- parts of speech
oper
VP = {
verb : AgrVerb ;
compl : Str
} ;
NP = {
s : Case => Str ;
a : Agr
} ;
-- verb as in VP, including copula
AgrVerb : Type = {
s : ClForm => TTense => Bool => Agr => {fin,inf : Str} ;
inf : Str
} ;
copula : AgrVerb = {
s = \\d,t,p,a => case <t,a> of {
<TPres,Ag Sg Per1> => {fin = "am" ; inf = neg p} ;
<TPres,Ag Sg Per3> => {fin = "is" ; inf = neg p} ;
<TPres,_ > => {fin = "are" ; inf = neg p} ;
<TPerf,Ag Sg Per3> => {fin = "has" ; inf = neg p ++ "been"} ;
<TPerf,_ > => {fin = "have" ; inf = neg p ++ "been"} ;
<TPast,Ag Sg (Per1 | Per3)> => {fin = "was" ; inf = neg p} ;
<TPast,_ > => {fin = "were" ; inf = neg p} ;
<TFut, _ > => {fin = "will" ; inf = neg p ++ "be"}
} ;
inf = "be"
} ;
agrV : Verb -> AgrVerb = \v ->
let
vinf = v.s ! VInf ;
vpart = v.s ! VPart
in {
s = \\d,t,p,a => case <d,t,p,a> of {
<ClDir,TPres,True, Ag Sg Per3> => {fin = v.s ! VPres ; inf = []} ;
<_, TPres,_, Ag Sg Per3> => {fin = "does" ; inf = neg p ++ vinf} ;
<ClDir,TPres,True, _ > => {fin = vinf ; inf = []} ;
<_, TPres,_, _ > => {fin = "do" ; inf = neg p ++ vinf} ;
<_, TPerf,_, Ag Sg Per3> => {fin = "has" ; inf = neg p ++ vpart} ;
<_, TPerf,_, _ > => {fin = "have" ; inf = neg p ++ vpart} ;
<ClDir,TPast,True, _ > => {fin = v.s ! VPast ; inf = []} ;
<_, TPast,_, _ > => {fin = "did" ; inf = neg p ++ vinf} ;
<_, TFut, _, _ > => {fin = "will" ; inf = neg p ++ vinf}
} ;
inf = vinf
} ;
agrAux : (_,_,_,_ : Str) -> AgrVerb = \can,could,beenableto, beableto -> {
s = \\d,t,p,a => case <t,a> of {
<TPres,_ > => {fin = can ; inf = neg p} ;
<TPerf,Ag Sg Per3> => {fin = "has" ; inf = neg p ++ beenableto} ;
<TPerf,_ > => {fin = "have" ; inf = neg p ++ beenableto} ;
<TPast,_ > => {fin = could ; inf = neg p} ;
<TFut, _ > => {fin = "will" ; inf = neg p ++ beableto}
} ;
inf = beableto
} ;
infVP : VP -> Str = \vp ->
vp.verb.inf ++ vp.compl ;
neg : Bool -> Str = \b -> case b of {True => [] ; False => "not"} ;
-- for coordination
conjAgr : Number -> Agr -> Agr -> Agr = \n,xa,ya ->
case <xa,ya> of {
<Ag xn xp, Ag yn yp> =>
Ag (conjNumber (conjNumber xn yn) n) (conjPerson xp yp)
} ;
conjNumber : Number -> Number -> Number = \m,n ->
case m of {Pl => Pl ; _ => n} ;
conjPerson : Person -> Person -> Person = \p,q ->
case <p,q> of {
<Per1,_> | <_,Per1> => Per1 ;
<Per2,_> | <_,Per2> => Per2 ;
_ => Per3
} ;
-- for morphology
Noun : Type = {s : Number => Str} ;
Adj : Type = {s : Str} ;
Verb : Type = {s : VForm => Str} ;
mkNoun : Str -> Str -> Noun = \man,men -> {
s = table {Sg => man ; Pl => men}
} ;
regNoun : Str -> Noun = \s ->
mkNoun s (s + "s") ; ----
mkAdj : Str -> Adj = \s -> ss s ;
mkVerb : (_,_,_,_ : Str) -> Verb =
\go,goes,went,gone -> {
s = table {
VInf => go ;
VPres => goes ;
VPast => went ;
VPart => gone
}
} ;
regVerb : Str -> Verb = \v -> case v of {
_ + "e" => mkVerb v (v + "s") (v + "d") (v + "d") ;
_ => mkVerb v (v + "s") (v + "ed") (v + "ed")
} ;
-- for structural words
mkDet : Str -> Number -> {s : Str ; n : Number} = \s,n -> {
s = s ;
n = n
} ;
pronNP : (s,a : Str) -> Number -> Person -> NP =
\s,a,n,p -> {
s = table {
Nom => s ;
Acc => a
} ;
a = Ag n p
} ;
-- phonological auxiliaries
vowel : pattern Str = #("a" | "e" | "i" | "o") ;
}
|
