1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
|
resource ResIta = open Prelude in {
-- parameters
param
Number = Sg | Pl ;
Gender = Masc | Fem ;
Case = Nom | Acc | Dat | Gen | C_in | C_con | C_da ;
Agr = Ag Gender Number Person ;
Aux = Avere | Essere ;
Tense = Pres | Past | Perf | Fut ;
Mood = Ind | Con ;
Person = Per1 | Per2 | Per3 ;
VForm =
VInf
| VInfContr -- contracted infinitive, "amar"
| VPres Mood Number Person
| VPast Mood Number Person
| VFut Number Person
| VPart Gender Number ;
QForm = QDir | QIndir ;
ClitAgr = CAgrNo | CAgr Agr ;
-- parts of speech
oper
VP = {
v : Verb ;
clit : Str ;
clitAgr : ClitAgr ;
obj : Agr => Str
} ;
NP = {
s : Case => {clit,obj : Str ; isClit : Bool} ;
a : Agr
} ;
-- the preposition word of an abstract case
prepCase : Case -> Str = \c -> case c of {
Dat => "a" ;
Gen => "di" ;
C_con => "con" ;
C_in => "in" ;
C_da => "da" ;
_ => []
} ;
-- for predication
-- this is used for PredVP, QuestVP, SlashV2
predVP : Str -> Agr -> VP -> {s : Mood => Tense => Bool => Str} = \subj,agr,vp ->
let
obj = vp.obj ! agr ;
clit = vp.clit ;
verb : Mood -> Tense => Str = \m -> table {
Perf => agrV (auxVerb vp.v.aux) m Pres agr ++ agrPart vp.v agr vp.clitAgr ;
t => agrV vp.v m t agr
}
in {
s = \\m,t,b => subj ++ neg b ++ clit ++ verb m ! t ++ obj
} ;
useV : Verb -> (Agr => Str) -> VP = \v,o -> {
v = v ;
clit = [] ;
clitAgr = CAgrNo ;
obj = o
} ;
agrV : Verb -> Mood -> Tense -> Agr -> Str = \v,m,t,a -> case a of {
Ag _ n p => case t of {
Past => v.s ! VPast m n p ;
Fut => v.s ! VFut n p ;
_ => v.s ! VPres m n p
}
} ;
auxVerb : Aux -> Verb = \a -> case a of {
Avere =>
mkVerb "avere" "ho" "hai" "ha" "abbiamo" "avete" "hanno"
"avevo" "avrò" "abbia" "avessi" "avuto" Avere ;
Essere =>
mkVerb "essere" "sono" "sei" "è" "siamo" "siete" "sono"
"ero" "sarò" "sia" "fossi" "stato" Essere ---- eravamo
} ;
agrPart : Verb -> Agr -> ClitAgr -> Str = \v,a,c -> case v.aux of {
Avere => case c of {
CAgr (Ag g n _) => v.s ! VPart g n ;
_ => v.s ! VPart Masc Sg
} ;
Essere => case a of {
Ag g n _ => v.s ! VPart g n
}
} ;
neg : Bool -> Str = \b -> case b of {True => [] ; False => "non"} ;
essere_V = auxVerb Essere ;
-- for coordination
conjAgr : Number -> Agr -> Agr -> Agr = \n,xa,ya ->
let
x = agrFeatures xa ; y = agrFeatures ya
in Ag
(conjGender x.g y.g)
(conjNumber (conjNumber x.n y.n) n)
(conjPerson x.p y.p) ;
agrFeatures : Agr -> {g : Gender ; n : Number ; p : Person} = \a ->
case a of {Ag g n p => {g = g ; n = n ; p = p}} ;
conjGender : Gender -> Gender -> Gender = \g,h ->
case g of {Masc => Masc ; _ => h} ;
conjNumber : Number -> Number -> Number = \m,n ->
case m of {Pl => Pl ; _ => n} ;
conjPerson : Person -> Person -> Person = \p,q ->
case <p,q> of {
<Per1,_> | <_,Per1> => Per1 ;
<Per2,_> | <_,Per2> => Per2 ;
_ => Per3
} ;
-- for morphology
Noun : Type = {s : Number => Str ; g : Gender} ;
Adj : Type = {s : Gender => Number => Str ; isPre : Bool} ;
Verb : Type = {s : VForm => Str ; aux : Aux} ;
mkNoun : Str -> Str -> Gender -> Noun = \vino,vini,g -> {
s = table {Sg => vino ; Pl => vini} ;
g = g
} ;
regNoun : Str -> Noun = \vino -> case vino of {
fuo + c@("c"|"g") + "o" => mkNoun vino (fuo + c + "hi") Masc ;
ol + "io" => mkNoun vino (ol + "i") Masc ;
vin + "o" => mkNoun vino (vin + "i") Masc ;
cas + "a" => mkNoun vino (cas + "e") Fem ;
pan + "e" => mkNoun vino (pan + "i") Masc ;
_ => mkNoun vino vino Masc
} ;
mkAdj : (_,_,_,_ : Str) -> Bool -> Adj = \buono,buona,buoni,buone,p -> {
s = table {
Masc => table {Sg => buono ; Pl => buoni} ;
Fem => table {Sg => buona ; Pl => buone}
} ;
isPre = p
} ;
regAdj : Str -> Adj = \nero -> case nero of {
ner + "o" => mkAdj nero (ner + "a") (ner + "i") (ner + "e") False ;
verd + "e" => mkAdj nero nero (verd + "i") (verd + "i") False ;
_ => mkAdj nero nero nero nero False
} ;
mkVerb : (x1,_,_,_,_,_,_,_,_,_,_,x12 : Str) -> Aux -> Verb =
\amare,amo,ami,ama,amiamo,amate,amano,amavo,amero,amic,amassi,amato,aux ->
let
amav = init amavo ;
amas = Predef.tk 2 amassi ;
amer = init amero ;
in {
s = table {
VInf => amare ;
VInfContr => init amare ;
VPres Ind Sg Per1 => amo ;
VPres Ind Sg Per2 => ami ;
VPres Ind Sg Per3 => ama ;
VPres Ind Pl Per1 => amiamo ;
VPres Ind Pl Per2 => amate ;
VPres Ind Pl Per3 => amano ;
VPres Con Sg _ => amic ;
VPres Con Pl Per1 => amiamo ;
VPres Con Pl Per2 => Predef.tk 2 amiamo + "te" ;
VPres Con Pl Per3 => amic + "no" ;
VPast Ind Sg Per1 => amavo ;
VPast Ind Sg Per2 => amav + "i" ;
VPast Ind Sg Per3 => amav + "a" ;
VPast Ind Pl Per1 => amav + "amo" ;
VPast Ind Pl Per2 => amav + "ate" ;
VPast Ind Pl Per3 => amav + "ano" ;
VPast Con Sg Per1 => amassi ;
VPast Con Sg Per2 => amassi ;
VPast Con Sg Per3 => amas + "se" ;
VPast Con Pl Per1 => amas + "simo" ;
VPast Con Pl Per2 => amas + "te" ;
VPast Con Pl Per3 => amas + "sero" ;
VFut Sg Per1 => amero ;
VFut Sg Per2 => amer + "ai" ;
VFut Sg Per3 => amer + "à" ;
VFut Pl Per1 => amer + "emo" ;
VFut Pl Per2 => amer + "ete" ;
VFut Pl Per3 => amer + "ono" ;
VPart g n => (regAdj amato).s ! g ! n
} ;
aux = aux
} ;
regVerb : Str -> Verb = \amare -> case amare of {
am + "are" => mkVerb amare (am+"o") (am+"i") (am+"a")
(am+"iamo") (am+"ate") (am+"ano")
(am +"avo") (am+"erò") (am+"i") (am+"assi")
(am+"ato") Avere ;
tem + "ere" => mkVerb amare (tem+"o") (tem+"i") (tem+"e")
(tem+"iamo") (tem+"ete") (tem+"ono")
(tem +"evo") (tem+"erò") (tem+"a") (tem+"essi")
(tem+"uto") Avere ;
fin + "ire" => mkVerb amare (fin+"isco") (fin+"isci") (fin+"isce")
(fin+"iamo") (fin+"ite") (fin+"iscono")
(fin +"ivo") (fin+"irò") (fin+"isca") (fin+"issi")
(fin+"ito") Avere
} ;
-- for structural words
adjDet : Adj -> Number -> {s : Gender => Case => Str ; n : Number} =
\adj,n -> {
s = \\g,c => prepCase c ++ adj.s ! g ! n ;
n = n
} ;
pronNP : (s,a,d,i : Str) -> Gender -> Number -> Person -> NP =
\s,a,d,i,g,n,p -> {
s = table {
Nom => {clit = [] ; obj = s ; isClit = False} ;
Acc => {clit = a ; obj = [] ; isClit = True} ;
Dat => {clit = d ; obj = [] ; isClit = True} ;
c => {clit = [] ; obj = prepCase c ++ i ; isClit = False}
} ;
a = Ag g n p
} ;
-- phonological auxiliaries
vowel : pattern Str = #("a" | "e" | "i" | "o" | "u" | "h") ;
s_impuro : pattern Str = #("z" | "s" + ("b"|"c"|"d"|"f"|"m"|"p"|"q"|"t")) ;
elisForms : (_,_,_ : Str) -> Str = \lo,l',il ->
pre {#s_impuro => lo ; #vowel => l' ; _ => il} ;
}
|
