blob: 4d0796befd610ab63b9a3d5a37db7309159424d3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
include numerals.Abs.gf ;
param DForm = ental | ton | tiotal ;
lincat Numeral = { s : Str } ;
lincat Digit = {s : DForm => Str} ;
lincat Sub10 = {s : DForm => Str} ;
lincat Sub100 = { s : Str } ;
lincat Sub1000 = { s : Str } ;
lincat Sub1000000 = { s : Str } ;
oper
mkTal : Str -> Str -> Str -> Lin Digit = \två, tolv, tjugo ->
{s = table {ental => två ; ton => tolv ; tiotal => tjugo}} ;
regTal : Str -> Lin Digit = \fem ->
mkTal fem (fem + "ton") (fem + "tio") ;
ss : Str -> {s : Str} = \s -> {s = s} ;
lin
num x = x ;
n2 = mkTal "två" "tolv" "tjugo" ;
n3 = mkTal "tre" "tretton" "trettio" ;
n4 = mkTal "fyra" "fjorton" "fyrtio" ;
n5 = regTal "fem" ;
n6 = regTal "sex" ;
n7 = mkTal "sju" "sjutton" "sjuttio" ;
n8 = mkTal "åtta" "arton" "åttio" ;
n9 = mkTal "nio" "nitton" "nittio" ;
pot01 = {s = table {f => "ett"}} ;
pot0 d = {s = table {f => d.s ! f}} ;
pot110 = ss "tio" ;
pot111 = ss "elva" ;
pot1to19 d = ss (d.s ! ton) ;
pot0as1 n = ss (n.s ! ental) ;
pot1 d = ss (d.s ! tiotal) ;
pot1plus d e = ss (d.s ! tiotal ++ e.s ! ental) ;
pot1as2 n = n ;
pot2 d = ss (d.s ! ental ++ "hundra") ;
pot2plus d e = ss (d.s ! ental ++ "hundra" ++ e.s) ;
pot2as3 n = n ;
pot3 n = ss (n.s ++ "tusen") ;
pot3plus n m = ss (n.s ++ "tusen" ++ m.s) ;
|
