1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
|
-- (c) 2009 Ramona Enache and Aarne Ranta under LGPL
--# -coding=latin1
concrete WordsFre of Words = SentencesFre ** open
SyntaxFre,
IrregFre,
(E = ExtraFre),
(L = LexiconFre),
ParadigmsFre,
(M = MorphoFre),
(P = ParadigmsFre),
Prelude in {
lin
-- kinds
Apple = mkCN L.apple_N ;
Beer = mkCN L.beer_N ;
Bread = mkCN L.bread_N ;
Cheese = mkCN (mkN "fromage" masculine) ;
Chicken = mkCN (mkN "poulet") ;
Coffee = mkCN (mkN "café") ;
Fish = mkCN L.fish_N ;
Meat = mkCN (mkN "viande") ;
Milk = mkCN L.milk_N ;
Pizza = mkCN (mkN "pizza" feminine) ;
Salt = mkCN L.salt_N ;
Tea = mkCN (mkN "thé") ;
Water = mkCN L.water_N ;
Wine = mkCN L.wine_N ;
-- properties
Bad = L.bad_A ;
Boring = mkA "ennuyeux" ;
Cheap = let bm = "bon marché" in mkA bm bm bm bm ;
Cold = L.cold_A ;
Delicious = mkA "délicieux" ;
Expensive = mkA "cher" ;
Fresh = mkA "frais" "fraîche" "frais" "fraîchement" ;
Good = L.good_A ;
Suspect = mkA "suspect" ;
Warm = L.warm_A ;
-- places
Airport = mkPlace (mkN "aéroport") dative ;
AmusementPark = mkPlace (compN (mkN "parc") ["d'attractions"]) dative ;
Bank = mkPlace (mkN "banque") dative ;
Bar = mkPlace (mkN "bar") dative ;
Cafeteria = mkPlace (mkN "cafétéria") dative ;
Center = mkPlace (mkN "centre" "centres" ParadigmsFre.masculine) dative ;
Church = mkPlace (mkN "église") dative ;
Cinema = mkPlace (mkN "cinéma" masculine) dative ;
Disco = mkPlace (mkN "discothèque" feminine) dative ;
Hospital = mkPlace (mkN "hôpital") dative ;
Hotel = mkPlace (mkN "hôtel") dative ;
Museum = mkPlace (mkN "musée" masculine) dative ;
Park = mkPlace (mkN "parc") dative ;
Parking = mkPlace (mkN "parking" masculine) dative ;
Pharmacy = mkPlace (mkN "pharmacie" feminine) dative ;
PostOffice = mkPlace (mkN "poste" feminine) dative ;
Pub = mkPlace (mkN "pub" masculine) dative ;
Restaurant = mkPlace (mkN "restaurant") dative ;
School = mkPlace (mkN "école") dative ;
Shop = mkPlace (mkN "magasin") dative ;
Station = mkPlace (mkN "gare") dative ;
Supermarket = mkPlace (mkN "supermarché" masculine) dative ;
Theatre = mkPlace (mkN "théâtre" masculine) dative ;
Toilet = mkCNPlacePl (mkCN (mkN "toilette")) dative dative;
University = mkPlace (mkN "université" feminine) dative ;
Zoo = mkPlace (mkN "zoo" masculine) dative ;
CitRestaurant cit = mkCNPlace (mkCN cit (mkN "restaurant")) dative to_Prep ;
-- currencies
DanishCrown = mkCN (mkA "danois") (mkN "couronne") | mkCN (mkN "couronne") ;
Dollar = mkCN (mkN "dollar") ;
Euro = mkCN (mkN "euro") ;
Lei = mkCN (mkN "leu" "lei" masculine) ;
Leva = mkCN (mkN "lev" "leva" masculine);
NorwegianCrown = mkCN (mkA "norvégien") (mkN "couronne") | mkCN (mkN "couronne") ;
Pound = mkCN (compN (mkN "livre") ["sterling"]);
Rouble = mkCN (mkN "rouble" "rouble" masculine) ;
SwedishCrown = mkCN (mkA "suédois") (mkN "couronne") | mkCN (mkN "couronne") ;
Zloty = mkCN (mkN "zloty" "zlotych" masculine) ;
-- nationalities
Belgian = mkA "belge" ;
Belgium = mkNP (mkPN "Belgique") ;
Bulgarian = mkNat "bulgare" "Bulgarie" ;
Catalan = mkNat "catalan" "Catalogne" ;
Danish = mkNat "danois" "Danemark" ;
Dutch = mkNat "hollandais" "Holland" ;
English = mkNat "anglais" "Angleterre" ;
Finnish = mkNat "finlandais" "Finlande" ;
Flemish = mkNP (mkPN "flamand") ;
French = mkNat "français" "France" ;
German = mkNat "allemand" "Allemagne" ;
Italian = mkNat "italien" "Italie" ;
Norwegian = mkNat "norvégien" "Norvège" ;
Polish = mkNat "polonais" "Pologne" ;
Romanian = mkNat "roumain" "Roumanie" ;
Russian = mkNat "russe" "Russie" ;
Spanish = mkNat "espagnol" "Espagne" ;
Swedish = mkNat "suédois" "Suède" ;
-- means of transportation
Bike = mkTransport en_Prep L.bike_N ;
Bus = mkTransport par_Prep (mkN "bus") ;
Car = mkTransport en_Prep L.car_N ;
Ferry = mkTransport en_Prep (mkN "ferry") ;
Plane = mkTransport par_Prep L.airplane_N ;
Subway = mkTransport par_Prep (mkN "métro") ;
Taxi = mkTransport en_Prep (mkN "taxi") ;
Train = mkTransport par_Prep (mkN "train") ;
Tram = mkTransport par_Prep (mkN "tram") ;
ByFoot = P.mkAdv "à pied" ;
-- actions
AHasAge p num = mkCl p.name have_V2 (mkNP num L.year_N) ;
AHasChildren p num = mkCl p.name have_V2 (mkNP num L.child_N) ;
AHasRoom p num = mkCl p.name have_V2
(mkNP (mkNP a_Det (mkN "chambre"))
(SyntaxFre.mkAdv for_Prep (mkNP num (mkN "personne")))) ;
AHasTable p num = mkCl p.name have_V2
(mkNP (mkNP a_Det (mkN "table"))
(SyntaxFre.mkAdv for_Prep (mkNP num (mkN "personne")))) ;
AMarried p = mkCl p.name (mkA "marié") ;
AWant p obj = mkCl p.name vouloir_V2 obj ;
ALike p item = mkCl item plaire_V2 p.name ;
ASpeak p lang = mkCl p.name (mkV2 (mkV "parler")) lang ;
ALove p q = mkCl p.name (mkV2 (mkV "aimer")) q.name ;
AHungry p = mkCl p.name (E.ComplCN have_V2 (mkCN (mkN "faim" feminine))) ;
AReady p = mkCl p.name (mkA "prêt") ;
AThirsty p = mkCl p.name (E.ComplCN have_V2 (mkCN (mkN "soif" feminine))) ;
ATired p = mkCl p.name (mkA "fatigué") ;
AScared p = mkCl p.name (E.ComplCN have_V2 (mkCN (mkN "peur" feminine))) ;
AIll p = mkCl p.name (mkA "malade") ;
AUnderstand p = mkCl p.name (mkV IrregFre.comprendre_V2) ;
AKnow p = mkCl p.name (mkV IrregFre.savoir_V2) ;
AWantGo p place = mkCl p.name want_VV (mkVP (mkVP L.go_V) place.to) ;
AHasName p name = mkCl p.name (mkV2 (reflV (mkV "appeler"))) name ;
ALive p co = mkCl p.name (mkVP (mkVP (mkV "habiter")) (SyntaxFre.mkAdv (mkPrep "en") co)) ;
-- miscellaneous
QWhatName p = mkQS (mkQCl how_IAdv (mkCl p.name (reflV (mkV "appeler")))) ;
QWhatAge p = mkQS (mkQCl (mkIP whichSg_IDet (mkN "âge" masculine)) p.name have_V2) ;
PropOpen p = mkCl p.name open_A ;
PropClosed p = mkCl p.name closed_A ;
PropOpenDate p d = mkCl p.name (mkVP (mkVP open_A) d) ;
PropClosedDate p d = mkCl p.name (mkVP (mkVP closed_A) d) ;
PropOpenDay p d = mkCl p.name (mkVP (mkVP open_A) d.habitual) ;
PropClosedDay p d = mkCl p.name (mkVP (mkVP closed_A) d.habitual) ;
HowMuchCost item = mkQS (mkQCl how8much_IAdv (mkCl item (mkV "coûter"))) ;
ItCost item price = mkCl item (mkV2 (mkV "coûter")) price ;
-- Building phrases from strings is complicated: the solution is to use
-- mkText : Text -> Text -> Text ;
PSeeYouPlace d = mkText (lin Text (ss ("on se voit"))) (mkPhrase (mkUtt d.at)) ;
PSeeYouDate d = mkText (lin Text (ss ("on se voit"))) (mkPhrase (mkUtt d)) ;
PSeeYouPlaceDate p d =
mkText (lin Text (ss ("on se voit")))
(mkText (mkPhrase (mkUtt p.at)) (mkPhrase (mkUtt d))) ;
-- Relations are expressed as "my wife" or "the wife of my son", as defined by $xOf$
-- below. Languages with productive genitives can use an equivalent of
-- "my son's wife" for non-pronouns, as e.g. in English.
Wife = xOf sing (mkN "femme") ;
Husband = xOf sing (mkN "mari") ;
Son = xOf sing (mkN "fils") ;
Daughter = xOf sing (mkN "fille") ;
Children = xOf plur L.child_N ;
-- week days
Monday = mkDay "lundi" ;
Tuesday = mkDay "mardi" ;
Wednesday = mkDay "mercredi" ;
Thursday = mkDay "jeudi" ;
Friday = mkDay "vendredi" ;
Saturday = mkDay "samedi" ;
Sunday = mkDay "dimanche" ;
Tomorrow = ParadigmsFre.mkAdv "demain" ;
-- modifiers of places
TheBest = mkSuperl True L.good_A ;
TheClosest = mkSuperl True L.near_A ;
TheCheapest = mkSuperl False
(compADeg {s = \\_ => (M.mkAdj "bon marché" "bon marché" "bon marché" "bon marché").s ;
isPre = False ; lock_A = <>}) ;
TheMostExpensive = mkSuperl True (mkA "cher") ;
TheMostPopular = mkSuperl True (mkA "populaire") ;
TheWorst = mkSuperl True L.bad_A ;
SuperlPlace sup kind =
let
det : Det = mkDet the_Art sup.s ;
name : NP = case sup.isPre of {
True => mkNP det kind.name ; -- le meilleur bar
False => mkNP the_Art (mkCN kind.name (mkNP det)) -- le bar le plus cher
}
in {
name = name ;
at = SyntaxFre.mkAdv kind.at name ;
to = SyntaxFre.mkAdv kind.to name
} ;
-- transports
HowFar place = mkQS (mkQCl what_distance_IAdv place.name) ;
HowFarFrom x y =
mkQS (mkQCl (E.CompIQuant which_IQuant)
(mkNP (mkNP distance_NP (SyntaxFre.mkAdv from_Prep x.name)) y.to)) ;
HowFarFromBy x y t =
mkQS (mkQCl (E.CompIQuant which_IQuant)
(mkNP (mkNP (mkNP distance_NP (SyntaxFre.mkAdv from_Prep x.name)) y.to) t)) ;
HowFarBy place t =
mkQS (mkQCl what_distance_IAdv (mkNP place.name t)) ;
WhichTranspPlace trans place =
mkQS (mkQCl (mkIP which_IDet trans.name) (mkVP (mkVP L.go_V) place.to)) ;
IsTranspPlace trans place =
lin QS {s = \\_ => (E.EstcequeS (mkS (mkCl (mkCN trans.name (SyntaxFre.mkAdv for_Prep place.name))))).s} ;
-- mkQS (mkQCl (mkCl (mkCN trans.name place.to))) ;
oper
mkNat : Str -> Str -> NPNationality = \nat,co ->
mkNPNationality (mkNP (mkPN nat)) (mkNP (mkPN co)) (mkA nat) ;
mkDay : Str -> {name : NP ; point : Adv ; habitual : Adv} = \d ->
let day = mkNP (mkPN d) in
mkNPDay day (P.mkAdv d) (P.mkAdv ("le" ++ d)) ;
mkPlace : N -> Prep -> {name : CN ; at : Prep ; to : Prep; isPl : Bool} = \p,i ->
mkCNPlace (mkCN p) i dative ;
open_A = P.mkA "ouvert" ;
closed_A = P.mkA "fermé" ;
xOf : GNumber -> N -> NPPerson -> NPPerson = \n,x,p -> mkRelative n (mkCN x) p ;
mkTransport : Prep -> N -> {name : CN ; by : Adv} = \p,n -> {
name = mkCN n ;
by = E.PrepCN p n -- par train, en vélo
} ;
en_Prep = mkPrep "en" ;
par_Prep = mkPrep "par" ;
mkSuperl : Bool -> A -> {s : Ord ; isPre : Bool} = \b,a ->
{s = SyntaxFre.mkOrd a ; isPre = b} ;
what_distance_IAdv = ss "à quelle distance"**{lock_IAdv=<>};
distance_NP : NP = mkNP the_Det (mkN "distance" feminine) ;
}
|
