path: root/next-lib/src/german/LexiconGer.gf

--# -path=.:../common:../abstract:../../prelude

-- work by Aarne Ranta, Andreas Priesnitz, and Henning Thielemann.

concrete LexiconGer of Lexicon = CatGer ** 
  open Prelude, ParadigmsGer, (Mo = MorphoGer), IrregGer in {

flags 
  optimize=all_subs ;

lin
  add_V3 = dirV3 (prefixV "hinzu" (regV "fügen")) zu_Prep ;
  airplane_N = regN "Flugzeug"  ;
  already_Adv = mkAdv "schon" ;
  answer_V2S = mkV2S (regV "antworten") datPrep ;
  apartment_N = regN "Wohnung" ;
  apple_N = reg2N "Apfel" "Äpfel" masculine  ;
  art_N = reg2N "Kunst" "Künste" feminine ;
  ask_V2Q = mkV2Q (regV "fragen") accPrep ;
  baby_N = reg2N "Baby" "Babies" neuter ; ----
  bad_A = regA "schlecht" ;
  bank_N = reg2N "Bank" "Banken" feminine ;
  beautiful_A = regA "schön" ;
  become_VA = mkVA IrregGer.werden_V ;
  beer_N = reg2N "Bier" "Biere" neuter ;
  beg_V2V = mkV2V (mk6V "bitten" "bittet" "bitte" "bat" "bäte" "gebeten") accPrep ;
  big_A = mk3A "groß" "größer" "größte" ;
  bike_N = reg2N "Fahrrad" "Fahrräder" neuter ;
  bird_N = reg2N "Vogel" "Vögel" masculine ;
  black_A = regA "schwarz" ;
  blue_A = regA "blau";
  boat_N = reg2N "Boot" "Boote" neuter ;
  book_N = reg2N "Buch" "Bücher" neuter ;
  boot_N = reg2N "Stiefel" "Stiefel" masculine ;
  boss_N = reg2N "Chef" "Chefs" masculine ; ----
  boy_N = reg2N "Junge" "Jungen" masculine ;
  bread_N = reg2N "Brot" "Brote" neuter ;
  break_V2 = dirV2 
    (irregV "zerschlagen" "zerschlägt" "zerschlug" "zerschlüge" "zerschlagen") ;
  broad_A = regA "breit" ;
  brother_N2 = mkN2 (reg2N "Bruder" "Brüder" masculine)  von_Prep ;
  brown_A = regA "braun" ;
  butter_N = reg2N "Butter" "Butter" feminine ; ---- infl
  buy_V2 = dirV2 (regV "kaufen") ;
  camera_N = reg2N "Kamera" "Kameras" feminine ;
  cap_N = regN "Mütze" ;
  car_N = regN "Wagen" ;
  carpet_N = regN "Teppich" ;
  cat_N = regN "Katze" ;
  ceiling_N = reg2N "Dach" "Dächer" neuter ;
  chair_N = reg2N "Stuhl" "Stühle" masculine ;
  cheese_N = regN "Käse" ;
  child_N = reg2N "Kind" "Kinder" neuter ;
  church_N = regN "Kirche" ;
  city_N = reg2N "Stadt" "Städte" feminine ;
  clean_A = regA "rein" ;
  clever_A = mk3A "klug" "klüger" "klügste" ;
  close_V2 = dirV2 (irregV "schließen" "schließt" "schloß" "schlösse" "geschlossen") ;
  coat_N = regN "Jacke" ;
  cold_A = regA "kalt" ;
  come_V = seinV (mk6V "kommen" "kommt" "komm" "kam" "käme" "gekommen") ;
  computer_N = reg2N "Rechner" "Rechner" masculine ;
  country_N = reg2N "Land" "Länder" neuter ;
  cousin_N = reg2N "Vetter" "Vetter" masculine ; --- Kusine
  cow_N = reg2N "Kuh" "Kühe" feminine ;
  die_V = seinV (irregV "sterben" "stirbt" "starb" "stürbe" "gestorben") ;
  distance_N3 = mkN3 (regN "Entfernung") von_Prep zu_Prep ;
  dirty_A = regA "schmutzig" ;
  do_V2 = dirV2 (irregV "tun" "tut" "tat" "täte" "getan") ;
  doctor_N = reg2N "Arzt" "Ärzte" masculine ;
  dog_N = regN "Hund" ;
  door_N = reg2N "Tür" "Türen" feminine ;
  drink_V2 = dirV2 (irregV "trinken" "trinkt" "trank" "tränke" "getrunken") ;
  easy_A2V = mkA2V (regA "leicht") (mkPrep "für" accusative) ;
  eat_V2 = dirV2 (irregV "essen" "ißt" "aß" "äße" "gegessen") ;
  empty_A = regA "leer" ; ---- check infl
  enemy_N = regN "Feind" ; 
  factory_N = regN "Fabrik" ;
  father_N2 = mkN2 (reg2N "Vater" "Väter" masculine) von_Prep ;
  fear_VS = mkVS (regV "fürchten") ;
  find_V2 = dirV2 (irregV "finden" "findet" "fand" "fände" "gefunden") ;
  fish_N = regN "Fisch" ;
  floor_N = reg2N "Fußboden" "Fußböden" masculine ;
  forget_V2 = dirV2 (irregV "vergessen" "vergißt" "vergaß" "vergäße" "vergessen") ;
  fridge_N = reg2N "Kühlschrank" "Kühlschränke" masculine ;
  friend_N = regN "Freund" ;
  fruit_N = reg2N "Frucht" "Früchte" feminine ;
  fun_AV = mkAV (regA "toll") ;
  garden_N = reg2N "Garten" "Gärten" masculine ;
  girl_N = reg2N "Mädchen" "Mädchen" neuter ;
  glove_N = regN "Handschuh" ;
  gold_N = reg2N "Gold" "Golde" neuter ; ---- infl
  good_A = mk3A "gut" "besser" "beste" ;
  go_V = seinV (irregV "gehen" "geht" "ging" "ginge" "gegangen") ;
  green_A = regA "grün" ;
  harbour_N = reg2N "Hafen" "Häfen" masculine ;
  hate_V2 = dirV2 (regV "hassen") ;
  hat_N = reg2N "Hut" "Hüte" masculine ;
  have_V2 = dirV2 IrregGer.haben_V ;
  hear_V2 = dirV2 (regV "hören") ;
  hill_N = regN "Hügel" ;
  hope_VS = mkVS (regV "hoffen") ;
  horse_N = reg2N "Pferd" "Pferde" neuter ;
  hot_A = regA "heiß" ;
  house_N = reg2N "Haus" "Häuser" neuter ;
  important_A = regA "wichtig" ;
  industry_N = regN "Industrie" ;
  iron_N = reg2N "Eisen" "Eisen" neuter ;
  jump_V = seinV (irregV "springen" "springt" "sprang" "spränge" "gesprungen") ;
  king_N = regN "König" ;
  know_V2 = dirV2 (irregV "wissen" "weiß" "wußte" "wüßte" "gewußt") ; ---- infl
  lake_N = reg2N "See" "Seen" masculine ; --- infl
  lamp_N = regN "Lampe";
  learn_V2 = dirV2 (regV "lernen") ;
  leather_N = reg2N "Leder" "Leder" neuter ;
  leave_V2 = dirV2 (irregV "verlassen" "verläßt" "verließ" "verließe" "verlassen") ;
  like_V2 = dirV2 (irregV "mögen" "mag" "mochte" "möchte" "gemocht") ;
  listen_V2 = prepV2 (prefixV "zu" (regV "hören")) datPrep ; ---- dat
  live_V = regV "leben" ;
  long_A = mk3A "lang" "länger" "längste" ;
  lose_V2 = dirV2 (irregV "verlieren" "verliert" "verlor" "verlöre" "verloren") ;
  love_N = regN "Liebe" ;
  love_V2 = dirV2 (regV "lieben") ;
  man_N = reg2N "Mann" "Männer" masculine ;
  married_A2 = mkA2 (regA "verheiratet") (mkPrep "mit" dative) ;
  meat_N = reg2N "Fleisch" "Fleische" neuter ; ---- infl
  milk_N = reg2N "Milch" "Milche" feminine ; ---- infl
  moon_N = regN "Mond" ;
  mother_N2 = mkN2 (reg2N "Mutter" "Mütter" feminine) von_Prep ;
  mountain_N = regN "Berg" ;
  music_N = reg2N "Musik" "Musiken" feminine ;
  narrow_A = regA "schmal" ;
  new_A = regA "neu" ;
  newspaper_N = regN "Zeitung" ;
  now_Adv = mkAdv "jetzt" ;
  number_N = reg2N "Zahl" "Zahlen" feminine ;
  oil_N = reg2N "Öl" "Öle" neuter ;
  old_A = mk3A "alt" "älter" "älteste" ;
  open_V2 = dirV2 (regV "öffnen") ;
  paint_V2A = mkV2A (regV "malen") accPrep ;
  paper_N = reg2N "Papier" "Papiere" neuter ;
  paris_PN = mkPN "Paris" "Paris" ;
  peace_N = mk6N "Friede" "Frieden" "Frieden" "Friedens" "Frieden" "Frieden" masculine ;
  pen_N = regN "Bleistift" ; ----
  planet_N = reg2N "Planet" "Planeten" masculine ;
  plastic_N = reg2N "Plastik" "Plastiken" feminine ; ----
  play_V2 = dirV2 (regV "spielen") ;
  policeman_N = reg2N "Polizist" "Polizisten" masculine ;
  priest_N = regN "Priester" ;
  probable_AS = mkAS (regA "wahrscheinlich") ;
  put_V2 = dirV2 (regV "setzen") ;
  queen_N = reg2N "Königin" "Königinnen" feminine ;
  radio_N = reg2N "Radio" "Radios" neuter ; ----
  rain_V0 = mkV0 (regV "regnen") ;
  read_V2 = dirV2 (irregV "lesen" "liest" "las" "läse" "gelesen") ;
  red_A = regA "rot" ;
  religion_N = regN "Religion" ;
  restaurant_N = reg2N "Restaurant" "Restaurants" neuter ;
  river_N = reg2N "Fluß" "Flüsse" masculine ;
  rock_N = regN "Stein" ;
  roof_N = reg2N "Dach" "Dächer" neuter ;
  rubber_N = reg2N "Gummi" "Gummis" neuter ;
  run_V = seinV (irregV "laufen" "läuft" "lief" "liefe" "gelaufen") ;
  say_VS = mkVS (regV "sagen") ;
  school_N = regN "Schule";
  science_N = reg2N "Wissenschaft" "Wissenschaften" feminine ;
  sea_N = reg2N "Meer" "Meere" neuter ;
  seek_V2 = dirV2 (regV "suchen") ;
  see_V2 = dirV2 (irregV "sehen" "sieht" "sah" "sähe" "gesehen") ;
  sell_V3 = accdatV3 (no_geV (regV "verkaufen")) ;
  send_V3 = accdatV3 (regV "schicken") ;
  sheep_N = reg2N "Schaf" "Schafe" neuter ;
  ship_N = reg2N "Schiff" "Schiffe" neuter ;
  shirt_N = reg2N "Hemd" "Hemden" neuter ; ---- infl
  shoe_N = regN "Schuh" ;
  shop_N = reg2N "Laden" "Läden" masculine ;
  short_A =  mk3A "kurz" "kürzer" "kürzeste" ;
  silver_N = reg2N "Silber" "Silber" neuter ; ---- infl
  sister_N = reg2N "Schwester" "Schwestern" feminine ;
  sleep_V = irregV "schlafen" "schläft" "schlief" "schliefe" "geschlafen" ;
  small_A = regA "klein" ;
  snake_N = regN "Schlange" ;
  sock_N = reg2N "Strumpf" "Strümpfe" masculine ;
  song_N = reg2N "Lied" "Lieder" neuter ;
  speak_V2 = dirV2 (irregV "sprechen" "spricht" "sprach" "spräche" "gesprochen") ;
  star_N = regN "Sterne" ;
  steel_N = regN "Stahl" ;
  stone_N = regN "Stein" ;
  stop_V = seinV (irregV "halten" "hält" "hielt" "hielte" "gehalten") ;
  stove_N = regN "Herd" ;
  student_N = reg2N "Student" "Studenten" masculine ;
  stupid_A = mk3A "dumm" "dümmer" "dümmste" ; ----
  sun_N = regN "Sonne" ;
  switch8off_V2 = dirV2 (prefixV "aus" (regV "schalten")) ;
  switch8on_V2 = dirV2 (prefixV "ein" (regV "schalten")) ;
  table_N = regN "Tisch"  ;
  talk_V3 = mkV3 (regV "reden") datPrep von_Prep ;
  teacher_N = reg2N "Lehrer" "Lehrer" masculine ;
  teach_V2 = dirV2 (no_geV (regV "unterrichten")) ;
  television_N = reg2N "Fernsehen" "Fernsehen" neuter;
  thick_A = regA "dick" ;
  thin_A = regA "dünn" ;
  train_N = reg2N "Zug" "Züge" masculine  ;
  travel_V = regV "reisen" ;
  tree_N = reg2N "Baum" "Bäume" masculine ;
  ----  trousers_N = regN "trousers" ; ---- pl t !
  ugly_A = regA "häßlich" ;
  understand_V2 = 
    dirV2 (irregV "verstehen" "versteht" "verstand" "verstände" "verstanden") ;
  university_N = reg2N "Universität" "Universitäten" feminine  ;
  village_N = reg2N "Dorf" "Dörfer" neuter ;
  wait_V2 = prepV2 (regV "warten") (mkPrep "auf" accusative) ;
  walk_V = seinV (irregV "gehen" "geht" "ging" "ginge" "gegangen") ;
  warm_A = mk3A "warm" "wärmer" "wärmste" ;
  war_N = regN "Krieg" ;
  watch_V2 = prepV2 (regV "schauen") (mkPrep "an" accusative) ;
  water_N = reg2N "Wasser" "Wasser" neuter ;
  white_A = regA "weiß" ;
  window_N = reg2N "Fenster" "Fenster" neuter ;
  wine_N = regN "Wein" ;
  win_V2 = dirV2 (irregV "gewinnen" "gewinnt" "gewann" "gewänne" "gewonnen") ;
  woman_N = reg2N "Frau" "Frauen" feminine ;
  wonder_VQ = mkVQ (reflV (regV "wundern") accusative) ;
  wood_N = reg2N "Holz" "Hölzer" neuter ;
  write_V2 = dirV2 (irregV "schreiben" "schreibt" "schrieb" "schriebe" "geschrieben") ;
  yellow_A = regA "gelb" ;
  young_A = mk3A "jung" "jünger" "jüngste" ;
  left_Ord = Mo.mkOrd (regA "link") ;
  right_Ord = Mo.mkOrd (regA "recht") ;
  far_Adv = mkAdv "weit" ;
  correct_A = regA "richtig" ;
  dry_A = regA "trocken" ;
  dull_A = regA "stumpf" ;
  full_A = regA "voll" ;
  heavy_A = regA "schwer" ;
  near_A = mk3A "nahe" "näher" "nächste" ;
  rotten_A = regA "verdorben" ;
  round_A = regA "rund" ;
  sharp_A = mk3A "scharf" "schärfer" "schärfste" ;
  smooth_A = regA "glatt" ;
  straight_A = regA "gerade" ;
  wet_A = regA "naß" ;
  wide_A = regA "breit" ;
  animal_N = reg2N "Tier" "Tiere" neuter ;
  ashes_N = regN "Asche" ;
  back_N = reg2N "Rücken" "Rücken" masculine ;
  bark_N = regN "Rinde" ;
  belly_N = reg2N "Bauch" "Bäuche" masculine ;
  blood_N = regN "Blut" ;
  bone_N = reg2N "Knochen" "Knochen" masculine ;
  breast_N = reg2N "Brust" "Brüste" feminine ;
  cloud_N = regN "Wolke" ;
  day_N = regN "Tag" ;
  dust_N = reg2N "Staub" "Stäube" masculine ;
  ear_N = regN "Ohr" ;
  earth_N = regN "Erde" ;
  egg_N = regN "Ei" ;
  eye_N = regN "Auge" ;
  fat_N = regN "Fett" ;
  feather_N = regN "feather" ;
  fingernail_N = reg2N "Fingernagel" "Fingernägel" masculine ;
  fire_N = regN "Feuer" ;
  flower_N = regN "Blume" ;
  fog_N = regN "Nebel" ;
  foot_N = reg2N "Fuß" "Füße" masculine ;
  forest_N = reg2N "Wald" "Wälder" masculine ;
  grass_N = regN "Gras" ;
  guts_N = regN "Eingeweide" ;
  hair_N = regN "Haar" ;
  hand_N = regN "Hand" ;
  head_N = regN "Kopf" ;
  heart_N = regN "Herz" ;
  horn_N = regN "Horn" ;
  husband_N = regN "Ehemann" ;
  ice_N = regN "Eis" ;
  knee_N = regN "Knie" ;
  leaf_N = reg2N "Blatt" "Blätter" neuter ;
  leg_N = regN "Bein" ;
  liver_N = regN "Leber" ;
  louse_N = reg2N "Laus" "Läuse" feminine ;
  mouth_N = regN "Mund" ;
  name_N = regN "Name" ;
  neck_N = regN "Nacken" ;
  night_N = reg2N "Nacht" "Nächte" feminine ;
  nose_N = regN "Nase" ;
  person_N = regN "Person" ;
  rain_N = regN "Regen" ;
  road_N = regN "Straße" ;
  root_N = regN "Wurzel" ;
  rope_N = regN "Seil" ;
  salt_N = regN "Salz" ;
  sand_N = regN "Sand" ;
  seed_N = regN "Same" ;
  skin_N = regN "Haut" ;
  sky_N = regN "Himmel" ;
  smoke_N = regN "Rauch" ;
  snow_N = regN "Schnee" ;
  stick_N = regN "Stock" ;
  tail_N = regN "Schwanz" ;
  tongue_N = regN "Zunge" ;
  tooth_N = regN "Zahn" ;
  wife_N = regN "Ehefrau" ;
  wind_N = regN "Wind" ;
  wing_N = reg2N "Flügel" "Flügel" masculine ;
  worm_N = regN "Wurm" ;
  year_N = regN "Jahr" ;
  blow_V = regV "blasen" ;
  breathe_V = regV "atmen" ;
  burn_V = regV "brennen" ;
  dig_V = regV "graben" ;
  fall_V = regV "fallen" ;
  float_V = regV "treiben" ;
  flow_V = regV "fließen" ;
  fly_V = regV "fliegen" ;
  freeze_V = regV "frieren" ;
  give_V3 = accdatV3 (irregV "geben" "gibt" "gab" "gäbe" "gegeben") ;
  laugh_V = regV "lachen" ;
  lie_V = regV "lügen" ;
  play_V = regV "spielen" ;
  sew_V = regV "nähen" ;
  sing_V = regV "singen" ;
  sit_V = irregV "sitzen" "sitzt" "saß" "säße" "gesessen" ;
  smell_V = regV "riechen" ;
  spit_V = regV "spucken" ;
  stand_V = regV "stehen" ;
  swell_V = prefixV "an" (regV "schwellen") ;
  swim_V = regV "schwimmen" ;
  think_V = regV "denken" ;
  turn_V = regV "drehen" ;
  vomit_V = regV "kotzen" ;

  bite_V2 = dirV2 (irregV "beißen" "beißt" "biss" "bisse" "gebissen") ;
  count_V2 = dirV2 (regV "zählen") ;
  cut_V2 = dirV2 (irregV "schneiden" "schneidet" "schnitt" "schnitte" "geschnitten") ;
  fear_V2 = dirV2 (regV "fürchten") ;
  fight_V2 = dirV2 (regV "bekämpfen") ;
  hit_V2 = dirV2 (irregV "schlagen" "schlägt" "schlug" "schlüge" "geschlagen") ;
  hold_V2 = dirV2 (irregV "halten" "hält" "hielt" "hielte" "gehalten") ;
  hunt_V2 = dirV2 (regV "jagen") ;
  kill_V2 = dirV2 (regV "töten") ;
  pull_V2 = dirV2 (irregV "ziehen" "zieht" "zog" "zöge" "gezogen") ;
  push_V2 = dirV2 (irregV "schieben" "schiebt" "schub" "schübe" "geschoben") ;
  rub_V2 = dirV2 (irregV "reiben" "reibt" "rieb" "riebe" "gerieben") ;
  scratch_V2 = dirV2 (regV "kratzen") ;
  split_V2 = dirV2 (prefixV "auf" (regV "teilen")) ;
  squeeze_V2 = dirV2 (regV "pressen") ;
  stab_V2 = dirV2 (irregV "stechen" "sticht" "stach" "stäche" "gestochen") ;
  suck_V2 = dirV2 (regV "saugen") ;
  throw_V2 = dirV2 (irregV "werfen" "wirft" "warf" "würfe" "geworfen") ;
  tie_V2 = dirV2 (irregV "binden" "bindet" "band" "bände" "gebunden") ;
  wash_V2 = dirV2 (irregV "waschen" "wäscht" "wusch" "wüsche" "gewaschen") ;
  wipe_V2 = dirV2 (regV "wischen") ;

  grammar_N = reg2N "Grammatik" "Grammatiken" feminine ;
  language_N = regN "Sprache" ;
  rule_N = reg2N "Regel" "Regeln" feminine ;

    john_PN = regPN "Johann" ;
    question_N = regN "Frage" ;
    ready_A = regA "fertig" ;
    reason_N = reg2N "Grund" "Gründe" masculine ;
    today_Adv = mkAdv "heute" ;
    uncertain_A = regA "unsicher" ;


} ;